[文本处理] 【已解决】BAT：多个代码如何合并成一个

@echo off
for /f "skip=1 delims=" %%i in ('dir /b /a-d /o-n /s "d:\分解\数据1\0001\lishi\*.txt"') do (
copy "%%i" "d:\分解\数据2\0001.txt"
goto :eof
)

@echo off
for /f "skip=1 delims=" %%i in ('dir /b /a-d /o-n /s "d:\分解\数据1\0002\lishi\*.txt"') do (
copy "%%i" "d:\分解\数据2\0002.txt"
goto :eof
)

......

@echo off
for /f "skip=1 delims=" %%i in ('dir /b /a-d /o-n /s "d:\分解\数据1\1330\lishi\*.txt"') do (
copy "%%i" "d:\分解\数据2\1330.txt"
goto :eof
)

上述代码是将一文件夹内倒数第二行的txt文本数据导出
现在欲将上述若干代码合而为一，自己试写了如下代码，但是只能导出0001.txt，错在哪？

@echo off&setlocal enabledelayedexpansion
for /l %%x in (10001,1,11330) do (
    set y=%%x
pushd "d:\分解\数据1\!y:~1!\lishi\"
for /f "skip=1 delims=" %%i in ('dir /b /a-d /o-n /s *.txt') do (
    copy "%%i" "d:\分解\数据2\!y:~1!.txt"
    goto :eof
)
)
复制代码

1 评分人数

pcl_test: 感谢给帖子标题标注[已解决]字样PB + 2

WHY

上校

Rank: 6 Rank: 6

帖子: 1442
积分: 3193
技术: 556
捐助: 0
注册时间: 2015-7-19

2楼

发表于 2015-10-5 14:39 | 只看该作者

@echo off&setlocal enabledelayedexpansion
for /l %%x in (10001,1,11330) do (
    set y=%%x&set "flag="
    pushd "d:\分解\数据1\!y:~1!\lishi\"
    for /f "skip=1 delims=" %%i in ('dir /b /a-d /o-n *.txt') do (
        if not defined flag (
            copy "%%i" "d:\分解\数据2\!y:~1!.txt"
            set flag=1
        )
    )
    popd
)
复制代码

1 评分人数

思想之翼: 感谢技术 + 1

TOP

返回列表

[新手上路]批处理新手入门导读	[视频教程]批处理基础视频教程	[视频教程]VBS基础视频教程	[批处理精品]批处理版照片整理器
[批处理精品]纯批处理备份&还原驱动	[批处理精品]CMD命令50条不能说的秘密	[在线下载]第三方命令行工具	[在线帮助]VBScript / JScript 在线参考

[文本处理] 【已解决】BAT：多个代码如何合并成一个

[收藏此主题] [关注此主题的新回复]

[通过 QQ、MSN 分享给朋友]