[已解决]批处理怎样获取文件夹路径并根据结果生成文件夹？

001011 · 发表于 2011-6-26 17:10:07

本帖最后由 001011 于 2011-6-26 21:28 编辑

比如文件夹路径是：G:\文件\九\0501\06.21\2010-10套-目的地-1-10
首先获取文件夹路径然后根据最后面的1-10（有可能是其他数字，但是“-”的左右最多不超过3位）生成对应的文件夹：1、2、3、4、5、6、7、8、9、10
如果路径是：G:\文件\九\0501\06.21\2010-10套-目的地-102-108，生成对应的文件夹为：102、103、104、105、106、107、108
谢谢指教！

001011 · 发表于 2011-6-26 17:12:13

“-”的左右,不会出现左大右小的现象

001011 · 发表于 2011-6-26 17:13:33

这个可以获取路径：
@ECHO OFF
set AAA=%0
FOR %%i in (%AAA%) do (echo %%~dpi>a.txt)
type a.txt
pause

tmplinshi · 发表于 2011-6-26 17:33:10

文件夹生成到哪里？

batman · 发表于 2011-6-26 17:33:53

@echo off&setlocal enabledelayedexpansion
set "paths=G:\文件\九\0501\06.21\2010-10套-目的地-1-10"
for %%a in (%paths%) do (
set "str=%%~na"&set "str=!str:-=.!"
for %%a in (!str!) do (
set "max=%%~xa"
for %%b in (%%~na) do set "min=%%~xb"
)
)
for /l %%a in (%min:~1%,1,%max:~1%) do md "%paths%\%%a"

复制代码

001011 · 发表于 2011-6-26 17:36:20

生成在获取文件夹路径的文件夹

001011 · 发表于 2011-6-26 17:39:13

@echo off&setlocal enabledelayedexpansion
set "paths=G:\文件\九\0501\06.21\2010-10套-目的地-1-10"
for %%a in (%paths%) do (
set "str=%%~na"&set "str=!str:-=.!"
for %%a in (!str!) do (
s ...
batman 发表于 2011-6-26 17:33

谢谢您但是我要获取的的路径是有变化的生成的文件夹也是根据路径而变化的

001011 · 发表于 2011-6-26 17:40:05

文件夹生成到哪里？
tmplinshi 发表于 2011-6-26 17:33

谢谢您的回复生成在获取文件夹路径的文件夹

tmplinshi · 发表于 2011-6-26 17:48:47

@echo off
cd /d G:\
for /r /d %%i in (*-*-*) do (
set _path=%%i
setlocal enabledelayedexpansion
for /f "tokens=1,2 delims=?" %%i in ("!_path:-=\!\..?!_path:-=\!") do (
for /l %%a in (%%~ni 1 %%~nj) do md "!_path!\%%a"
)
endlocal
)
pause

复制代码

lvsehuaxue · 发表于 2011-6-26 17:54:54

@echo off
for /f "tokens=1-5 delims=-" %%i in ('dir /s /ad /b G:\文件\九\0501\06.21') do (
for /l %%a in (%%l 1 %%m) do (
md %%i-%%j-%%k-%%l-%%m\%%a
)
)
pause

复制代码

001011 · 发表于 2011-6-26 21:22:58

@echo off
cd /d G:\
for /r /d %%i in (*-*-*) do (
set _path=%%i
setlocal enabledelayedexpansion
for /f "tokens=1,2 delims=?" %%i in ("!_path:-=\!\..?!_path:-=\!") do (
for /l ...
tmplinshi 发表于 2011-6-26 17:48

非常好用非常好的论坛谢谢啦

mstsc · 发表于 2011-6-29 23:30:10

学习中不是很懂

		自动登录	找回密码
密码			注册

[新手上路]批处理新手入门导读	[视频教程]批处理基础视频教程	[视频教程]VBS基础视频教程	[批处理精品]批处理版照片整理器
[批处理精品]纯批处理备份&还原驱动	[批处理精品]CMD命令50条不能说的秘密	[在线下载]第三方命令行工具	[在线帮助]VBScript / JScript 在线参考

[其他] [已解决]批处理怎样获取文件夹路径并根据结果生成文件夹？

评分

评分

浏览过的版块