批处理新手入门导读[视频教程]批处理基础视频教程[视频教程]VBS基础视频教程
[批处理文件精品]批处理版照片整理器[批处理文件精品]纯批处理备份&还原驱动在线第三方下载
返回列表 发帖

[日期时间] 【方案汇总】批处理标准化获取当前系统日期时间(20190315更新)

操作系统不同,日期格式也可能不同:

星期二 2008-07-29
2008-07-29 星期二
07/29/2008 Tue
Tue 07/29/2008

再考虑到中、英之外的其它语言的操作系统,日期格式的种类实在太多了。要想标准化地获取当前系统日期20080728,以下两个方法都不好:
1. 直接使用系统变量 %date% 进行字符串截取
2. 直接对 date 命令的结果进行字符串截取
实际上日期格式是由注册表 HKEY_CURRENT_USER\Control Panel\International 里面 sShortDate 的值来决定的。

推荐使用其它方法来获取系统日期:

【方案1】BAT + PowerShell
  1. @echo off
  2. REM Win7/Win8/Win10等系统自带PowerShell
  3. for /f %%i in ('powershell -c "Get-Date -uformat '%%Y%%m%%d'"') do (
  4.     set "Today=%%i"
  5. )
  6. echo,%Today%
  7. pause
  8. for /f "delims=" %%i in ('powershell -c "Get-Date -UFormat '%%Y-%%m-%%d %%H:%%M:%%S'"') do (
  9.     set "SysTS=%%i"
  10. )
  11. echo %SysTS%
  12. pause
复制代码
【方案2】BAT + WMIC
  1. @echo off
  2. for /f "tokens=2 delims==" %%i in ('wmic path win32_operatingsystem get LocalDateTime /value ^| findstr "="') do (
  3.     set "strDate=%%i"
  4. )
  5. set "Today=%strDate:~0,4%%strDate:~4,2%%strDate:~6,2%"
  6. echo,%Today%
  7. pause
  8. set "Now=%strDate:~0,4%-%strDate:~4,2%-%strDate:~6,2% %strDate:~8,2%:%strDate:~10,2%:%strDate:~12,2%"
  9. echo %Now%
  10. pause
复制代码
【方案3】BAT + VBS
  1. @echo off
  2. >"%temp%\DateCalculate.vbs" echo dt=date()
  3. >>"%temp%\DateCalculate.vbs" echo s=right(year(dt),4) ^& "-" ^& right("0" ^& month(dt),2) ^& "-" ^& right("0" ^& day(dt),2)
  4. >>"%temp%\DateCalculate.vbs" echo wscript.echo s
  5. for /f %%a in ('cscript /nologo "%temp%\DateCalculate.vbs"') do (
  6.     set Today=%%a
  7. )
  8. echo,%Today%
  9. pause
复制代码
【方案4】BAT + REG
  1. @echo off
  2. REM 无法保证在中、英之外的其它语言的操作系统上得到正确结果
  3. for /f "delims=" %%a in ('reg query "HKEY_CURRENT_USER\Control Panel\International" /v sShortDate') do (
  4.     set "RegDateOld=%%a"
  5. )
  6. set RegDateOld=%RegDateOld:~-8%
  7. reg add "HKEY_CURRENT_USER\Control Panel\International" /v sShortDate /t REG_SZ /d yyyy-M-d /f>nul
  8. set Today=%date: =%
  9. reg add "HKEY_CURRENT_USER\Control Panel\International" /v sShortDate /t REG_SZ /d %RegDateOld% /f>nul
  10. set "Week=Mon Tue Wed Thu Fri Sat Sun 星期一 星期二 星期三 星期四 星期五 星期六 星期日"
  11. for %%a in (%Week%) do (
  12.     call set "Today=%%Today:%%a=%%"
  13. )
  14. echo,%Today%
  15. pause
复制代码
【方案5】BAT + REG
  1. @echo off
  2. for /f "delims=" %%a in ('reg query "HKEY_CURRENT_USER\Control Panel\International" /v sShortDate') do (
  3.     set "RegDateOld=%%a"
  4. )
  5. set RegDateOld=%RegDateOld:~-8%
  6. reg add "HKEY_CURRENT_USER\Control Panel\International" /v sShortDate /t REG_SZ /d yyyy-M-d /f>nul
  7. set Today=%date: =%
  8. reg add "HKEY_CURRENT_USER\Control Panel\International" /v sShortDate /t REG_SZ /d %RegDateOld% /f>nul
  9. if "%Today:~0,1%" gtr "9" (
  10.     set Today=%Today:~-10%
  11. ) else (
  12.     set Today=%Today:~0,10%
  13. )
  14. echo,%Today%
  15. pause
复制代码
【方案6】BAT + REG
  1. @echo off
  2. for /f "delims=" %%a in ('reg query "HKEY_CURRENT_USER\Control Panel\International" /v sShortDate') do (
  3.     set "RegDateOld=%%a"
  4. )
  5. set RegDateOld=%RegDateOld:~-8%
  6. reg add "HKEY_CURRENT_USER\Control Panel\International" /v sShortDate /t REG_SZ /d yyyy-M-d /f>nul
  7. type nul>"%temp%\MyFile.tmp"
  8. for /f %%a in ('dir "%temp%\MyFile.tmp" ^| findstr /i "MyFile.tmp"') do (
  9.     set Today=%%a
  10. )
  11. reg add "HKEY_CURRENT_USER\Control Panel\International" /v sShortDate /t REG_SZ /d %RegDateOld% /f>nul
  12. echo,%Today%
  13. pause
复制代码
【方案7】BAT + REGEDIT
  1. @echo off
  2. REM 需要保证注册表编辑器没有处于锁定状态
  3. regedit /e "%temp%\bak.reg" "HKEY_CURRENT_USER\Control Panel\International"
  4. >"%temp%\new.reg" echo REGEDIT4
  5. >>"%temp%\new.reg" echo,
  6. >>"%temp%\new.reg" echo [HKEY_CURRENT_USER\Control Panel\International]
  7. >>"%temp%\new.reg" echo "sShortDate"="yyyy-MM-dd"
  8. regedit /s "%temp%\new.reg"
  9. set Today=%date: =%
  10. regedit /s "%temp%\bak.reg"
  11. if "%Today:~0,1%" gtr "9" (
  12.     set Today=%Today:~-10%
  13. ) else (
  14.     set Today=%Today:~0,10%
  15. )
  16. echo,%Today%
  17. pause
复制代码
【方案8】BAT + DEBUG
  1. @echo off
  2. for /f "tokens=6,8 delims== " %%a in ('^(echo a100^&echo mov ah^,2a^&echo int 21^&echo.^&echo p 2^&echo q^)^|debug^|find "CX"') do (
  3.     set /a y=0x%%a
  4.     set md=%%b
  5. )
  6. set /a m=0x%md:~,2%
  7. set /a d=0x%md:~-2%
  8. set m=0%m%
  9. set d=0%d%
  10. set Today=%y%-%m:~-2%-%d:~-2%
  11. echo,%Today%
  12. pause
复制代码
以下转载两个在DOS系统(不是Windows系统的CMD)里面获取日期、时间的代码:
原文:http://www.cn-dos.net/forum/viewthread.php?tid=19756
【willsort原始版】
  1. @echo off
  2. if "%1"=="[(" goto parse
  3. echo.|date|find "Current" > _getdate.bat
  4. echo set _dw=%%3> current.bat
  5. echo set _date=%%4>> current.bat
  6. call _getdate.bat
  7. echo.|date|find "Enter" > _getdfmt.bat
  8. echo set _dfmt=%%3> enter.bat
  9. call _getdfmt.bat
  10. echo.|time|find "Current" > _gettime.bat
  11. echo set _time=%%3> current.bat
  12. call _gettime.bat
  13. echo _|choice /c%_dfmt%%_date%_%_time%_ @%0 > _parse.bat
  14. %comspec% /e:2048 /c _parse.bat
  15. goto end
  16. :parse
  17. set _dt1=_%2%3
  18. set _dt2=_%5%6
  19. set _dt3=_%8%9
  20. for %%t in ([,Y,Y,-,M,M,-,D,D,]) do shift
  21. set _vdt=
  22. :loop1
  23. shift
  24. set _tmp=%_vdt%
  25. for %%t in (1,2,3,4,5,6,7,8,9,0) do if "%1"=="%%t" set _vdt=%_vdt%%1
  26. if not "%_vdt%"=="%_tmp%" goto loop1
  27. set %_dt1%=%_vdt%
  28. set _vdt=
  29. :loop2
  30. shift
  31. set _tmp=%_vdt%
  32. for %%t in (1,2,3,4,5,6,7,8,9,0) do if "%1"=="%%t" set _vdt=%_vdt%%1
  33. if not "%_vdt%"=="%_tmp%" goto loop2
  34. set %_dt2%=%_vdt%
  35. set _vdt=
  36. :loop3
  37. shift
  38. set _tmp=%_vdt%
  39. for %%t in (1,2,3,4,5,6,7,8,9,0) do if "%1"=="%%t" set _vdt=%_vdt%%1
  40. if not "%_vdt%"=="%_tmp%" goto loop3
  41. set %_dt3%=%_vdt%
  42. set _vdt=
  43. :loop4
  44. shift
  45. set _tmp=%_vdt%
  46. for %%t in (1,2,3,4,5,6,7,8,9,0) do if "%1"=="%%t" set _vdt=%_vdt%%1
  47. if not "%_vdt%"=="%_tmp%" goto loop4
  48. set _HH=%_vdt%
  49. set _vdt=
  50. :loop5
  51. shift
  52. set _tmp=%_vdt%
  53. for %%t in (1,2,3,4,5,6,7,8,9,0) do if "%1"=="%%t" set _vdt=%_vdt%%1
  54. if not "%_vdt%"=="%_tmp%" goto loop5
  55. set _MN=%_vdt%
  56. set _vdt=
  57. :loop6
  58. shift
  59. set _tmp=%_vdt%
  60. for %%t in (1,2,3,4,5,6,7,8,9,0) do if "%1"=="%%t" set _vdt=%_vdt%%1
  61. if not "%_vdt%"=="%_tmp%" goto loop6
  62. set _SS=%_vdt%
  63. set _vdt=
  64. :loop7
  65. shift
  66. set _tmp=%_vdt%
  67. for %%t in (1,2,3,4,5,6,7,8,9,0) do if "%1"=="%%t" set _vdt=%_vdt%%1
  68. if not "%_vdt%"=="%_tmp%" goto loop7
  69. set _CS=%_vdt%
  70. echo DTN:%_YY% %_MM% %_DD% %_HH% %_MN% %_SS% %_CS%
  71. :end
复制代码
【willsort简化版】
  1. @echo off
  2. if "%1"==":" goto %2 (subroutine handler at %2)
  3. echo.exit|%comspec%/e:4096/k prompt set v=$d $t$_:>_tm.bat
  4. call _tm.bat
  5. echo.%v%&|%comspec%/e:4096/c %0 : Parse>_tm.bat
  6. for %%p in (_tm.bat* _tmset.bat*) do call %%p
  7. echo.Note that d1 d2 and d3 are in your system date order
  8. echo.DTN:d1=%d1% d2=%d2% d3=%d3% hh=%hh% mm=%mm% ss=%ss% cs=%cs%.
  9. for %%e in (v d1 d2 d3 hh mm ss cs) do set %%e=
  10. for %%f in (_tm.bat* _tm.tmp* _tmset.bat*) do del %%f
  11. goto end
  12. :Parse (usage: call %0 : Parse +input redirect date/time)
  13. set me=%0
  14. set tok=d1 d2 d3 hh mm ss cs
  15. set d1=
  16. :NextToken
  17. for %%v in (v1 v) do set %%v=
  18. choice /c&0123456789 /n>_tm.tmp
  19. for %%n in (0 1 2 3 4 5 6 7 8 9) do if errorlevel 77%%n set v=%%n
  20. if not errorlevel 2 %me% : SetToken %tok%
  21. find ""<_tm.tmp>nul
  22. if not errorlevel 1 if not "%d1%"=="" call %me% : SetToken %tok%
  23. set d1=%d1%%v%
  24. goto NextToken
  25. :SetToken
  26. set tok=%4 %5 %6 %7 %8 %9
  27. echo set %3=%d1%>> _tmset.bat
  28. set d1=
  29. goto end
  30. :end (end-of-file)
复制代码
1

评分人数

【扫描二维码捐助论坛的朋友请留言注明论坛账号】http://bbs.bathome.net/thread-10403-1-1.html
【批处理在线视频分享】http://bbs.bathome.net/thread-31727-1-1.html
【微信公众号、微信群、QQ群】http://bbs.bathome.net/thread-3473-1-1.html

作为个人作品,在小范围内流通不需要考虑这么多。。。

当然,鼓励LZ。。。

TOP

不错的总结。
  1. wmic path win32_operatingsystem get LocalDateTime
  2. wmic os get LocalDateTime
复制代码
纯P的话,这个我常用
命令行参考:hh.exe ntcmds.chm::/ntcmds.htm
求助者请拿出诚心,别人才愿意奉献热心!
把查看手册形成条件反射!

TOP

回复 2楼 的帖子

确实如此。
不过等你参加工作以后,可能会发现自己的代码需要兼容各种各样的环境。
^_^
【扫描二维码捐助论坛的朋友请留言注明论坛账号】http://bbs.bathome.net/thread-10403-1-1.html
【批处理在线视频分享】http://bbs.bathome.net/thread-31727-1-1.html
【微信公众号、微信群、QQ群】http://bbs.bathome.net/thread-3473-1-1.html

TOP

回复 4楼 的帖子

我在win98 MS-DOS4.10下,就不能使用%time%来引用当前时间,echo %time%的结果还是%time%。这就是环境不同的结果吧。能告诉我为什么会这样呢?

TOP

回复 5楼 的帖子

DOS系统里面没有%date%、%time%等环境变量,顶楼添加了两种在DOS系统里面的解决方案。
【扫描二维码捐助论坛的朋友请留言注明论坛账号】http://bbs.bathome.net/thread-10403-1-1.html
【批处理在线视频分享】http://bbs.bathome.net/thread-31727-1-1.html
【微信公众号、微信群、QQ群】http://bbs.bathome.net/thread-3473-1-1.html

TOP

很多种方法,研究一下

TOP

mark一下,明日再研究

TOP

学习了,感谢楼主。

TOP

感谢分享!!!

TOP

不错的分享
我就是我,不一样的烟火!

TOP

返回列表