[文本处理] [已解决]批处理如何添加和去除BAT代码里多个指定行前面::字符？

@echo off&setlocal enabledelayedexpansion
for /f "tokens=3" %%i in ('find /v /c "" 1.txt') do set /a a=%%i
for /f "tokens=1,2 delims=:" %%i in ('findstr /n  /b  "::" 1.txt') do set /a b+=1
if "!b!"=="" exit
if "!b!"=="!a!" exit
set /p aa=要添加::请输入y 去除::输入n:
for /f "delims=" %%i in (1.txt) do (
set str=%%i
if "!aa!"=="n" (
if "!str:~0,2!"== "::"  (echo !str:~2!) else echo !str! ) 
if "!aa!"=="y" ( 
if not "!str:~0,2!"== "::"  (echo ::!str!) else echo !str!) 
)  
pause
复制代码

for /f "delims=:" %%i in ('findstr/in "echo.*>>.%%4%%\.txt" a.bat')do call set ns=%%ns% %%i 
复制代码

@echo off
set fs=a.bat
set fd=b.bat
rem 下一行表示 加/减 :: 在第一个数前附 +/- 的行序号(空行计入序号)
set ns=+2 3 4 6
set "f=%ns:~,1%1"
set "ns=%ns:~1%"
for /f "delims=:" %%i in ('findstr/nb "::" "%fs%"')do set/a #%%i=1
for /f "delims=:" %%i in ('findstr/nb ":::" "%fs%"')do set "##%%i=:"
for /f "delims=:" %%i in ('findstr/nb ":" "%fs%"'
  )do if not defined #%%i set "##%%i=:"
for %%i in (%ns%)do (
     if defined #%%i (
        if %f% lss 0 set fg=y&set/a _%%i=f)else (
        if %f% gtr 0 set fg=y&set/a _%%i=f)
)
if not defined fg echo 不需要更改&goto :end
cd.>"%fd%"
for /f "tokens=1* delims=: " %%i in ('findstr/n .* "%fs%"')do (
   if defined _%%i (>tem.yky echo.%%j&call :yky %%i)else (
     (if defined #%%i set/p=::<nul
     if defined ##%%i set/p=:<nul
     echo.%%j)>>"%fd%"))
del tem.yky
echo ok&goto :end
:yky
call set xx=%%_%1%%
if %xx% gtr 0 (
(set/p=::<nul
  call set/p=%%##%1%%<nul&type tem.yky)>>"%fd%"&goto :eof)
for /f "tokens=* delims=: " %%i in (tem.yky)do (
   (call set/p=%%##%1%%<nul
   echo.%%i)>>"%fd%" &goto :eof)
:end
pause
复制代码

set f=1&set/p f=请输入1或直接回车选择添加:: 其他为去掉::
set ns=&if %f% neq 1 set/a f=-1
for /f "delims=:" %%i in ('findstr/in "echo.*>.*%%4%%\.txt" "%fs%"')do call set ns=%%ns%% %%i
复制代码