[文件操作] 批处理如何将一个txt文本平分为指定等份？

@echo off
setlocal EnableDelayedExpansion
for /f "delims=" %%i in (a.txt) do set/a b+=1
set/a c=%b%/4
set/a d=%b%%%4
set e=1
set f=-%d%
for /f "delims=" %%j in (a.txt) do (
echo %%j>>!e!.txt
 set/a f+=1
if !f! GEQ %c% set/a e+=1 & set f=0
)
endlocal
pause
复制代码

@echo off&setlocal enabledelayedexpansion
set "sf=tt.txt"
set /a id=4,t=id-1,n=1
for /f "tokens=2 delims=:" %%a in ('find /v /c "" "%sf%"') do set /a x=%%a%%id,z=y=%%a/id
if %x% equ %t% set /a z=y+=1
for /l %%a in (1,1,%id%) do (
   if %%a equ %id% (sed -n !n!,$p "%sf%" >%%a.txt) else sed -n !n!,!z!p "%sf%" >%%a.txt
   set /a n=z+1,z+=y
)
复制代码

@echo off&setlocal enabledelayedexpansion
set /a m=4,j=m-1
for /f "tokens=*" %%i in ('find /c /v "" ^< a.txt') do set /a "n=%%i,i=n/4"
for /l %%i in (1 1 %j%) do (
    set /a n-=i
    more  +!n! a.txt >$a_%%i.txt
    sort /+5000 a.txt | more +!i! | sort /+5000 |findstr "." >#
    move # a.txt
)
move a.txt $a_%m%.txt
pause
复制代码

@echo off&setlocal enabledelayedexpansion
set "sf=t t.txt"
set /a id=4,t=id-1
::sf为源文件名称，id为分几个文件,t用来判断余数及循环。
for /f "tokens=2 delims=:" %%a in ('find /v /c "" "%sf%"') do set /a x=%%a%%id,z=y=%%a/id
if %x% equ %t% set /a z=y+=1"
::如果余数等于分割的文件数id-1(%t%),则前id-1个文件各多加1行.否则多余行数全添加至最后一个文件
set "com=usebackq delims="
for /l %%i in (1,1,%t%) do call :sc %%i "!com!"
more +!m! <"%sf%">%id%.txt
exit /b
:sc
(for /f %2 %%a in ("%sf%") do (
  echo %%a
  set /a m+=1,"1/(y-m)" 2>nul||(set /a y+=z&set "com=usebackq skip=!m! delims="&goto :eof)
))>%~1.txt
复制代码