[代码合集] 求助批处理按顺序依次复制一张或多张图片到多个文件夹

@rem 请保存文件为ANSI编码
@rem 假设目标文件夹D:\test\targe下有jpg1～25，共25个子文件夹
@echo off
Setlocal enabledelayedexpansion
set "source=D:\test\source"
set "target=D:\test\target"
for /f "delims==" %%a in ('set _ 2^>nul') do set "%%a="
for /l %%a in (1,1,100) do (
	set/a n=%%a+3,n/=4
	set "_%%a=!n!"
)
cd /d "%source%"
for /f %%a in ('dir *.jpg *.jpeg *.png *.bmp /b /s /a-d') do (
	move /y "%%~fa" "%target%\jpg!_%%~na!\"
)
endlocal
复制代码

@echo off
Setlocal enabledelayedexpansion
set "source=D:\test\source"
set "target=D:\test\target"
cd /d "%source%"
for /f %%a in ('dir *.jpg *.jpeg *.png *.bmp /b /s /a-d') do (
	set/a n=%%~na+3,n/=4
	mkdir "%target%\jpg!n!" 2>nul
	move /y "%%~fa" "%target%\jpg!n!\"
)
endlocal
复制代码

@echo off
REM 每3个文件移动到一个文件夹
set "AvgNum=3"
cd /d "%~dp0"
setlocal enabledelayedexpansion
set "FileCount=-1"
REM dir /b /a-d *.jpg *.jpeg *.png *.bmp 文件名顺序不一定是想要的结果
for /f "delims=" %%i in ('dir /b /a-d ^| findstr /e /c:".jpg" /c:".jpeg" /c:".png" /c:".bmp"') do (
    set /a FileCount+=1
    set /a FolderCount=FileCount/AvgNum+1
    if not exist "!FolderCount!" (
        md "!FolderCount!"
    )
    move /y "%%i" "!FolderCount!\"
)
复制代码

@echo off
set "AvgNum=3"
cd /d "%~dp0"
setlocal enabledelayedexpansion
for /f "delims=" %%i in ('dir /b /a-d ^| findstr /e /c:".jpg" /c:".jpeg" /c:".png" /c:".bmp"') do (
    set fn=%%~ni
    set /a "FolderCount=(!fn:~1!-1)/AvgNum+1"
    if not exist "!FolderCount!" (
        md "!FolderCount!"
    )
    move /y "%%i" "!FolderCount!\"
)
复制代码