[文件操作] [分享]超级文件文档搜索批处理

@echo off
mode con lines=17 cols=60
color 1f
title 文件索引       chenlian  --20081218
rem 本程序的特点是可以快速的查找你想找的文件、文件夹、和文字，并可快速打开搜索的结果。
rem 例如查找"i love you"的文件或文件夹，或者在指定文件类型里查找含有"i love you"文字的文件，并迅速打开。
rem 可以单个或全部删除搜索到的文件。
rem 2007-08-30 @XP CMD

:0
cls
echo.
echo   本机所有磁盘列表:
echo -----------------------
echo 盘符  磁盘类型
echo.
setlocal enabledelayedexpansion
for /f "skip=1 tokens=1,2 delims=\" %%a in ('fsutil fsinfo drives^|find /v ""') do (
    set aa=%%a
    set aa=!aa:~-2!
    for %%i in (!aa!) do fsutil fsinfo drivetype %%i
)
endlocal
echo ------------------------
set cpan=%~dp0
set cpan=%cpan:~0,-1%
echo  [ 默认查找路径: %cpan%\ ]&echo.
echo  在哪里查找？[请输入一个盘符或拖入待查找的文件夹]
set/p cpan= : 
if "%cpan:~3,1%"=="\" set cpan=%cpan:~1,-1%
if not exist %cpan:~0,1%: echo 路径不存在!  任意键返回...&pause>nul&goto 0
set ziliao=:
echo  (查找内容前加[\]忽略子目录,加[/]在指定文件中找文字.)
echo  (查找文档时可用通配符号或[?]进行模糊查找.       )
echo  请输入要查找的文档名[如：*.doc; temp.txt]
set/p ziliao= 或者输入想在某类文档中查找的文字[如：/工作安排; /第十七章] : 
cls
echo.&echo.&echo  执行中!
echo  在路径[ %cpan% ]中搜索[ %ziliao% ].
echo.&echo  正在查找，请稍候 ...
set "ziliao=%ziliao:"=%"
if "%ziliao%"==":" goto 0
if exist 查找结果.txt del/f/q 查找结果.txt
if exist 查找结果.czjg del/f/q 查找结果.czjg
set dirrs=dir/a/s/b/d
set zimulu=查找
set ads=/s
if not "%cpan:~2,1%"=="\" set cpan=%cpan:~0,1%:
if "%ziliao:~0,1%"=="\" (if "%ziliao:~1,1%"=="/" (set ziliao=%ziliao:~2,100%&set zimulu=忽略&set ads=&goto 2) else (set ziliao=%ziliao:~1,100%&set dirrs=dir/a/b/d&set zimulu=忽略&goto cazao))
if "%ziliao:~1,1%"=="\" set dirrs=dir/a/b/d&set zimulu=忽略&set ads=
if "%ziliao:~0,1%"=="/" (if "%ziliao:~1,1%"=="\" (set ziliao=%ziliao:~2,100%&set ads=&goto 2) else (set ziliao=%ziliao:~1,100%&goto 2)) else (if "%ziliao:~0,1%"=="\" set ziliao=%ziliao:~1,100%)

:cazao
if "%leixin%"=="" (set neixin=全部) else (set neixin=.%leixin%)
>查找结果.txt echo 查找时间: [ %date:~0,10% %time:~0,5% ]
>>查找结果.txt echo.
>>查找结果.txt echo 查找目录: [ %cpan%\ ]
>>查找结果.txt echo.
>>查找结果.txt echo 子 目 录: [ %zimulu% ]
>>查找结果.txt echo.
>>查找结果.txt echo 文件类型: [ %neixin% ]
>>查找结果.txt echo.
>>查找结果.txt echo 查找内容: [ %ziliao% ]
>>查找结果.txt echo.
>>查找结果.txt echo 查找结果:        %dxx%
>>查找结果.txt echo ──────────────────────
%gotoend%

:1
%dirrs% "%cpan%\*%ziliao%*"|findstr /n .>>查找结果.txt
>>查找结果.txt echo ──────────end────────────
if %ERRORLEVEL%==1 cls&echo.&echo  搜索类型: [ 文件或文件夹 ]&echo.&echo  搜索目录: [ %cpan%\ ]&echo.&echo  子 目 录: [ %zimulu% ]&echo.&echo  结    果: 没有找到与"%ziliao%"有关的文件或文件夹!&echo.&echo  按任意键返回... &pause>nul&goto 0
start "%SystemRoot%\system32\notepad.exe" 查找结果.txt
cls
for /f "tokens=1 delims=:" %%i in ('findstr /n /c:"──────────end────────────" 查找结果.txt') do (set /a hhao=%%i-13)
echo.&echo  查找路径: [ %cpan%\ ]
echo.&echo  查找内容: [ %ziliao% ]
echo.&echo  找到结果: [ %hhao%个 ]
echo.&echo  请在弹出的窗口在查看详细内容.
echo.&echo  如需打开相应文件,请输入查找结果前对应的数字并回车.
echo.&echo  数字前加[d]删除对应的文件;[0]删除所有搜索到的文件.
echo.&echo  数字前加[.]用记事本打开对应的文件.&echo.
:czwj
set/p dakai= ^>^>: 
set sta=start ""
set paus=
if "%dakai%"=="0" cls&echo  下列文件删除失败:&set paus=pause&for /f "tokens=3 delims=:" %%i in ('findstr /b . 查找结果.txt') do (if exist "%cpan:~0,1%:%%i" del/q/f/a "%cpan:~0,1%:%%i" 2>nul)
%paus%
if "%dakai:~0,1%"=="." set dakai=%dakai:~1,5%&set sta=notepad.exe
if /i "%dakai%"=="d" goto 0
if /i "%dakai:~0,1%"=="d" set dakai=%dakai:~1,5%&set sta=del/q/f/a
set/a jisuan=10000-%dakai%
if "%jisuan%"=="10000" goto 0
for /f "tokens=3 delims=:" %%i in ('findstr /b "%dakai%:" 查找结果.txt') do (%sta% "%cpan:~0,1%:%%i")
goto czwj

:2
cls
echo.&echo  扩展名前加[.]关键词被视为整体;后加[/x]区分大小写.&echo.
echo  文件扩展名默认为TXT格式.&echo.
set adi=/i&set dxx=(搜索不分大小写)
set sdc=
set leixin=txt
set/p leixin= 请输入文件扩展名(如"htm",保持默认请直接回车) :  
echo.&echo  正在搜索字符串，请稍候 ...
if /i "%leixin%"=="/x" set leixin=:&set dxx=(搜索区分大小写)&set adi=
if /i "%leixin:~-2,2%"=="/x" set leixin=%leixin:~0,-2%&set dxx=(搜索区分大小写)&set adi=
if "%leixin:~0,1%"=="." (if "%leixin:~-1%"=="." (set leixin=txt&set sdc=/c:) else (set leixin=%leixin:~1,100%&set sdc=/c:)) else (set sdc=)
set gotoend=goto :eof
call :cazao
ren 查找结果.txt 查找结果.czjg
findstr %ads% %adi% %sdc%"%ziliao%" "%cpan%\*.%leixin%"|findstr /n .>>查找结果.czjg 2>nul
>>查找结果.czjg echo ──────────end────────────
if %ERRORLEVEL%==1 cls&echo.&echo  搜索类型: [ 文档字符串 ]&echo.&echo  搜索目录: [ %cpan%\ ]&echo.&echo  子 目 录: [ %zimulu% ]&echo.&echo  文件类型: [ .%leixin% ]&echo.&echo  结    果: 没有找到存在"%ziliao%"的文档! 请检查大小写再试试.&echo.&echo  按任意键返回... &pause>nul&goto 0
ren 查找结果.czjg 查找结果.txt
start "%SystemRoot%\system32\notepad.exe" 查找结果.txt
cls
for /f "tokens=1 delims=:" %%i in ('findstr /n /c:"──────────end────────────" 查找结果.txt') do (set /a hhao=%%i-13)
echo.&echo  查找路径: [ %cpan%\ ]
echo.&echo  字符内容: [ %ziliao% ]
echo.&echo  找到结果: [ %hhao%条 ]
echo.&echo  请在弹出的窗口在查看详细内容.
echo.&echo  如需查看文件请输入查找结果前对应的数字并回车.
echo.&echo  数字前加[.]用记事本打开;[d]删除文件;[0]删除所有!&echo.
:dk
set/p dakai= ^>^>: 
set sta=start ""
set paus=
if "%dakai%"=="0" cls&echo  下列文件删除失败:&set paus=pause&for /f "tokens=3 delims=:" %%i in ('findstr /b . 查找结果.txt') do (if exist "%cpan:~0,1%:%%i" del/q/f/a "%cpan:~0,1%:%%i" 2>nul)
%paus%
if "%dakai:~0,1%"=="." set dakai=%dakai:~1,5%&set sta=notepad.exe
if /i "%dakai%"=="d" goto 0
if /i "%dakai:~0,1%"=="d" set dakai=%dakai:~1,5%&set sta=del/q/f/a
set/a jisuan=10000-%dakai%
if "%jisuan%"=="10000" goto 0
for /f "tokens=3 delims=:" %%i in ('findstr /b "%dakai%:" 查找结果.txt') do %sta% "%cpan:~0,1%:%%i"
goto dk
复制代码