[文件操作] [已解决]批处理如何获得一小时前到当前时间之间所创建的文件？

@echo off&setlocal enabledelayedexpansion
for /f %%i in ("%date%") do set dd=%%i
for /f "delims=:" %%i in ("%time%") do set /a tt=%%i-1
for /r e:\ %%i in (*) do (
    for /f "tokens=1,2 delims=: " %%a in ("%%~ti") do (
        if "%%a"=="%dd%" if "%%b"=="%tt%" echo %%i
    )
)
pause
复制代码

@echo off&setlocal enabledelayedexpansion
set ndy=%date:~0,-4%
set nte=%time:~0,-3%
set nhr=%nte:~0,-6%
set nme=%nte:~3,-3%
set nsd=%nte:~6%
set /a strhr=%nhr%-1
set strTime=%strhr%:%nme%

echo.正在搜索文件，请稍等...
echo.%ndy%  %strTime%--%nte:~0,-3% >t.txt
echo.>>t.txt
for /f "delims=" %%a in ('dir /b/s/a-d e:\') do (
  set t=%%~ta
  set d=!t:~0,-6!
  set t=!t:~-5!
  if !d! equ %ndy% if !t! leq %nte% if !t! geq %strTime% >>t.txt echo.%%a  %%~ta
)
复制代码

@echo off&setlocal enabledelayedexpansion
for /f "tokens=1,2 delims=:" %%i in ('time/t') do set hh=%%i&set mm=%%j
for /f "tokens=1-3 delims=- " %%i in ('date/t') do set year=%%i&set month=%%j&set day=%%k
set/a month=100%month%%%100,day=100%day%%%100,hh=100%hh%%%100,hh-=1
if %hh% equ -1 set/a hh=23&call :datejs
set/a month=10%month%,day=10%day%,hh=10%hh%
set month=%month:~-2%&set day=%day:~-2%&set hh=%hh:~-2%
set "rqsj=%year%-%month%-%day% %hh%:%mm%"
for /f "delims=" %%i in ('dir/b/s/a-d e:\') do if "%%~ti" geq "%rqsj%" echo %%i
pause&exit
:datejs //**日期计算部分，以前写的，拿来凑合用**//
for %%i in (1,5,7,10,12) do (
   if %month% equ %%i (
      if %day% neq 1 (set/a day-=1&goto :eof
         ) else (
           if %month% neq 1 (set/a month-=1,day=30&goto :eof
              ) else (set/a year-=1,month=12,day=31&goto :eof)
		)
	)
)
for %%i in (2,4,6,8,9,11) do (
   if %month% equ %%i (
      if %day% neq 1 (set/a day-=1&goto :eof
         ) else (set/a month-=1,day=31&goto :eof)
	)
)
set/a mod=!(year%%4)^&!(!(year%%100))^|!(year%%400)
if %month% equ 3 (
   if %mod% equ 1 (
     if %day% neq 1 (set/a day-=1&goto :eof
        ) else (set/a month-=1,day=29&goto :eof)
	) else (
		if %day% neq 1 (set/a day-=1&goto :eof
        ) else (set/a month-=1,day=28&goto :eof)
	)
)
复制代码

' 2>nul&cls&@cscript //nologo //e:vbscript "%~f0" &pause
strNowDate = Now
FilesTree("E:\")
Function FilesTree(sPath)
    Set oFso = CreateObject("Scripting.FileSystemObject")
    Set oFolder = oFso.GetFolder(sPath)
    Set oFiles = oFolder.Files
    For Each oFile In oFiles
        If DateDiff("s",oFile.DateCreated,strNowDate) <= 3600 Then
           Wscript.Echo oFile.Path & "  " &  oFile.DateCreated
        End If
    Next
    Set oSubFolders = oFolder.SubFolders
    For Each oSubFolder In oSubFolders
        FilesTree(oSubFolder.Path)
    Next   
    Set oFolder = Nothing
    Set oSubFolders = Nothing
    Set oFso = Nothing
End Function
复制代码