[新手上路]批处理新手入门导读[视频教程]批处理基础视频教程[视频教程]VBS基础视频教程[批处理精品]批处理版照片整理器
[批处理精品]纯批处理备份&还原驱动[批处理精品]CMD命令50条不能说的秘密[在线下载]第三方命令行工具[在线帮助]VBScript / JScript 在线参考
返回列表 发帖

[文本处理] [已解决]批处理文本替换问题

本帖最后由 pd1 于 2021-2-16 23:22 编辑
  1. @echo off
  2. setlocal enabledelayedexpansion
  3. set "str=xxx123456yyy"
  4. echo !str!
  5. set /p Choice1=请输入:
  6. set "str=!str:123=%Choice1%!"
  7. echo !str!
  8. set /p Choice2=请输入:
  9. set "str=!str:456=%Choice2%!"
  10. echo !str!
  11. pause
复制代码
这样替换文本是可以的。
  1. @echo off
  2. setlocal enabledelayedexpansion
  3. for /f "delims=" %%i in (1.ini) do (
  4. set "str=%%i"
  5. echo !str!
  6. set /p Choice1=请输入:
  7. set "str=!str:123=%Choice1%!"
  8. echo !str!
  9. set /p Choice2=请输入:
  10. set "str=!str:456=%Choice2%!"
  11. echo !str!
  12. )
  13. pause
复制代码
从文件里把这字符串读出来就不行。

回复 1# pd1


请参考Q-01观察一下哪行代码在报错:
https://mp.weixin.qq.com/s/6lbb97qUOs1sTyKJfN0ZEQ

请参考Q-04和Q-05把bat文件和ini文件都保存为ANSI编码:
https://mp.weixin.qq.com/s/6lbb97qUOs1sTyKJfN0ZEQ
我帮忙写的代码不需要付钱。如果一定要给,请在微信群或QQ群发给大家吧。
【微信公众号、微信群、QQ群】http://bbs.bathome.net/thread-3473-1-1.html
【支持批处理之家,加入VIP会员!】http://bbs.bathome.net/thread-67716-1-1.html

TOP

回复 2# Batcher
  1. D:\1\test>setlocal enabledelayedexpansion
  2. D:\1\test>for /F "delims=" %i in (D:\1\test\1.ini) do (
  3. set "str=%i"
  4. echo !str!
  5. set /p Choice1=请输入:
  6. set "str=!str:123=!"
  7. echo !str!
  8. set /p Choice2=请输入:
  9. set "str=!str:456=!"
  10. echo !str!
  11. )
  12. D:\1\test>(
  13. set "str=xxx123456yyy"
  14. echo !str!
  15. set /p Choice1=请输入:
  16. set "str=!str:123=!"
  17. echo !str!
  18. set /p Choice2=请输入:
  19. set "str=!str:456=!"
  20. echo !str!
  21. )
  22. xxx123456yyy
  23. 请输入:aaa
  24. xxx456yyy
  25. 请输入:bbb
  26. xxxyyy
  27. D:\1\test>pause
  28. Press any key to continue . . .
复制代码

TOP

  1. @echo off
  2. setlocal enabledelayedexpansion
  3. for /f "delims=" %%i in (1.ini) do (
  4. set "str=%%i"
  5. echo !str!
  6. set /p Choice1=请输入:
  7. call set "str=!str:123=%%Choice1%%!"
  8. echo !str!
  9. set /p Choice2=请输入:
  10. call set "str=!str:456=%%Choice2%%!"
  11. echo !str!
  12. )
  13. pause
复制代码
微信:flashercs
QQ:49908356

TOP

set "str=!str:456=%Choice2%!" 改成这样
call set "str=%%str:123=!Choice1!%%"
不然for里面取不到chouce1的值

TOP

  1. @echo off
  2. setlocal enabledelayedexpansion
  3. for /f "delims=" %%i in (1.ini) do (
  4. set "str=%%i"
  5. echo !str!
  6. set /p Choice1=请输入:
  7. for %%A in (!Choice1!) do (
  8.   set "str=!str:123=%%A!"
  9. )
  10. echo !str!
  11. set /p Choice2=请输入:
  12. for %%A in (!Choice2!) do (
  13.   set "str=!str:456=%%A!"
  14. )
  15. echo !str!
  16. )
  17. pause
复制代码
微信:flashercs
QQ:49908356

TOP

谢谢各位大佬的热心解答。

TOP

返回列表