批处理之家 » BAT求助&讨论 » [已解决]批处理进行文本内容字符串替换时冒号会消失？

[新手上路]批处理新手入门导读	[视频教程]批处理基础视频教程	[视频教程]VBS基础视频教程	[批处理精品]批处理版照片整理器
[批处理精品]纯批处理备份&还原驱动	[批处理精品]CMD命令50条不能说的秘密	[在线下载]第三方命令行工具	[在线帮助]VBScript / JScript 在线参考

返回列表发帖

Rank: 3 Rank: 3

帖子: 15
积分: 217
技术: 0
捐助: 0
注册时间: 2008-11-7

1楼 跳转到 » 倒序看帖

字体大小: tT

发表于 2009-6-8 21:43 | 只看该作者

[文本处理] [已解决]批处理进行文本内容字符串替换时冒号会消失？

call :replace count wxwei Login.txt
:replace
for /f "tokens=1* delims=:" %%i in ('findstr /n .* %3') do (
    set str=%%j
    if not "!str!"=="" set "str=!str:%1=%2!"
    >>"Auto_tmp.txt" echo.!str!
)
move /y Auto_tmp.txt %3
goto :eof
复制代码

Login.txt中的内容为：

This is a test for replace.
username=count
:Login
Login code
:Exit
exit
::This is a test
复制代码

用上面的替换程序替换后结果为：

This is a test for replace.
username=wxwei
Login
Login code
Exit
exit
This is a test
复制代码

但希望得到的结果是

This is a test for replace.
username=wxwei
:Login
Login code
:Exit
exit
::This is a test
复制代码

如何保留冒号？
谢谢

[ 本帖最后由 welky 于 2009-6-8 23:28 编辑 ]

1 评分人数

随风: 感谢主动给标题加上“以解决”PB + 2

Rank: 2

帖子: 8
积分: 114
技术: 0
捐助: 0
注册时间: 2009-5-5

2楼

发表于 2009-6-8 22:05 | 只看该作者

试试?

(for /f "delims=" %%i in (login.txt) do (
if  not %%i==count  echo %%i esle echo wxwei))>login.txt
复制代码

Rank: 3 Rank: 3

帖子: 15
积分: 217
技术: 0
捐助: 0
注册时间: 2008-11-7

3楼

发表于 2009-6-8 22:29 | 只看该作者

原帖由 wjjy 于 2009-6-8 22:05 发表
(for /f "delims=" %%i in (login.txt) do (
if not %%i==count echo %%i esle echo wxwei))>login.txt

谢谢，试了下，但没有达到要求！

Rank: 2

帖子: 13
积分: 132
技术: 0
捐助: 0
注册时间: 2009-5-17

4楼

发表于 2009-6-8 22:30 | 只看该作者

改了下.你再看下能行不

@echo off&setlocal enabledelayedexpansion
for /f "tokens=*" %%i in (login.txt) do (
    set var=%%i
    set var=!var:count=wxwei!
    echo !var!>>login2.txt
)
del /q login.txt&ren login2.txt login.txt
复制代码

[ 本帖最后由 fyb198351 于 2009-6-8 22:55 编辑 ]

Rank: 3 Rank: 3

帖子: 15
积分: 217
技术: 0
捐助: 0
注册时间: 2008-11-7

5楼

发表于 2009-6-8 22:33 | 只看该作者

原帖由 fyb198351 于 2009-6-8 22:30 发表
楼上的代码有几个地方错了@echo off
for /f "delims=" %%i in (login.txt) do (
   if  not %%i==count  (echo %%i) else (
               echo wxwei
)
  )>>login1.txt
del /q login.txt&ren login1.t ...

count 可能不是在一行的开始，可以在一行的任意地方。
Sorry,没写清楚！
还是谢谢！

Rank: 8 Rank: 8

帖子: 618
积分: 6100
技术: 9
捐助: 0
注册时间: 2008-8-10

6楼

发表于 2009-6-8 22:54 | 只看该作者

@echo off
setlocal enabledelayedexpansion
call :replace count wxwei Login.txt

goto :eof
:replace
for /f "delims=" %%i in ('findstr /n .* %3') do (
    set str=%%i
    set "str=!str:*:=!"
    if not "!str!"=="" set "str=!str:%1=%2!"
    >>"Auto_tmp.txt" echo+!str!
)
::    >>"Auto_tmp.txt" echo+!str!
move /y Auto_tmp.txt %3
goto :eof
复制代码

[ 本帖最后由 wxcute 于 2009-6-8 22:59 编辑 ]

批处理之家论坛官方 QQ 群：【当前人数/人数上限】【2009-07-08】
群①：43011867（181/200）；群②：（暂缺数据）；群③：66165582（120/200）。

Rank: 8 Rank: 8

帖子: 1759
积分: 5387
技术: 51
捐助: 210
注册时间: 2007-10-26

7楼

发表于 2009-6-8 23:00 | 只看该作者

回复 5楼的帖子

@echo off
call :replace count wxwei Login.txt
:replace
(for /f "delims=" %%i in ('findstr /n .* "%~3"') do (
    set "str=%%i"
    setlocal enabledelayedexpansion
    set "str=!str:*:=!"
    set "str=!str:%~1=%~2!"
    echo;!str!
    endlocal
))>Auto_tmp.txt
move /y Auto_tmp.txt %3
goto :eof
复制代码

技术问题请到论坛发帖求助！

Rank: 3 Rank: 3

帖子: 15
积分: 217
技术: 0
捐助: 0
注册时间: 2008-11-7

8楼

发表于 2009-6-8 23:24 | 只看该作者

原帖由 wxcute 于 2009-6-8 22:54 发表
@echo off
setlocal enabledelayedexpansion
call :replace count wxwei Login.txt

goto :eof
:replace
for /f "delims=" %%i in ('findstr /n .* %3') do (
set str=%%i
set "str=!str:*:=!"
...

谢谢斑竹！
能实现想要的功能！

Rank: 3 Rank: 3

帖子: 15
积分: 217
技术: 0
捐助: 0
注册时间: 2008-11-7

9楼

发表于 2009-6-8 23:27 | 只看该作者

原帖由随风于 2009-6-8 23:00 发表
@echo off
call :replace count wxwei Login.txt
:replace
(for /f "delims=" %%i in ('findstr /n .* "%~3"') do (
set "str=%%i"
setlocal enabledelayedexpansion
set "str=!str:*:=!"
se ...

谢谢超超级版主，你的不仅能保留冒号，连感叹号都能保留！
非常感谢各位。
结贴！