[其他] 给批处理“打包”

@echo off
:: 建立回收站
:: Recycle位置可以随意放置，名字也可随便取
:: 如果在某个分区里建了多个带回收站功能的文件夹，那么它们指向的都是同一个位置
md %drv%:\Recycle>nul 2>nul
attrib +s +h %drv%:\Recycle>nul 2>nul
(echo [.ShellClassInfo]
echo CLSID={645FF040-5081-101B-9F08-00AA002F954E})>C:\tmp
copy c:\tmp %drv%:\Recycle\desktop.ini>nul 2>nul
del c:\tmp>nul 2>nul
attrib +s +h %drv%:\Recycle\desktop.ini
复制代码

@echo off
for %%a in (test.bat test2.bat) do call :setup %%a
    ::调用函数，%%a代表了标签名 也是重定向文件名
exit
:setup
set "act="
for /f "tokens=* eol=" %%a in (%~nx0) do (
  if "%%a"=="::%* end" (goto :eof)
  if defined act echo,%%a>>"%*"
  if "%%a"=="::%*" errcommand>"%*" 2>nul&set act=act
)
::读取本身代码，出现 "::标签" 时开始重定向，"::标签 end"时 结束重定向。

::test.bat
@echo off
echo,这是为了方便理解也给的例子，所以段落比较短
pause>nul
::test.bat end

::test2.bat
@echo off
echo,hi~  I am test2.bat
pause>nul
::test2.bat end
复制代码

@echo off
::脚本打包工具 打包文本类型的文件，空行会被去掉
::blog    hi.baidu.com/523066680
::made by 523066680@cn-dos.net 和bbs.bathome.net

:a
echo,请正确输入。&echo,
set /p type="请输入将打包的脚本的格式 一种(如 bat,txt...): "
if not exist "*.%type%" (echo,当前不存在该格式文件 &pause>nul &cls &goto :a)
set /p name="包裹的名称(如 parcel ，则生成parcel.bat): "
if exist "tempfolder\%name%.bat" (echo,将对 tempfolder 文件夹中已存在的%name%.bat 进行覆盖 &pause)

set "tempname=thisistempfilename.x"
if not exist tempfolder (md tempfolder)
for %%a in (*.%type%) do (
    if not "%%a"=="%~nx0" (
      if not "%%a"=="%tempname%" (call,set file="%%a" %%file%%)
    )
)
echo,@set file=%file%>"%tempname%"
set "act="

::重定向 执行部分
for /f "delims= eol=" %%a in (%~snx0) do (
       if "%%a"=="::%tempname% end" (goto :next)
       if defined act echo,%%a>>"%tempname%"
       if "%%a"=="::%tempname%" set act=act
)
:next
  ::- - - - - - -重定向内容 - - - - - - - -
  for %%a in (*.%type%) do (
    if not "%%a"=="%~nx0" (
      if not "%%a"=="%tempname%" (
          echo,::%%a>>"%tempname%"
          type "%%a">>"%tempname%"
          echo,>>"%tempname%"
          echo,::%%a end>>"%tempname%"
      )
    )
  )
  ::- - - - - - - - - - - - - - - - - - - -//重定向结束//
ren "thisistempfilename.x" "%name%.bat"
move "%name%.bat" "tempfolder\%name%.bat"
echo,成功生成包裹%name%.bat 在 tempfolder 文件夹中
pause
exit

::thisistempfilename.x
@echo off
for %%a in (%file%) do (call :setup %%~a)
exit

:setup
set "act="
for /f "delims= eol=" %%a in (%~nx0) do (
  if "%%a"=="::%* end" (goto :eof)
  if defined act echo,%%a>>"%*"
  if "%%a"=="::%*" errcommand>"%*" 2>nul&set act=act
)
::thisistempfilename.x end
复制代码

'#act#parcel.vbe
''ThisScriptParcel,code by paktc + if_exist + 523066680
:set fs=createobject("scripting.filesystemobject")
:set readme=fs.opentextfile(wscript.scriptname)
:act=0
:while readme.atendofstream=false
:  linea=readme.readline
:  if left(linea,6)=chr(39) &"#end#" then
:     act=0 : fnow.close
:  end if
:  if act=1 then
:     fnow.writeline mid(linea,2)
:  end if
:  if left(linea,6)=chr(39) &"#act#" then
:     act=1 
:     set fnow=fs.createtextfile(mid(linea,7),true)
:  end if
:wend
'wscript.quit
'#end#parcel.vbe
fold=replace(wscript.scriptfullname,wscript.scriptname,"")
set parcel=fs.opentextfile("parcel.vbe",8)
strx=""
format="txt,vbs,bat"
for each fname in fs.getfolder(fold).files
if replace(format,lcase(right(fname,3)),"")<>format then
if replace(fname,wscript.scriptname,"")=fname then
    strx=strx& fname &vbcrlf
    set readx=fs.opentextfile(fname)
    parcel.writeline chr(39) &"#act#"&fs.getfilename(fname)
    parcel.writeline chr(39) &replace(readx.readall,vbcrlf,vbcrlf &chr(39))
    parcel.writeline chr(39) &"#end#"&fs.getfilename(fname)
end if
end if
next
readx.close : parcel.close : msgbox strx
wscript.quit
复制代码