[数值计算] 怎么用批处理生成随机不重复的数字1~10

@echo off
for /l %%a in (1,1,10) do call echo %%random:~-1%%#%%a >>$
for /f "tokens=1* delims=#" %%b in ('type $ ^|sort') do echo %%c
del $
pause
复制代码

@echo off
setlocal enabledelayedexpansion
for /l %%a in (1,1,10) do set _%%a=%%a
for /l %%a in (10,-1,1) do (
    set /a mod=!random!%%%%a+1
    for %%b in (!mod!) do echo !_%%b!
    set/a _!mod!=_%%a
)
pause
复制代码

@echo off
setlocal enabledelayedexpansion
for /l %%a in (1,1,10) do set _!random!_%%a=%%a
for /f "tokens=2 delims==" %%a in ('set _') do echo %%a
pause
复制代码

@echo off
setlocal enabledelayedexpansion
for /f "delims=" %%z in (%1) do (set /a b+=1)
for /l %%a in (1,1,%b%) do call echo %%random:~-1%%#%%a >>$
for /f "tokens=1* delims=#" %%b in ('type $ ^|sort') do echo %%c>>1.ini
del $
pause
复制代码

@echo off
setlocal enabledelayedexpansion
for /f "delims=" %%z in ('type %1') do (set /a b+=1)
for /l %%a in (1,1,!b!) do echo !random:~-1!#%%a >>$
for /f "tokens=1* delims=#" %%b in ('type $ ^|sort') do echo %%c>>1.ini
del $
pause
复制代码

@echo off&setlocal enabledelayedexpansion
set n=0123456789
for /l %%i in (0 1 9) do (
    set/a a=!random!%%(10-%%i^)
    for %%a in (!a!) do (
        if "!n:~%%a,1!"=="0" (
            echo,10
        ) else (
            echo,!n:~%%a,1!
        )
    set u=!n:~%%a,1!
    )
    for %%a in (!u!) do set n=!n:%%a=!
)
pause
复制代码

@echo off&setlocal enabledelayedexpansion
for /l %%i in (1 1 10) do set _!RANDOM!=%%i
for /f "tokens=2 delims==" %%i in ('set _') do echo,%%i
pause
复制代码

@echo off&setlocal enabledelayedexpansion
set m=10
for /L %%i in (1,1,%m%) do set $%%i=%%i
:start
for /L %%i in (%m%,-1,1) do (
    set /a n=!random!%%%%i+1
    for %%j in (!n!) do set /a $%%i=$%%j,$%%j=!$%%i!
    echo !$%%i!
)
pause
goto start
复制代码