[分享&讨论]批处理变量赋值时含有双引号及特殊符号如何转义

77七 · 发表于 2025-8-1 13:53:26

@echo off
echo "假设：双引号不成对（不包括被转义的双引号），则末尾存在隐形双引号
echo "已知：双引号对内的特殊字符（包括^<>&|不包括 %%!）无需转义
echo 1.变量名前无双引号：从左（set 后）到右，双引号(包括隐形双引号，不包括被转义的双引号)双双配对，处于双引号对外需要转义，处于双引号对内不需要转义。
rem 存在一个显形双引号，与末尾的隐形双引号配对，引号对内的 "<" 无需转义
set a="<
cmd /v:on /c echo !a!
rem 对比:多余的“转义”字符，变普通字符
set a="^<
cmd /v:on /c echo !a!
rem 存在一个显形双引号但是被转义了，失去配对资格（没有双引号对，所有字符都在双引号对之外），需要转义 "<"
set a=^"^<
cmd /v:on /c echo !a!
rem 第一个双引号被转义，失去配对资格，第二个双引号与末尾的隐形双引号配对，无需转义 "<"
set a=^""<
cmd /v:on /c echo !a!
rem 前两个双引号配对，第三个与末尾的隐形双引号配对，第一个 "<" 无需转义，第二个 "<" 需要转义，末尾 "|" 无需转义
set a="<"^<"|
cmd /v:on /c echo !a!
echo=
echo 2.变量名前有双引号：仍按上一条规律，变量值去除了最后一个显形双引号及其后的内容
rem 双引号对内的 "|" 无需转义，双引号对外的 "|" 需要转义
set "a="^|"|"1""""
cmd /v:on /c echo !a!
rem 即使变量值去除了最后一个显形双引号及其后的内容，最后一个双引号后的内容仍需要按规律书写转义
set "a="^|"|"1""^<
cmd /v:on /c echo !a!
echo=
echo 3."^" 处于双引号对内，则其失去转义作用（只是普通字符），此时其后跟随的双引号仍为可以配对的双引号
rem "^" 处于双引号对内，失去转义作用
set "a=^""<"1
cmd /v:on /c echo !a!
rem 第3个双引号被转义，失去配对资格，第4个双引号与隐形双引号配对，第4个双引号之前的 "<" 处于双引号对外，需要转义
set "a=^"1^"^<"<
cmd /v:on /c echo !a!
echo=
echo 4. "^" 处于末尾情况
rem "^" 处于双引号对外，末尾的偶数位数 "^" 被奇数位数 "^" 转义为普通字符。末尾的 "^" 数量为奇数时，最后一个 "^" 未被转义，连接了下一行
set c="1"^^^
2
cmd /v:on /c echo c=!c!
set d="1"^^^^
cmd /v:on /c echo d=!d!
rem "^" 处于双引号对内（第一个双引号与与隐形的双引号配对），无论多少个 "^" 均被双引号对转义，为普通字符
set e="^^^^^
cmd /v:on /c echo e=!e!
rem 一个复杂例子，"^" 处于双引号对外，连接了下一行，但是变量名前存在双引号，最后一个双引号及其后的内容被去除，且 "^" 仍有转义作用，转义了 "&"
set "f=1"^
&"2
cmd /v:on /c echo f=!f!
pause

复制代码

我试着总结了下。另外1.特殊符号在不同的环境下会有变化；2.其它命令大概也适用。如echo "&、if 跟vbs命令需转义)、for /f in ('echo ^=') 等。请多多指正！

Five66 · 发表于 2025-8-2 05:58:58

其实就是从左往右 ,与距离最近的双引号配对 ,不在双引号对里或者没有被单个双引号引起来的都要转义
经过解析后 ,set命令及其内容就分离出来了 ,如果变量名开头是双引号就去掉"开头的引号"跟"最后一个引号及其后内容" ,保留剩下的
感觉这样的规则是真的恶心 ,尤其是跟外部程序混在一起时就更加了 ,既要满足这样的规则又要满足外部程序的规则 ,最典型的就是用vbs以管理员身份运行包含特殊字符文件名的bat了

aloha20200628 · 发表于 2025-8-2 12:39:03

本帖最后由 aloha20200628 于 2025-8-2 12:40 编辑

回复 1# 77七

踩着老帖的脚印走过来再加上一些力所能及的实证，可简要理解 cmd 处理字符串中特殊字符的转义机理如下》
第奇数个双引号开启特殊字符转义，第偶数个双引号关闭特殊字符转义，如没有第偶数个双引号则至当前行结束自动关闭。看以下示例代码，用转义符^本身是否被保留表示转义被开启或被关闭

@echo off
echo,我^被转义 "我^未被转义" 我^被转义
echo,"我^未被转义" 我^被转义 "我^未被转义"
echo,"我^未被转义我^未被转义
echo,我^被转义 "我^未被转义
pause&exit/b

复制代码

至于双引号本身在字符串中的转义方法，会根据当前语境有所变化，批处脚本中可用 ^" 或 "" 转义单个双引号，在传递给c/c++/c#系列程序的参数字符串中可用 \" 转义单个双引号，在调用 powershell 代码中的字符串内可用 """ 转义单个双引号，在调用 vbs 代码中的字符串内可用 "" 转义单个双引号，...等等。其余特殊符号的一些常见转义方法可参考旧帖 http://www.bathome.net/thread-66857-1-1.html

buyiyang · 发表于 2025-8-2 16:22:28

其实是有两步：
首先是cmd解析命令行，处理特殊字符和扩展变量，逐字符解析，其中有以遇到引号为条件开或关转义功能。
然后内部或外部命令根据其自己规则处理参数，set的规则就是——如果参数以引号开头，就去掉开头的引号和后续空白字符，并找到最后一个引号，去掉这个引号及其后字符。

即使变量值去除了最后一个显形双引号及其后的内容，最后一个双引号后的内容仍需要按规律书写转义
"^" 处于双引号对外，连接了下一行，但是变量名前存在双引号，最后一个双引号及其后的内容被去除，且 "^" 仍有转义作用

复制代码

1楼这两句似乎弄错了顺序，不是先去除再转义，而是先cmd转义再set去除。所以最后一个双引号后的内容才也需要符合cmd解析的规则。

		自动登录	找回密码
密码			注册

[新手上路]批处理新手入门导读	[视频教程]批处理基础视频教程	[视频教程]VBS基础视频教程	[批处理精品]批处理版照片整理器
[批处理精品]纯批处理备份&还原驱动	[批处理精品]CMD命令50条不能说的秘密	[在线下载]第三方命令行工具	[在线帮助]VBScript / JScript 在线参考

[其他] [分享&讨论]批处理变量赋值时含有双引号及特殊符号如何转义

评分

评分

评分

浏览过的版块