网卡的静态IP地址和动态IP地址之间的切换

tomtangfish2 · 发表于 2025-12-23 14:00:47

笔记本电脑会在公司网和家庭网之间来回切换，网卡IP地址要来回切换的，用脚本切换IP地址就方便。

@echo off
title 配置网卡地址工具
mode con cols=70 lines=100 & color 0a
setlocal EnableDelayedExpansion
REM Readed address.txt.
set lineFlag=0
for /f "delims=" %%i in (%~dp0address.txt) do (
set /a lineFlag+=1
if !lineFlag!==1 ( set name=%%i )
if !lineFlag!==2 ( set ip=%%i )
if !lineFlag!==3 ( set subnet=%%i )
if !lineFlag!==4 ( set gateway=%%i )
if !lineFlag!==5 ( set dns=%%i )
)
:menu
::cls
echo:
echo =============================
echo 请选择要进行的操作
echo 1、设置静态IP地址
echo 2、设置动态IP地址
echo 3、退出
echo =============================
set /p choice="选择操作（1/2/3）:"
if "%choice%" == "3" ( exit )
if "%choice%" == "1" ( goto static )
if "%choice%" == "2" (
netsh interface ip set address name=%name% source=dhcp
netsh interface ip set dns name=%name% source=dhcp
)
echo 动态IP地址设置完成。
echo:
echo:
goto menu
)
goto menu
:static
netsh interface ipv4 set address name=%name% static %ip% %subnet% %gateway%
netsh interface ipv4 set dnsservers name=%name% source=static address=%dns% register=primary validate=no
::netsh interface ipv4 add dnsservers name=%name% address=114.114.114.114 index=2 validate=no
echo 静态IP地址设置完成。
echo:
echo:
goto menu

复制代码

把静态IP地址提前写在address.txt中，例如：
以太网
10.238.101.140
255.255.255.0
10.238.101.1
12.118.2.201

jiavip · 发表于 2025-12-23 17:30:53

本帖最后由 jiavip 于 2025-12-23 18:36 编辑

没那么复杂，，

@echo off
if "%1"=="" echo.没有参数输入，按任意键退出！& pause > nul & exit
set name=以太网
set ip=10.238.101.140
set 子掩码=255.255.255.0
set 网关=10.238.101.1
set dns=12.118.2.201
goto,%1
:0
netsh interface ip set address name=%name% source=dhcp
netsh interface ip set dns name=%name% source=dhcp
exit
:1
netsh interface ipv4 set address name=%name% static %ip% %子掩码% %网关%
netsh interface ipv4 set dnsservers name=%name% source=static address=%dns% register=primary validate=no

复制代码

如果是自己用的  上面这个脚本就足够了，简单明了！
把本机 IP,子掩码，网关，DNS写对存好，任意位置，发送快捷方式到桌面或任意地方，
快捷方式 1
修改快捷方式，在文件名的后面空格 0  是动态
复制快捷方式 2
修改快捷方式，在文件名的后面空格 1  是静态
标签 :0 和 :1 就是快捷方式参数的对应值，，，
可以根据自己的喜好修改成自己喜欢的字符，，，如：D 代表动态，，：J 代表静态

脚本可以有很多种写法，最简化，最快捷的才是根本，，，
把脚本写得复杂，有点舍本求远了，，，！

jiavip · 发表于 2025-12-23 17:45:52

我写自己用的脚本，基本都是怎么方便，就怎么写！
多数都是采用参数调用脚本标签，，，，
利用标签的分割性质，在一个脚本里写下不同的命令代码，采用参数调用，，用快捷方式+参数执行，，
一个主体脚本，创建多个快捷方式，实现多个命令调用，实现多个执行效果，这就是BAT 脚本的魅力之一，，，，，

tomtangfish2 · 发表于 2025-12-24 13:37:20

回复 3# jiavip

主题脚本+快捷方式+参数，调用灵魂方便。一直想学这种方法，请高手指点一下怎么优化下面的脚本。
脚本作用是静默安装软件，软件组合写死在脚本中，如17 微信QQWPS360浏览器搜狗WinRAR。希望在安装时能灵活组合软件。

@echo off
setlocal enabledelayedexpansion
echo ================================================
::创建开始页面
:start
echo 选择对应的软件序号进行安装：
echo 1 微信 2 QQ 3 腾讯会议 4 钉钉
echo 6 WPS 7 谷歌浏览器 8 360安全浏览器 9 火狐浏览器
echo 11 搜狗输入法 12 微信输入法 13 百度输入法
echo 16 WinRAR 17 微信QQWPS360浏览器搜狗WinRAR
echo 21 安全卫士 22 网络激活 23 KMS激活 24 解除WPS限制 25 重启电脑
echo 31 关闭UCA 32 打开UCA 33 基础配置 34 驱动安装
echo ===================================================================
echo 61 微信x86
echo 输入程序的序号，按“Enter”进行安装。退出安装程序输入“N”后按“Enter”。
set /p num=
::echo %mun%
if %num% EQU 1 start %~dp0WeChatSetup.exe /S
if %num% EQU 2 start %~dp0QQ.exe /s
if %num% EQU 3 start %~dp0TencentMeeting.exe /silentinstall=0 /Language="zh-cn"
if %num% EQU 4 start %~dp07.8.0-Release.exe /S /NCRC
if %num% EQU 6 start %~dp0WPS_Setup.exe /S -agreelicense
if %num% EQU 7 start %~dp0ChromeSetup.exe
if %num% EQU 8 start %~dp0360se_setup.exe --silent-install=3_1_1
if %num% EQU 9 start /i %~dp0Firefox_Setup.msi /passive
if %num% EQU 11 start %~dp0sogou_pinyin.exe /S
if %num% EQU 12 start %~dp0wetype.exe /s
if %num% EQU 13 start %~dp0BaiduPinyinSetup.exe /s
if %num% EQU 16 start %~dp0winrar.exe /S
if %num% EQU 17 start %~dp0WeChatSetup.exe /S &start %~dp0QQ.exe /s &start %~dp0WPS_Setup.exe /S -agreelicense &start %~dp0360se_setup.exe --silent-install=3_1_1 &start %~dp0sogou_pinyin.exe /S &start %~dp0winrar.exe /S
if %num% EQU 21 start %~dp0anquanweishi.exe /install /silent
if %num% EQU 22 start %~dp0\cmd\callactivatedps.bat
if %num% EQU 23 start %~dp0\KMS_VL_ALL\KMS-VL-ALL_cn.cmd
if %num% EQU 24 reg add HKEY_CURRENT_USER\Software\kingsoft\Office\6.0\plugins\officespace\flogin /V enableForceLoginForFirstInstallDevice /t REG_SZ /d false /f
if %num% EQU 25 start %~dp0reboot.bat
if %num% EQU 31 start %~dp0disableUAC.bat
if %num% EQU 32 start %~dp0EnableUAC.bat
if %num% EQU 33 start %~dp0normalinstall.bat
if %num% EQU 34 start %~dp0runSDIRUS.bat
if %num% EQU 61 start %~dp0WeChatSetup_x86.exe /S
echo ============================================
if %num% EQU n goto end
if %num% EQU N goto end
::pause
goto start
:end

复制代码

谢谢高手指点。

jiavip · 发表于 2025-12-25 02:36:31

根据你那原始脚本修改，，，，

@echo off
Set num=%~1
:start
if %num% EQU 1 start %~dp0WeChatSetup.exe /S
if %num% EQU 2 start %~dp0QQ.exe /s
if %num% EQU 3 start %~dp0TencentMeeting.exe /silentinstall=0 /Language="zh-cn"
if %num% EQU 4 start %~dp07.8.0-Release.exe /S /NCRC
if %num% EQU 6 start %~dp0WPS_Setup.exe /S -agreelicense
if %num% EQU 7 start %~dp0ChromeSetup.exe
if %num% EQU 8 start %~dp0360se_setup.exe --silent-install=3_1_1
if %num% EQU 9 start /i %~dp0Firefox_Setup.msi /passive
if %num% EQU 11 start %~dp0sogou_pinyin.exe /S
if %num% EQU 12 start %~dp0wetype.exe /s
if %num% EQU 13 start %~dp0BaiduPinyinSetup.exe /s
if %num% EQU 16 start %~dp0winrar.exe /S
if %num% EQU 17 start %~dp0WeChatSetup.exe /S &start %~dp0QQ.exe /s &start %~dp0WPS_Setup.exe /S -agreelicense &start %~dp0360se_setup.exe --silent-install=3_1_1 &start %~dp0sogou_pinyin.exe /S &start %~dp0winrar.exe /S
if %num% EQU 21 start %~dp0anquanweishi.exe /install /silent
if %num% EQU 22 start %~dp0\cmd\callactivatedps.bat
if %num% EQU 23 start %~dp0\KMS_VL_ALL\KMS-VL-ALL_cn.cmd
if %num% EQU 24 reg add HKEY_CURRENT_USER\Software\kingsoft\Office\6.0\plugins\officespace\flogin /V enableForceLoginForFirstInstallDevice /t REG_SZ /d false /f
if %num% EQU 25 start %~dp0reboot.bat
if %num% EQU 31 start %~dp0disableUAC.bat
if %num% EQU 32 start %~dp0EnableUAC.bat
if %num% EQU 33 start %~dp0normalinstall.bat
if %num% EQU 34 start %~dp0runSDIRUS.bat
if %num% EQU 61 start %~dp0WeChatSetup_x86.exe /S
if /i %num% EQU n exit
if not "%num%"=="" exit
cls
echo 选择对应的软件序号进行安装：
echo 1 微信 2 QQ 3 腾讯会议 4 钉钉
echo 6 WPS 7 谷歌浏览器 8 360安全浏览器 9 火狐浏览器
echo 11 搜狗输入法 12 微信输入法 13 百度输入法
echo 16 WinRAR 17 微信QQWPS360浏览器搜狗WinRAR
echo 21 安全卫士 22 网络激活 23 KMS激活 24 解除WPS限制 25 重启电脑
echo 31 关闭UCA 32 打开UCA 33 基础配置 34 驱动安装 61 微信x86
echo 输入程序的序号，按“Enter”进行安装。
set /p num=
goto start

复制代码

-------------------这些都是很入门的写法，，，
%num% 是执行变量，，，%1，是获取外部第一个参数
第二行写明，执行参数=外部参数，，
如果外部参数为空白则IF 都没被执行，脚本则走到，echo 选择对应的软件序号进行安装：进行显示选择，，
当 set /p num= 语句，把%num% 变量赋予参数后goto start
跳到 :start标签脚本前段，重复执行IF判断，，
if /i %num% EQU n exit if /i 是不分大小写的 n 被判断到则执行 exit 退出命令。
if not "%num%"=="" exit 当%num% 变量不再是空白，则执行 exit 退出命令。

------------
这样写法的好处是，你可以把脚本拖进其他脚本或cmd窗口下写空格加参数（序号）直接运行指定命令，
运行完后退出，免去选择。
同理，你也可以把脚本创建快捷方式，目标：脚本完整路径名（后面）空格 + 序号，指定执行。运行完后退出，免去选择。

77七 · 发表于 2025-12-25 08:49:17

本帖最后由 77七于 2025-12-25 08:50 编辑

回复 4# tomtangfish2

set #1=start %~dp0WeChatSetup.exe /S
set #2=start %~dp0QQ.exe /s
set #3=start %~dp0TencentMeeting.exe /silentinstall=0 /Language="zh-cn"
set #4=start %~dp07.8.0-Release.exe /S /NCRC
:loop
setlocal enabledelayedexpansion
rem 可以一次输入多个，如 1 3
set /p num=
for %%a in (%num%) do (
!#%%a!
)
endlocal
pause
goto :loop

复制代码

aloha20200628 · 发表于 2025-12-25 11:03:00

本帖最后由 aloha20200628 于 2025-12-25 11:19 编辑

回复 4# tomtangfish2

以下示例代码假设所有安装程序均在系统路径或当前目录中，可在3-6行之间参照示例格式增减所需安装程序，代码假设采用并发安装（非顺序安装）方式...

@echo off &setlocal enabledelayedexpansion &set "n=0" &set "i="
for %%p in (
"WeChatSetup.exe /S"
"TencentMeeting.exe /silentinstall=0 /Language="zh-cn""
"360se_setup.exe --silent-install=3_1_1"
"WPS_Setup.exe /S -agreelicense"
) do set/a "n+=1" &set "#!n!=%%~p" &for /f %%a in (%%p) do echo,!n!: %%a
:[loop]
set/p "i=选择以上对应的软件序号进行安装(可输入多个序号，其间用空格分隔)，直接回车键退出："
if not defined i exit/b
for %%n in (%i%) do start "" !#%%n!
:: 若全部采用顺序安装方式须用此行代码》for %%n in (%i%) do !#%%n!
set "i=" & goto [loop]

复制代码

tomtangfish2 · 发表于 2025-12-29 10:32:39

在各位高手的指点下，代码分写成两部分：第一部分是写软件编号、名称和静默安装命令；第二部分是指定被安装软件。以后增删安装软件只需修改第一部分。
不足处：
1、向脚本传递参数的功能没有实现。
2、软件编号名称与静默安装命令是分开写的，一一对应是麻烦的。没有省略写编号名称是因为直接读静默命令不方便。

@echo off
set #1=start %~dp0WeChatSetup.exe /S
set #2=start %~dp0QQ.exe /s
set #3=start %~dp0TencentMeeting.exe /silentinstall=0 /Language="zh-cn"
set #4=start %~dp07.8.0-Release.exe /S /NCRC
set #6=start %~dp0WPS_Setup.exe /S -agreelicense
set #7=start %~dp0ChromeSetup.exe
set #8=start %~dp0360se_setup.exe --silent-install=3_1_1
set #9=start /i %~dp0Firefox_Setup.msi /passive
set #11=start %~dp0sogou_pinyin.exe /S
set #12=start %~dp0wetype.exe /s
set #13=start %~dp0BaiduPinyinSetup.exe /s
set #16=start %~dp0winrar.exe /S
set #21=start %~dp0anquanweishi.exe /install /silent
set #22=start %~dp0\cmd\callactivatedps.bat
set #23=start %~dp0\KMS_VL_ALL\KMS-VL-ALL_cn.cmd
set #24=reg add HKEY_CURRENT_USER\Software\kingsoft\Office\6.0\plugins\officespace\flogin /V enableForceLoginForFirstInstallDevice /t REG_SZ /d false /f
set #25=start %~dp0reboot.bat
set #31=start %~dp0disableUAC.bat
set #32=start %~dp0EnableUAC.bat
set #33=start %~dp0normalinstall.bat
set #34=34 start %~dp0runSDIRUS.bat
set #61=start %~dp0WeChatSetup_x86.exe /S
echo 选择以上软件对应的序号进行安装，可以输入多个序号，空格分开，比如1 2 3：
echo 1 微信 2 QQ 3 腾讯会议 4 钉钉
echo 6 WPS 7 谷歌浏览器 8 360安全浏览器 9 火狐浏览器
echo 11 搜狗输入法 12 微信输入法 13 百度输入法
echo 16 WinRAR
echo 21 安全卫士 22 网络激活 23 KMS激活 24 解除WPS限制 25 重启电脑
echo 31 关闭UCA 32 打开UCA 34 驱动安装
echo ==================================
echo 61 微信x86
:loop
setlocal EnableDelayedExpansion
rem 一次可以输入多个，比如1 2 3
echo 输入软件对应编号，一次可以输入多个，空格分开，如：1 2 3
set /p num=
for %%a in (%num%) do (
!#%%a!
)
endlocal
goto loop

复制代码

再次感谢各位高手的指点！

jiavip · 发表于 2025-12-29 17:26:21

回复 8# tomtangfish2

传递参数最好写了，，，

@Echo off
rem;;; %1 是代表第一个参数 %2代表第二个参数，类推到%9 ,%0 代表该脚本
if "%1"=="1" Echo.%0 参数1 &pause>nul&exit
if "%1"=="2" Echo.%0 参数2 &pause>nul&exit
if "%1"=="3" Echo.%0 参数3 &pause>nul&exit
if "%1"=="4" Echo.%0 参数4 &pause>nul&exit
if "%1"=="5" Echo.%0 参数5 &pause>nul&exit
if "%1"=="6" Echo.%0 参数6 &pause>nul&exit
if "%1"=="7" Echo.%0 参数7 &pause>nul&exit
if "%1"=="8" Echo.%0 参数8 &pause>nul&exit
if "%1"=="9" Echo.%0 参数9 &pause>nul&exit
if "%1"=="0" Echo.%0 参数0 &pause>nul&exit
Goto,%1
Exit
:a
Echo.%0 参数A 不分大小写 &pause>nul&exit
:b
Echo.%0 参数B 不分大小写 &pause>nul&exit
:c
Echo.%0 参数C 不分大小写 &pause>nul&exit
:d
Echo.%0 参数D 不分大小写,可以写A - Z 也可以是字符组 &pause>nul&exit
:A1
Echo.%0 参数A1 不分大小写 &pause>nul&exit

复制代码

存以上代码脚本，，
把脚本创建快捷方式  加参数 1 到 9  a , b , c , d , a1
把脚本拖到运行筐空格加参数 1 到 9  a , b , c , d , a1
把脚本拖到CMD 空格加参数 1 到 9  a , b , c , d , a1

77七 · 发表于 2025-12-29 23:47:14

回复 8# tomtangfish2

@echo off
setlocal
rem 读取自身，打印提示+定义变量
set n=
for /f "tokens=1-2*" %%a in ('findstr /rbc:"#[0-9][0-9]*[ ]" "%~f0"') do (
for /f "delims=#" %%c in ("%%a") do (
set /p="%%c.%%b "<nul
)
set /a "n+=1,1/(n%%4)" 2>nul || echo=
set %%a=%%c
)
echo=
rem 获取输入，执行相应动作
:loop
echo=
setlocal enabledelayedexpansion
set num=
if "%*" equ "" (
echo 输入软件对应编号，一次可以输入多个，空格分开，如：1 2 3
set /p num=
) else (
set num=%*
)
for %%a in (%num%) do (
!#%%a!
timeout /t 3
)
endlocal
if "%*" equ "" (
goto :loop
)
endlocal
exit /b
rem 序号名称操作
#1 微信 start %~dp0WeChatSetup.exe /S
#2 QQ start %~dp0QQ.exe /s
#3 腾讯会议 start %~dp0TencentMeeting.exe /silentinstall=0 /Language="zh-cn"
#4 钉钉 start %~dp07.8.0-Release.exe /S /NCRC
#6 WPS start %~dp0WPS_Setup.exe /S -agreelicense

复制代码

tomtangfish2 · 发表于 2026-1-11 09:36:01

回复 10# 77七
在77七和jiavip的帮助下，更新了脚本。
1、实现了脚本接收参数的功能。
2、简化了增删软件的修改操作。
再次感谢77七和jiavip的热心帮助。

@echo off
setlocal EnableDelayedExpansion
rem 跳过增删软件部分
goto main
rem 增删软件。按序号、软件名称、安装命令顺序写成一行，用空格分开
#1 微信 start WeChatSetup.exe /S
#2 QQ start QQ.exe /s
#3 腾讯会议 start TencentMeeting.exe /silentinstall=0 /Language="zh-cn"
#4 钉钉 start 7.8.0-Release.exe /S /NCRC
#6 WPS start WPS_Setup.exe /S -agreelicense
#7 谷歌浏览器（在线安装） start ChromeSetup.exe
#8 360安全浏览器 start 360se_setup.exe --silent-install=3_1_1
#9 火狐浏览器 start /i Firefox_Setup.msi /passive
#11 搜狗输入法 start sogou_pinyin.exe /S
#12 微信输入法 start wetype.exe /s
#13 百度输入法 start BaiduPinyinSetup.exe /s
#16 WinRAR start winrar.exe /S
#21 安全卫士 start anquanweishi.exe /install /silent
#22 MAS激活 start \cmd\callactivatedps.bat
#23 KMS激活 start \KMS_VL_ALL\KMS-VL-ALL_cn.cmd
#24 解除WPS登录限制 add HKEY_CURRENT_USER\Software\kingsoft\Office\6.0\plugins\officespace\flogin /V enableForceLoginForFirstInstallDevice /t REG_SZ /d false /f
#25 重启电脑 start reboot.bat
#31 关闭UCA start disableUAC.bat
#32 打开UCA start EnableUAC.bat
#34 安装驱动 start runSDIRUS.bat
rem x86软件
#61 微信x86 start WeChatSetup_x86.exe /S
rem 退出脚本
#0 退出脚本 exit /b
rem 脚本起始处
:main
rem 读取自身，打印提示+定义变量
set n=
for /f "tokens=1-2*" %%a in ('findstr /rbc:"#[0-9][0-9]*[ ]" "%~f0"') do (
for /f "delims=#" %%e in ("%%a") do (
set /p="%%e.%%b "<nul
)
set /a "n+=1,1/(n%%4)" 2>nul || echo=
set %%a=%%c
)
echo=
rem 传递参数
:loopparameter
if "%1"=="" goto end
for %%a in (%1) do (
!#%%a!
)
shift
goto loopparameter
:end
rem 指定安装软件
:loopchoice
rem 一次可以输入多个，比如1 2 3
echo 输入软件对应编号，一次可以输入多个，空格分开，如：1 2 3 按0退出脚本
set /p num=
for %%a in (%num%) do (
!#%%a!
)
goto loopchoice

复制代码

aloha20200628 · 发表于 2026-1-11 23:59:09

本帖最后由 aloha20200628 于 2026-1-12 00:20 编辑

回复 11# tomtangfish2

如果11楼代码直接用命令行参数驱动，需要用户启运脚本之前先了解代码内几十个安装选项序号，除非编码者本人，否则，对于终端用户的实际使用，可能不太方便，不如仅保留实时输入选项最为便捷...如是，代码可简化如下。

@echo off &setlocal enabledelayedexpansion &set "n=0"
for %%p in (
"#1 安装微信 start "" WeChatSetup.exe /S"
"#2 安装腾讯会议 start "" TencentMeeting.exe /silentinstall=0 /Language="zh-cn""
"#3 解除WPS登录限制 reg add HKEY_CURRENT_USER\Software\kingsoft\Office\6.0\plugins\officespace\flogin /V enableForceLoginForFirstInstallDevice /t REG_SZ /d false /f"
"#4 MAS激活 start "" \cmd\callactivatedps.bat"
) do set/a "n+=1" &set "#!n!=%%~p" &echo,%%~p
:[loop]
set "i=" &set/p "i=选择以上对应的软件序号进行安装(可输入多个序号，其间用空格分隔)，直接回车键退出："
if not defined i exit/b
for %%k in (%i%) do for /f "tokens=1-2* delims= " %%x in ("!#%%k!") do echo,%%x %%y... &%%z
goto [loop]

复制代码

以上代码中第3-6行仅抽取了11楼全部安装选项中的4个典型作为示范；
第一个 for %%p ... 循环直接完成选项变量表定义及其显示，其显示格式参照11楼的3字段定义》序号说明运行代码；
代码中的 start 句式增加了前置参数 "" 以便兼容后续可能出现需用双引号包裹的路径参数。

如果完全克隆11楼 '先处理命令行参数再进入实时选项' 的运行流程，可参考以下代码...

@echo off &setlocal enabledelayedexpansion &set "n=0"
for %%p in (
"#1 安装微信 start "" WeChatSetup.exe /S"
"#2 安装腾讯会议 start "" TencentMeeting.exe /silentinstall=0 /Language="zh-cn""
"#3 解除WPS登录限制 reg add HKEY_CURRENT_USER\Software\kingsoft\Office\6.0\plugins\officespace\flogin /V enableForceLoginForFirstInstallDevice /t REG_SZ /d false /f"
"#4 MAS激活 start "" \cmd\callactivatedps.bat"
) do set/a "n+=1" &set "#!n!=%%~p"
if "%~1"=="" goto[select]
for %%v in (%*) do for /f "tokens=1-2* delims= " %%x in ("!#%%~v!") do echo,%%x %%y... &%%z
:[select]
for /L %%k in (1,1,!n!) do echo,!#%%k!
:[loop]
set "i=" &set/p "i=选择以上对应的软件序号进行安装(可输入多个序号，其间用空格分隔)，直接回车键退出："
if not defined i exit/b
for %%k in (%i%) do for /f "tokens=1-2* delims= " %%x in ("!#%%k!") do echo,%%x %%y... &%%z
goto [loop]

复制代码

		自动登录	找回密码
密码			注册

[新手上路]批处理新手入门导读	[视频教程]批处理基础视频教程	[视频教程]VBS基础视频教程	[批处理精品]批处理版照片整理器
[批处理精品]纯批处理备份&还原驱动	[批处理精品]CMD命令50条不能说的秘密	[在线下载]第三方命令行工具	[在线帮助]VBScript / JScript 在线参考

[网络工具] 网卡的静态IP地址和动态IP地址之间的切换

本帖子中包含更多资源

评分

本帖子中包含更多资源