[网络连接] [已解决]批处理怎样去掉ping输出的不需要的内容和增加声音？

@echo off 
:a
echo Wscript.Sleep Wscript.Arguments(0) * 1000>Delay.vbs 
Delay.vbs 5  
echo OK!
echo %date% %time% >>log.txt 
ping 192.168.1.1 -n 1 >>log.txt
goto a
复制代码

@echo off
echo.strSoundFile = "%SystemRoot%\Media\Windows XP 注销音.wav">hanye.vbs
echo.Set objShell = CreateObject("Wscript.Shell")>>hanye.vbs
echo.strCommand = "sndrec32 /play /close " ^& chr(34) ^& strSoundFile ^& chr(34)>>hanye.vbs
echo.objShell.Run strCommand, 0, True>>hanye.vbs
:s
ping -n 6 127.1 >nul 2>nul
ping -n 1 192.168.1.1 >nul 2>nul||cscript //nologo hanye.vbs
goto:s
复制代码

@echo off
:s
ping -n 6 127.1 >nul 2>nul
ping -n 1 192.168.1.1 >nul 2>nul||start "" "%ProgramFiles%\Ringz Studio\Storm Codec\mplayerc.exe" /play /close /minimized "G:\Documents\My Music\What Becomes Of Us.mp3"
goto:s
复制代码

@echo off
more +8<%~fs0>hanye.vbs
:s
ping -n 6 127.1 >nul 2>nul
ping -n 1 192.168.1.2 >$temp$ 2>&1
if ERRORLEVEL 1 cscript //nologo hanye.vbs
(for /f "tokens=1* delims=:" %%a in ('findstr /n .* $temp$') do if %%a==4 echo.%date% %time%&echo.%%b)>>日志.log
goto:s
strSoundFile = "%SystemRoot%\Media\Windows XP 注销音.wav"
Set objShell = CreateObject("Wscript.Shell")
strCommand = "sndrec32 /play /close " & chr(34) & strSoundFile & chr(34)
objShell.Run strCommand, 0, True
复制代码

@echo off
set "hanye="%ProgramFiles%\Ringz Studio\Storm Codec\mplayerc.exe" /play /close /minimized "G:\Documents\My Music\What Becomes Of Us.mp3""
:s
ping -n 6 127.1 >nul 2>nul
ping -n 1 192.168.1.2 >$temp$ 2>&1
if ERRORLEVEL 1 start "" %hanye%
(for /f "tokens=1* delims=:" %%a in ('findstr /n .* $temp$') do if %%a==4 echo.%date% %time%&echo.%%b)>>日志.log
goto:s
复制代码