求助批处理如何批量删除文件名中的 -副本（）这些？

ypzdy · 发表于 2025-8-12 14:03:16

每次复制文件文件名后面就会出现 -副本（2）这些
比如
123.xlsx
复制后变成了
123 - 副本.xlsx
123 - 副本 .(2).xlsx
123 - 副本 .(3).xlsx
我想批量改成
1232.xlsx
1233.xlsx这样

aloha20200628 · 发表于 2025-8-12 15:52:36

本帖最后由 aloha20200628 于 2025-8-12 20:18 编辑

回复 1# ypzdy

以下代码运行后会将当前目录下所有 * - 副本*.* 文件更名为与主名对应的 *1.*，*2.*, ..., *n.*

@echo off &setlocal enabledelayedexpansion
for /f "delims=" %%F in ('dir /b/a-d^|find /v " - 副本" ') do set "n=" &for /f "delims=" %%a in ('dir /b/a-d "%%~nF - 副本*" 2^>nul') do (
set "a=%%~na" &set/a "n+=1"
for /f "delims=" %%x in ("!a: - 副本=\!") do ren "%%a" "%%x!n!%%~xa" )
pause&exit/b

复制代码

ypzdy · 发表于 2025-8-12 16:12:25

回复 2# aloha20200628

谢谢大神

aloha20200628 · 发表于 2025-8-12 20:33:26

本帖最后由 aloha20200628 于 2025-8-12 21:05 编辑

回复 3# ypzdy

二楼代码开启了延迟变量，故被处理的文件名中若包含 ! 字符会出错。
以下给出不用延迟变量的 A，B 两个版本，均可兼容文件名中的 ! 字符，B版利用 dir /b... 默认文件名排序的特性和尽量减少call调用次数，可能会比A版效率高一些，尤其是当文件量较大时...

A版

@echo off &setlocal &for /f "delims=" %%F in ('dir /b/a-d^|find /v " - 副本" ') do set "n=" &for /f "delims=" %%a in ('dir /b/a-d "%%~nF - 副本*" 2^>nul') do (
set "_a=%%~na" &set/a "n+=1" &call set "_a=%%_a: - 副本=\%%"
for /f "delims=" %%x in ('echo.%%_a%%') do call ren "%%a" "%%x%%n%%%%~xa" )
pause&exit/b

复制代码

B版

@echo off &setlocal &for /f "delims=" %%a in ('dir /b/a-d "* - 副本*" 2^>nul') do (
set "_a=%%~na" &call set "_a=%%_a: - 副本=\%%"
for /f "delims=" %%x in ('echo.%%_a%%') do (
if not defined %%x (set "n=1" &set "%%x=1") else set/a "n+=1"
for /f %%n in ('set/a n') do ren "%%a" "%%x%%n%%~xa" ))
pause&exit/b

复制代码

ypzdy · 发表于 2025-8-12 22:00:56

回复 4# aloha20200628

谢谢大神

77七 · 发表于 2025-8-13 15:38:58

本帖最后由 77七于 2025-8-13 15:42 编辑

如果文件名是数字，还不如保持原样，如1楼修改后的文件名，看起来很乱；但是如果文件名是汉字，还是可以一目了然。
如果重命名后再复制产生一个副本，再执行脚本，还要考虑重名问题。如果删除了原副本(2)，还可能需要考虑次序问题。
可以考虑添加一个右键菜单，从复制那一步就解决问题。

		自动登录	找回密码
密码			注册

[新手上路]批处理新手入门导读	[视频教程]批处理基础视频教程	[视频教程]VBS基础视频教程	[批处理精品]批处理版照片整理器
[批处理精品]纯批处理备份&还原驱动	[批处理精品]CMD命令50条不能说的秘密	[在线下载]第三方命令行工具	[在线帮助]VBScript / JScript 在线参考

[文本处理] 求助批处理如何批量删除文件名中的 -副本 （）这些？

[文本处理] 求助批处理如何批量删除文件名中的 -副本（）这些？