[文件操作] [已解决]批处理复制指定文件夹并跳过已存在的重复文件

@echo off
set src=C:\test\folder1
set dst=C:\test\folder2
cd /d "%dst%"
xcopy /l /s /e . \nul\ | sort /r | more +1 > "%temp%\exist~.txt"
cd /d "%src%"
xcopy /s /e /exclude:%temp\exist~.txt . "%dst%\"
del "%temp%\exist~.txt"
复制代码

@echo off
:: 源路径中不能含有符号“!”；不能复制隐藏/系统属性文件
set "Src=C:\test\folder1"
set "Dest=C:\test\folder2"

for /r "%Src%" %%S in (*) do (
  set dp=%%~dpS
  set nx=%%~nxS
  setlocal enabledelayedexpansion
  if not exist "!Dest!\!dp:%Src%=!\!nx!" (
    md "!Dest!\!dp:%Src%=!" 2>Nul
    copy "!dp!!nx!" "!Dest!\!dp:%Src%=!">nul
  )
  endlocal
)
复制代码

@echo off
:: 源路径中不能含有符号“!”；可以复制隐藏/系统属性文件
set "Src=C:\test\folder1"
set "Dest=C:\test\folder2"

(for /f "delims=" %%S in ('dir/a-d/b/s "%Src%"') do (
  set dp=%%~dpS
  set nx=%%~nxS
  setlocal enabledelayedexpansion
  if exist "!Dest!\!dp:%Src%=!\!nx!" echo !dp!!nx!
  endlocal
))>Exist_Files

xcopy "%Src%" "%Dest%" /sqih /EXCLUDE:Exist_Files
del Exist_Files
复制代码

@echo off
set "a=C:\test\folder1"
set "b=h:\test\folder2"
xcopy /TY "%a%" "%b%"
setlocal enabledelayedexpansion
for /f "delims=" %%i in ('dir/b/s/a-d "%a%\"') do (
   set str=%%i
   set str=!str:%a%=%b%!
   if not exist "!str!" copy "%%i" "!str!" >nul
)
pause
复制代码

@echo off
set "a=C:\test\folder1"
set "b=h:\test\folder2"
setlocal enabledelayedexpansion
for /f "delims=" %%i in ('dir/a-d/b/s "%a%"') do (
   set str=%%~dpi
   set str=!str:%a%=%b%!
   echo n|xcopy /HK "%%i" "!str!" >nul
)
pause
复制代码

for /r 1\ %%a in (*) do set /a n+=1
(for /l %%a in (1 1 %n%) do echo n)|xcopy /e /r /h /-y a b\
复制代码