[文件操作] 批处理怎样同步文件夹？

@echo off
if exist mubiao.txt del mubiao.txt>nul
if exist yuan.txt del yuan.txt>nul
if exist butong.txt del butong.txt>nul
cls
echo.
::>>>>>>>>>>>>>>>程序开始前动作
COLOR 08
MODE con: COLS=80 LINES=30
title 自动同步到U盘V1.0
::>>>>>>>>>>>>>>主界面开始
echo=
echo 自动同步到U盘V1.0
echo ===================
echo 请插入U盘，准备好后按任意键开始。
pause>nul
::>>>>>>>>>>>>>>确定U盘盘符
echo=
echo 正在确定U盘盘符...
set "var1=fsutil fsinfo drives"
set "var2=fsutil fsinfo drivetype"
for /f "delims=驱动器:\ " %%a in ('%var1%^|more') do (
     for /f "delims=:" %%b in ('%var2% %%a: ^| find/i "可移动驱动器"') do (
     call set "pan=%%pan%%%%b"
))
set "u=%pan:~-1%"
dir %u%: >%u%:\tb
if not exist %u%:\tb goto U盘出错
del %u%:\tb
::>>>>>>>>>>>>>>设置源文件夹及同步文件夹
set yuan="e:\源 文件夹"
set tongbu="%u%:\同步 文件夹"
if not exist %yuan% goto 源文件夹不存在
if not exist %tongbu% goto 目标文件夹不存在
::>>>>>>>>>>>>>>>>>>开始同步不存在的目录及文件
echo=
echo 正在同步中，请不要拔出U盘...
echo n |xcopy %yuan%\*.* %tongbu%\ /s /e /c /q /h /d >nul 2>nul
xcopy %yuan%\*.* %tongbu%\ /d /e /y >nul 2>nul
echo=
echo 完成...
::>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>开始查找U盘多余的文件，删除。
echo=
echo 是否开始反向处理？【Y=确认 其他键=退出】
echo 如果选择确认，那么将开始比照源盘文件，如果源盘某文件或目录被删除，
echo U盘上相同的文件或目录也将被删除，请谨慎选择...
set /p c=请输入：
if "%c%"=="y" goto y
goto end
:y
cls
echo=
echo 自动同步到U盘——反向处理V1.0
echo ==========================
echo 正在列表...
dir %yuan% /b /s >yuan.txt
dir %tongbu% /b /s >tongbu.txt
for /f "delims=\ tokens=2,*" %%d in (yuan.txt) do echo %%d %%e>>yuan1.txt
for /f "tokens=3,*" %%f in (yuan1.txt) do echo %%f %%g>>yuan2.txt
del yuan.txt
del yuan1.txt
ren yuan2.txt yuan.txt
for /f "delims=\ tokens=2,*" %%h in (tongbu.txt) do echo %%h %%i>>tongbu1.txt
for /f "tokens=3,*" %%j in (tongbu1.txt) do echo %%j %%k>>tongbu2.txt
del tongbu.txt
del tongbu1.txt
ren tongbu2.txt tongbu.txt
echo=
echo 正在查询，请稍等...
for /f "delims=" %%l in (tongbu.txt) do (
     type yuan.txt |find /i "%%l" >nul ||echo %%l >>butong.txt
)
del yuan.txt>nul
del tongbu.txt>nul
if not exist butong.txt echo=&&echo 没有需要反向处理的文件及目录&&goto end
echo=
echo 正在反向处理...
for /f %%m in (butong.txt) do (
	echo y|del %tongbu%\%%m >nul 2>nul
)
for /f %%n in (butong.txt) do (
	echo y|rd %tongbu%\%%n >nul 2>nul
)
del butong.txt>nul 2>nul
echo=
echo 反向处理完成...
goto end
::>>>>>>>>>>>>>>>>>>出错提示
:源文件夹不存在
echo=
echo %yuan% 不存在，请检查...
goto end
:目标文件夹不存在
echo %tongbu% 不存在，请检查...
goto end
:U盘出错
echo U盘没有准备好或不可写，请检查。
goto end
:end
echo=
echo 按任意键退出...
pause>nul
复制代码