[文件操作] （已解决）怎么把文件/文件夹名称的.号换成空格 ？

@echo off&SetLocal EnableDelayedExpansion
set /p strtemp1=要替换的文件名字符串(可替换空格):
set /p strtemp2=替换后的文件名字符串(删除则回车):
for /f "delims=" %%i in ('dir /s /b') do (
set "f=%%~nxi"
set "f1=!f:%strtemp1%=%strtemp2%!"
if not "%%i"==%0 ( 
if not "!f!"=="!f1!" (
if exist "!f1!" (
echo 由于!f1!存在同名，!f! 文件名未改 ) else ren "!f!" "!f1!" 
) 
endlocal
)
)
复制代码

@echo off&SetLocal EnableDelayedExpansion
set c=0123456789abcdefghijklmnopqrstuvwxyz
set /p strtemp1=要替换的文件名字符串(可替换空格):
set /p strtemp2=替换后的文件名字符串(删除则回车):
for /f "delims=" %%i in ('dir /s /b') do (
  set "f=%%~nxi"
  set "f1=!f:%strtemp1%=%strtemp2%!"
  if not "%%i"==%0 (
    if not "!f!"=="!f1!" (
       ren "%%i" "!f1!" 
    )
  )
)
pause
复制代码

@echo off&SetLocal EnableDelayedExpansion
set c=0123456789abcdefghijklmnopqrstuvwxyz
set /p strtemp1=要替换的文件名字符串(可替换空格):
set /p strtemp2=替换后的文件名字符串(删除则回车):
for /f "delims=" %%i in ('dir /a-d /s /b') do (
  set "f=%%~ni"
  set "f1=!f:%strtemp1%=%strtemp2%!"
  if not "%%i"==%0 (
    if not "!f!"=="!f1!" (
       ren "%%i" "!f1!%%~xi" 
    )
  )
)
pause
复制代码

@echo off
set /p str1=要替换的文件名字符串(可替换空格):
set /p str2=替换后的文件名字符串(删除则回车):
for /f "delims=" %%a in ('dir /s /b ^|sort /+65535') do (
if "%%~nxa" neq "%~nx0" (
set "file=%%a"
set "name=%%~na"
set "extension=%%~xa"
call set "name=%%name:%str1%=%str2%%%"
SetLocal EnableDelayedExpansion
ren "!file!" "!name!!extension!" 2>nul
endlocal
)
)
pause
复制代码

REM 功能:替换文件名和目录名(包含子目录)的指定字符串
@echo off
set "dir=%~1"
if not defined dir set "dir=%~dp0"
REM 要替换的文件名字符串(可替换空格):
set "strSrc=."
REM 替换后的文件名字符串(删除则留空):
set "strDst= "
call :recurse "%dir%"
pause
exit /b %errorlevel%

:recurse
setlocal
2>nul,pushd %1||goto end
REM 先处理文件-preorder
for %%A in (*) do (
  if not "%%~fA"==%0 (
    call :renfso "%%A" 
  )
)
REM 再处理目录-inorder
for /d %%D in (*) do (
  call :recurse "%%D"
  call :renfso "%%D"
)
popd
:end
endlocal
exit /b

:renfso
set "baseName=%~n1"
call set "newBaseName=%%baseName:%strSrc%=%strDst%%%"
if not "%newBaseName%"=="%baseName%" ren %1 "%newBaseName%%~x1"
exit /b
复制代码