[文本处理] 【已解决】批处理如何自动生成十位数的序列号？

xxpinqz

中校

Rank: 6 Rank: 6

帖子: 491
积分: 2671
技术: 119
捐助: 0
注册时间: 2008-11-19

3楼

发表于 2013-5-27 21:42 | 只看该作者

@echo off&setlocal enabledelayedexpansion
set /a p=p1=p2=p3=p4=p5=0
(for /f "tokens=1* delims=-" %%a in (a.txt) do (
  set /a 1/%%a 2>nul&&set "str=%%a-%%b"||(
    for /f "tokens=1* delims=、" %%c in ("%%a") do (
      set /a 1/%%c 2>nul&&set /a p4+=100,p5=0||(
        if not "%%d"=="" (
          set /a p2+=1000000,p3=p4=p5=0
        ) else (
          for /f "tokens=1,2 delims=）" %%e in ("%%a") do (
            set /a 1/%%e 2>nul&&set /a p5+=1||(
              if not "%%f"=="" (
                set /a p3+=10000,p4=p5=0
              ) else (
                set /a p1+=100000000,p2=p3=p4=p5=0
              )
            )
          )
        )
      )
    )
    set /a p=!p1!+!p2!+!p3!+!p4!+!p5!
    set "str=0!p!_%%a"
  )
  echo,!str!
))>b.txt
复制代码

初学BAT，非专业。代码不适当之处还望前辈们多多指点。在此表示感谢！

xxpinqz

中校

Rank: 6 Rank: 6

帖子: 491
积分: 2671
技术: 119
捐助: 0
注册时间: 2008-11-19

4楼

发表于 2013-5-27 21:48 | 只看该作者

本帖最后由 xxpinqz 于 2013-5-27 22:46 编辑

只测了你举的例子，没测压缩包的，所以注意下：
后两句FOR中的delims=、和delims=）是全角字符

供参考，自个儿看的都有点头大。。。
大体思路：
p1-p5分别代表第几个层次
先用-号分割，如果第一列是纯数字则直接输出；（日期开头的行）
如果非纯数字：再用、和）进行分割，如果第二列为空，则为p1 （宪法。。。）
如果不为空则分别判断第一列是否为纯数字，然后分别记为p4,p2,p5,p3
定义完某一层次的序号后同时清除之后层次的数值
最后定义出前缀p及str
第一序列不能超过21个,其他子项不能超99个

初学BAT，非专业。代码不适当之处还望前辈们多多指点。在此表示感谢！

Rank: 4

帖子: 172
积分: 403
技术: 2
捐助: 0
注册时间: 2008-5-11

5楼

发表于 2013-5-27 23:32 | 只看该作者

本帖最后由 pan528 于 2013-5-27 23:34 编辑

回复 4# xxpinqz

感谢回帖！思路很巧妙！
但，生成的文本从第五级目录的第二个数字开始出错；导致整体出错，以a.rar为例，出错200多处。。。
可能是贴上的例子造成的。
我没有看明白，还没有找到原因，请楼上帮助解决一下。

terse

中将

Rank: 8 Rank: 8

帖子: 2324
积分: 9712
技术: 471
捐助: 0
注册时间: 2008-2-25

6楼

发表于 2013-5-27 23:33 | 只看该作者

@echo off&setlocal enabledelayedexpansion
set /a a=b=c=d=e=100
(for /f "delims=" %%i in (a.txt) do (
    set str=%%i&set t=!str:~,10!
    for /l %%j in (0 1 9) do set t=!t:%%j=!
        if "!t!" == "--" (echo;%%i) else (
           if "!t:~,1!" == "、" (
              set /a d+=1,e=100
           ) else if "!t:~,1!" == "）" (
                  set /a "e+=1"
             ) else (
               for %%j in (一 二 三 四 五 六 七 八 九 十) do set t=!t:%%j=!
               if "!t:~,1!" == "、" (
                  set /a "b+=1,c=d=e=100"
               ) else if "!t:~,2!" == "（）" (
                         set /a "c+=1,d=e=100"
                      ) else set /a "a+=1,b=c=d=e=100"
            )
        echo !a:~-2!!b:~-2!!c:~-2!!d:~-2!!e:~-2!_%%i
   )
))>b.txt
pause
复制代码

1 评分人数

Batcher: 乐于助人技术 + 1

Rank: 4

帖子: 172
积分: 403
技术: 2
捐助: 0
注册时间: 2008-5-11

7楼

发表于 2013-5-27 23:54 | 只看该作者

回复 6# terse

高手啊，通过全部测试！谢谢！
好好学习、学习！

xxpinqz

中校

Rank: 6 Rank: 6

帖子: 491
积分: 2671
技术: 119
捐助: 0
注册时间: 2008-11-19

8楼

发表于 2013-5-28 01:20 | 只看该作者

回复 5# pan528
原来觉得用for直接分割比较快点，没考虑到同时出现、）的情况，稍微改下。不过还是有致命伤的，你还是6楼的代码。
怎么就没想到分成两位数在组合起来呢~~

@echo off&setlocal enabledelayedexpansion
set /a p=p1=p2=p3=p4=p5=0
(for /f "tokens=1* delims=-" %%a in (a.txt) do (
  set "str=%%a"
  set /a 1/%%a 2>nul&&set "str=%%a-%%b"||(
    for /f "tokens=1* delims=、" %%c in ("!str:~,5!") do (
      set /a 1/%%c 2>nul&&set /a p4+=100,p5=0||(
        if not "%%d"=="" (
          set /a p2+=1000000,p3=p4=p5=0
        ) else (
          for /f "tokens=1* delims=）" %%e in ("!str:~,5!") do (
            set /a 1/%%e 2>nul&&set /a p5+=1||(
              if not "%%f"=="" (
                set /a p3+=10000,p4=p5=0
              ) else (
                set /a p1+=100000000,p2=p3=p4=p5=0
              )
            )
          )
        )
      )
    )
    set /a p=p1+p2+p3+p4+p5
    set "str=0!p!_%%a"
  )
  echo,!str!
))>b.txt
复制代码

1 评分人数

Batcher: 乐于助人技术 + 1

初学BAT，非专业。代码不适当之处还望前辈们多多指点。在此表示感谢！

Rank: 4

帖子: 172
积分: 403
技术: 2
捐助: 0
注册时间: 2008-5-11

9楼

发表于 2013-5-28 09:25 | 只看该作者

回复 6# terse

六楼的思路更简洁：分别用过滤阿拉伯数字和汉字数字的方法，锁定第二级到第五级目录及子项主文；剩下的情况即为第一级目录了。实在是妙啊！

Rank: 4

帖子: 172
积分: 403
技术: 2
捐助: 0
注册时间: 2008-5-11

10楼

发表于 2013-5-28 09:29 | 只看该作者

回复 8# xxpinqz

谢谢修改，已通过测试。