[分析代码]批处理随机输出数字1~100不重复

523066680 · 发表于 2009-3-16 09:15:50

我试着分析一次哈~

@echo off
for /l %%a in (1,1,100) do (call set _%%random%%_%%a=%%a)
for /f "delims== tokens=2" %%a in ('set _') do (echo %%a)
pause

原理:    %%a从1~100  把他们赋值给变量名“_%random% ” 这样，当把名称有序列出时，对应的值就被打乱了
      但是当出现%random% 两次相同时，就会因变量名相同而把上次的值给替换掉，

            于是，就以_%%random%%_%%a 为名，而%%a是1-100不重复，中间又用 _ 隔开，绝不会出现替代。

后面的一句for就是把变量名有序输出，并显示他们的值。

我只用这个代码做过一个效果：随机打出图像的点，不重复
不知道有没有人能举一个好的应用例子呢，为表感谢分享我会酌情加分的。

[ 本帖最后由 523066680 于 2009-3-16 09:21 编辑 ]

523066680 · 发表于 2009-3-16 12:09:42

我自己顶~
真是的~ 难怪我喜欢写特效，写特效有人加分，写别的东西这么快就沉了

大伙多少说说对这个帖子的观点嘛

wxcute · 发表于 2009-3-16 13:27:52

精彩思路点评：利用随机数作为变量名，再用 SET 显示变量来打乱原有顺序。

当然不是直接用随机数来作变量名，前面加个符号防止不必要的麻烦。

PakTC · 发表于 2009-8-9 19:59:32

这算是利用了批处理的优点吧~

如果用别的语言的话，没这么好利用哟~
我亦有个思路，代码就没那么短了。

@echo off &title Made by PakTC
setlocal enabledelayedexpansion
for /l %%a in (1,1,100) do (set number%%a=%%a)
for /l %%a in (100,-1,1) do (
set /a rand=!random! %% %%a + 1
set /a new%%a=number!rand!,TempNum=number!rand!
set /a number!rand!=number%%a,number%%a=TempNum
)
for /l %%a in (1,1,100) do echo,!new%%a!
pause

复制代码

PakTC · 发表于 2009-8-10 09:55:09

这不是通过100次随机互换

是主次地缩小范围
第一次获取1~100 随机数
然后获取的那个数与100调换

第二次就获取1~99内随机数

=======================
获取并缩小范围,把拿过的数扔出范围。

这样就避免了重复，也保证了随机性

batman · 发表于 2009-8-10 10:53:18

＿%random%_%%a，此为一大提升，很好，很强大！

terse · 发表于 2009-8-10 14:44:20

如果数字大的话是否可考虑这样

@echo off&setlocal enabledelayedexpansion
if "%1" equ "" (
for /f "tokens=2 delims==" %%i in ('"%~s0 b|sort"') do echo %%i
pause&exit
) else for /l %%i in (1 1 100000) do echo !random!!random!!random!_%%i=%%i

复制代码

applba · 发表于 2011-4-26 04:46:29

本帖最后由 applba 于 2011-4-26 04:54 编辑

问题是：
1.你为了获得一个100以内的数，就需要random100次！
如果是值域是1-1000000以内的呢？你是不是要random 100万次吗！

所有说这种方式只适合值域很小的时候……

hanyeguxing · 发表于 2011-4-26 06:26:28

8# applba

什么时候 1~100 等于1 了？

applba · 发表于 2011-4-26 07:38:42

9# hanyeguxing

假如我只需要一个呢

hanyeguxing · 发表于 2011-4-26 08:05:49

1个数字哪来的重复与不重复？

523066680 · 发表于 2011-4-26 09:12:54

本帖最后由 523066680 于 2011-4-26 09:15 编辑

"问题是：
1.你为了获得一个100以内的数，就需要random100次！
如果是值域是1-1000000以内的呢？你是不是要random 100万次吗！"

"这个问题就是在描述事实，但是没有指出问题哇。"

啊喏，random100万次不是主要问题吧？你要说的应该是储存100万个变量这个事情。
这个时候随机数只有五位数，随机性质方面可能有影响，但是可以通过组合随机数达到X位数。
不管怎么想，我觉得为了获得随机数不重复，"random XX次" 始终还是要滴。
我的马甲在4楼写了一个用随机抽取N次的，效率上会差点吧。

如果有一张大尺寸图片要随机渐显，俺也会采用分块的方式渐显，而不是逐像素地显示，
那样太耗时间了

applba · 发表于 2011-4-26 09:28:16

11# hanyeguxing

汗，一个也可以是两个，三个……

applba · 发表于 2011-4-26 09:29:04

12# 523066680

明白了，是我想多了

CrLf · 发表于 2011-4-26 12:45:06

如果对不定死范围，可以这样：

@echo off&setlocal enabledelayedexpansion&echo %time%
set n=1000
(for /l %%a in (1 1 !n!) do (
set /a ra+=!random!/n
set os=!ra! !os! !ra!
)
for %%a in ("!os: %os% =","!") do echo %%~a)
echo %time%&pause

复制代码

几乎不定义临时变量，应该是最快的办法了

		自动登录	找回密码
密码			注册

[新手上路]批处理新手入门导读	[视频教程]批处理基础视频教程	[视频教程]VBS基础视频教程	[批处理精品]批处理版照片整理器
[批处理精品]纯批处理备份&还原驱动	[批处理精品]CMD命令50条不能说的秘密	[在线下载]第三方命令行工具	[在线帮助]VBScript / JScript 在线参考

[其他] [分析代码]批处理随机输出数字1~100不重复

评分

评分

浏览过的版块