[视频教程]批处理基础视频教程[视频教程]VBS基础视频教程批处理在线视频分享
返回列表 发帖

回复 41楼 的帖子

本帖最近评分记录
zqz0012005 技术 +1 吃的盐多,过的桥多,老成精了 2010-1-14 12:44

这个评论果然中肯!这样的命令和用法也能联想到一起,还能奏奇效,不服不行!

TOP

41楼的兄弟果然厉害,我也想到FC,但没想不出解决办法。
再想来,应该可以依靠类似“多线程”的方法来同时打开2个FOR来做文本读取,但控制输出顺序。
因为变量空间不同,必须依靠临时文件来做到这点,比如可以将控制信息写入流文件3.txt:ctrl.txt。

CMD要是能够实现内存映射,多进程使用公共变量就好了。。

TOP

这是刚想到的,没41楼的巧妙
  1. @echo off
  2. (for /f "delims=" %%a in ('findstr /n .* a.txt') do echo [%%a)>ab.txt
  3. find /v /n "" b.txt|more>>ab.txt +2
  4. for /f "tokens=1* delims=:]" %%a in ('sort ab.txt') do echo;%%b
  5. pause
复制代码

[ 本帖最后由 zm900612 于 2011-2-22 18:17 编辑 ]

TOP

41楼的改进思路,相信这能终结双文本同时输出的难题:
  1. @echo off
  2. findstr /n .* 1.txt>tmp1
  3. find /n /v "" 2.txt|more>tmp2 +2
  4. for /f "tokens=2*delims=]:" %%a in ('fc /lb1000 /n tmp1 tmp2^|sort') do echo;%%b
  5. del /q tmp?
  6. pause
复制代码

TOP

49楼的代码刚看过
改了一个findstr
少了一个find
代码和思路都有创新
不过限于算法思想
对于两个以上的文本就无法实现交替输出了

另外
find /n /v "" 2.txt|more>tmp2 +2
可以改用
find /n /v "" <2.txt>tmp2
更好些
天的白色影子

TOP

好办法,避开了多余的显示,省一个more。
其实如果文件数是2的倍数,还是可以这样用的,不过效率就难说了

TOP

楼上说的是递归算法吗?
也就是先a,c交替得到ac
再b,d交替得到bd
再ac,bd交替得到abcd
这是需要文件数是二的乘方吧

另外这只是原型代码
真正实用还要考虑一些细节
比如文本的末行没有\r\n
天的白色影子

TOP

本帖最后由 zm900612 于 2011-7-18 20:27 编辑
  1. @echo off
  2. (for /f "delims=" %%a in (1.txt) do (
  3.     endlocal
  4.     echo;%%a
  5.     setlocal enabledelayedexpansion
  6.     set /p t2=
  7.     if defined t2 echo;!t2!
  8. ))<2.txt>合并.txt
  9. ::由于可以有两个不同的输入来源并存,所以双文本合并就成为轻而易举的事了
复制代码

TOP

  1. @echo off&setlocal enabledelayedexpansion
  2. (for /l %%a in (1,1,50) do set /p n%%a=)<1.txt
  3. (for /l %%a in (1,1,50) do set /p m%%a=)<2.txt
  4. for /l %%a in (1,1,50) do (
  5.     if not "!n%%a!"=="" echo;!n%%a!
  6.     if not "!m%%a!"=="" echo;!m%%a!
  7. )
  8. pause
复制代码

TOP

本帖最后由 ai20110304 于 2018-9-5 23:13 编辑
  1. @echo off & setlocal enabledelayedexpansion
  2. cd /d %~dp0
  3. ::思路:通过行数定位结合more +n命令。
  4. set /a nn=0
  5. for /f "delims=" %%i in (1.txt) do (
  6. echo;%%i
  7. call :lp !nn! & set /a "nn+=1"
  8. )
  9. pause>nul & goto :eof
  10. :lp
  11. ::more 第一行是以0计数开始
  12. for /f "delims=" %%x in ('more +%1 2.txt') do echo;%%x & goto :eof
复制代码
附件: 您需要登录才可以下载或查看附件。没有帐号?注册
我就是我,不一样的烟火!

TOP

返回列表