[文本处理] [已解决]批处理如何实现删除多个文件夹里名字重复的txt文件

@echo off
REM 设置待处理的文件夹路径
set "FolderFrom=C:\Test\A"
REM 设置新的文件夹路径
set "FolderTo=C:\Test\B"

if not exist "%FolderFrom%\" (
    echo 找不到文件夹"%FolderFrom%"
    goto :End
)
if not exist "%FolderTo%\" (
    echo 找不到文件夹"%FolderTo%"
    goto :End
)
for /f "delims=" %%i in ('dir /b /s /a-d "%FolderFrom%"') do (
    echo 正在处理文件 "%%i"
    if not exist "%FolderTo%\%%~nxi" (
        copy /y "%%i" "%FolderTo%\"
    ) else (
        for %%j in ("%FolderTo%\%%~nxi") do (
            if %%~zi gtr %%~zj (
                copy /y "%%i" "%FolderTo%\"
            )
        )
    )
)
echo 请手工检查文件夹"%FolderTo%"
echo 如果没有问题就删除文件夹"%FolderFrom%"
goto :End

:End
pause
复制代码

@echo off
set "FP=D:\abc"
cd /d "%FP%"
setlocal enabledelayedexpansion
(for /r %%i in (*.txt) do (
    set "FS=0000000000%%~zi"
    echo,%%~ni/!FS:~-10!/%%i
))>tmp1.log
sort tmp1.log>tmp.log
del tmp1.log
for /f "tokens=1-2* delims=/" %%a in (tmp.log) do (
    if "%%a"=="!FN!" del "!FF!"
    set "FN=%%a"
    set "FF=%%c"
)
del tmp.log
pause
复制代码