【已解决】批处理将主板名称重命名计算机名称

chishingchan · 发表于 2025-7-27 11:55:26

本帖最后由 chishingchan 于 2025-7-29 16:30 编辑

鉴于计算机名称规范

不允许包含以下的字符：
反斜杠 (\)
斜杠 (/)
冒号 (

星号 (*)
问号 (?)
引号 (")
小于符号 (<)
大于符号 (>)
竖线 (|)
逗号 (,)

名称长度规则：
最小名称长度：1 个字符
最大名称长度：15 个字符

例如，计算机的名称变量：
z=A B"C,D.E/F:G?H\I^|J^<K^>L*M-N

在规范上再添加句号 (.)、空格 ( )，全都替换为下划线 (_)，即最终结果为：
z=A_B_C_D_E_F_G_H

求助，批处理该如何编写？谢谢！

谢谢以下各位的解答，总结如下：

@echo off
set z=A B"C,D.E/F:G?H\I^|J^<K^>L*M-N
echo:%z%
set "z=%z: =_%"
set "z=%z:"=_%"
set "z=%z:,=_%"
set "z=%z:.=_%"
set "z=%z:/=_%"
set "z=%z::=_%"
set "z=%z:?=_%"
set "z=%z:\=_%"
set "z=%z:|=_%"
set "z=%z:<=_%"
set "z=%z:>=_%"
echo:%z%
set "z=%z:~0,15%"
echo:%z%&pause&exit/b

复制代码

显示结果：

A B"C,D.E/F:G?H\I^|J^<K^>L*M-N
A_B_C_D_E_F_G_H_I_J_K_L*M-N
A_B_C_D_E_F_G_H
请按任意键继续. . .

复制代码

aloha20200628 · 发表于 2025-7-27 20:59:17

回复 1# chishingchan

是要更名计算机名称还是仅仅要替换字符串中的空格和圆点？

chishingchan · 发表于 2025-7-27 21:30:19

回复 2# aloha20200628

变量是变量（非固定字符串）。替换字符串相关字符即可。谢谢！

aloha20200628 · 发表于 2025-7-27 21:43:02

回复 3# chishingchan
是要以下这段代码吗...

@echo off
set "p=C.A68M-P PRO"
set "p=%p:.=_%
set "p=%p: =_%
echo,%p%&pause&exit/b

复制代码

Batcher · 发表于 2025-7-28 08:22:01

回复 1# chishingchan

@echo off
set "Product=C.A68M-P PRO"
set "Product=%Product:.=_%"
set "Product=%Product: =_%"
echo,%Product%
pause

复制代码

yakeyun · 发表于 2025-7-28 12:51:13

本帖最后由 yakeyun 于 2025-7-28 19:29 编辑

回复 1# chishingchan

@echo off
setlocal enabledelayedexpansion
:: 检查管理员权限
net session >nul 2>&1
if %errorLevel% neq 0 (
echo 请使用管理员权限运行此脚本！
pause
exit /b
)
:: 获取当前计算机名
for /f "tokens=*" %%a in ('hostname') do set "OLD_NAME=%%a"
echo,当前设备名称: %OLD_NAME%
::获取主板名称并处理格式
for /f "tokens=*" %%x in ('powershell -Command "(Get-CimInstance Win32_BaseBoard).Product"') do set "zbname=%%x"
set "zbname=%zbname: =_%"
set "zbname=%zbname:.=_%"
set "zbname=%zbname:/=_%"
set "zbname=%zbname:(=_%"
set "zbname=%zbname:)=_%"
set "NEW_NAME=!zbname!"
echo,应用设备名称: !NEW_NAME!
:: 设备名称 (%NEW_NAME%最多15字符，允许字母/数字/连字符)
:: 基础验证
if "!NEW_NAME!"=="" (
echo 错误：名称不能为空
pause
exit /b
)
if "!NEW_NAME!"=="%OLD_NAME%" (
echo 错误：新名称与当前名称相同
pause
exit /b
)
:: 使用PowerShell修改计算机名
powershell -Command "Rename-Computer -NewName '%NEW_NAME%' -Force -ErrorAction Stop" 2>nul
rem 如果要把名称中加入“Product=”，请将下面rem字段删除
rem powershell -Command "Rename-Computer -NewName 'Product=%NEW_NAME%' -Force -ErrorAction Stop" 2>nul
if %errorLevel% equ 0 (
echo 设备名称已成功修改为: %NEW_NAME%
echo 注意：需重启计算机生效！
rem 如果要自动重启，请将下面rem字段删除
rem shutdown /r /t 0
set /p REBOOT="是否立即重启？(y/n): "
if /i "!REBOOT!"=="y" shutdown /r /t 0
) else (
echo 修改失败！可能原因：
echo 1. 名称包含非法字符
echo 2. 名称长度超过15字符
echo 3. 名称包含空格或特殊符号
echo 4. 组策略限制
pause
)
endlocal

复制代码

holley · 发表于 2025-7-28 14:17:33

回复 3# chishingchan

@echo off
setlocal enabledelayedexpansion
set /p "input=请输入原始计算机名称："
set "output=!input: =_!"
set "output=!output:.=_!"
set "output=!output:\=_!"
set "output=!output:/=_!"
set "output=!output::=_!"
set "output=!output:*=_!"
set "output=!output:?=_!"
set "output=!output:"=_!"
set "output=!output:<=_!"
set "output=!output:>=_!"
set "output=!output:|=_!"
set "output=!output:,=_!"
if "!output!"=="" (
set "output=_"
) else (
set "output=!output:~0,15!"
)
echo.
echo 处理结果：
echo 原始名称：%input%
echo 规范名称：!output!

复制代码

yakeyun · 发表于 2025-7-28 19:31:18

回复 chishingchan
yakeyun 发表于 2025-7-28 12:51

加入了将“Product=”字段加入功能，删除改名命令前的“rem”字符即可。

chishingchan · 发表于 2025-7-28 20:05:58

鉴于以上的解答，可不可以不使用：
PowerShell
setlocal enabledelayedexpansion

set 能不能在 for 内
预设：Name=A/B\C*D?E"F<G>H|I,J.K L:M-N

如果不使用 setlocal，特殊字符可能不能应用某些字符，例如 < > | * ?
预设只是尽大程度包含所有不合适的字符，如果鉴于主板的名称，可能仅包含3~4种字符，特殊字符更是没有！

aloha20200628 · 发表于 2025-7-29 00:12:04

回复 9# chishingchan

不用纯批的逐字遍历方法,也不用外部脚本如 vbs/jscript/powershell 方法，可尝试如下代码，但有一难点是不能替换*字符...

@echo off
set z=A/B\C*D?E"F^<G^>H^|I,J.K L:M-N
set "z=%z:"=_%"
set "z=%z:|=_%"
set "z=%z:<=_%"
set "z=%z:>=_%"
set "z=%z:^=%"
set "z=%z:?=_%"
set "z=%z:\=_%"
set "z=%z:/=_%"
set "z=%z:,=_%"
set "z=%z:.=_%"
set "z=%z: =_%"
set "z=%z::=_%"
echo,"%z%"&exit/b

复制代码

chishingchan · 发表于 2025-7-29 16:13:54

回复 10# aloha20200628

请问：
1、第 7 行的作用是什么？
2、能使用 FOR %variable IN (set) DO command 循环吗？

aloha20200628 · 发表于 2025-7-29 17:10:28

本帖最后由 aloha20200628 于 2025-7-29 19:23 编辑

回复 11# chishingchan

一。由于代码第2行采用字面量定义被处理字符串的预设值，故须对管道符和重定向符加持转义符^，因此代码第7行即为及时清理遗留的转义符，若要省略此行，须改用以下代码（运行结果会将被处理字符串中非英文字母均替换为 _，但 * 字符除外）。

@echo off
set z=A/B\C*D?E"F^<G^>H^|I,J.K L:M-N
set "z=%z:"=_%"
set "z=%z:^|=_%"
set "z=%z:^<=_%"
set "z=%z:^>=_%"
set "z=%z:?=_%"
set "z=%z:\=_%"
set "z=%z:/=_%"
set "z=%z:,=_%"
set "z=%z:.=_%"
set "z=%z: =_%"
set "z=%z::=_%"
set "z=%z:-=_%"
echo,%z%&exit/b

复制代码

二。采用 for %%v in (...) 句式实现重复替换操作会引入延迟变量 setlocal enable...，否则会使代码复杂化，且通配符？*不能出现在 (...) 表达式中以免被系统强行转义为文件目录符匹配。
三。因 * 和 = 作为字符串替换函数的内置语义符，故采用字符串替换函数不能替换 * 和 =，好在硬件名称中不会采用之，本帖实况即可忽略了...

77七 · 发表于 2025-7-29 18:18:54

本帖最后由 77七于 2025-7-29 20:17 编辑

批处理把计算机重命名为主板名

@echo off
rem "右键管理员执行"
for /f "tokens=1* delims==" %%a in ('wmic baseboard get Product /value ^|find "="') do (
for /f tokens^=1-8delims^=_./\:*?^"^<^>^|^,^ %%a in ('echo "%%b"') do (
for /f "delims=" %%a in ("%%a.%%b.%%c.%%d.%%e.%%f.%%g.%%h") do (
set str=%%~nxa
)
setlocal enabledelayedexpansion
set "str=!str:.=_!"
wmic computersystem where name="!COMPUTERNAME!" call rename name="!str:~0,15!"
endlocal
)
)
pause

复制代码

代码没有直接替换这些字符，而是当作分隔符（相当于多个相邻的分隔符替换成一个，并删除首尾的分隔符号），也与计算机名称有长度限制，为保留更多主板名称信息的实际需要契合。
wmic代码由ai提供，部分修改。忘了限制字符数了，已修改。

aloha20200628 · 发表于 2025-7-29 20:12:32

本帖最后由 aloha20200628 于 2025-7-29 20:14 编辑

回复 11# chishingchan

如果是为修改有严格命名规则的计算机名称，确实不必如此修理这些特殊字符，但楼主有兴趣问究，就随之跟进吧...
以下代码是用延迟变量+for... 重写的12楼代码，运行结果会将被处理字符串中非英文字母均替换为 _，但 * 字符除外。

@echo off &setlocal enabledelayedexpansion &set "_#?=1" &set "_#"=1"
for %%c in ("^<", "^>", "^|", "/", "", ",", ".", ":", "-") do set "_#%%~c=1"
set z=A/B\C*D?E"F^<G^>H^|I,J.K L:M-N
for /f "delims=_#=" %%a in ('set _#') do set "z=!z:%%a=_!"
echo,!z!&exit/b

复制代码

最后再给一个用 for /f 分割法替换 * 和 = 两个钉子户的示例代码（均替换为 _ 字符），用此收尾以上代码或12楼代码即可最终搞定目标字符串中的 * 字符。

@echo off &set "zz=" &set "z=abc*xyz=123"
:zzz
for /f "tokens=1* delims=*=" %%a in ("%z%") do set "a=%%a" &set "z=%%b"
set "zz=%zz%_%a%"
if "%z%"=="" echo,%zz:~1%&exit/b
goto :zzz

复制代码

chishingchan · 发表于 2025-7-30 19:53:10

回复 14# aloha20200628

按本例的“主板产品名称”，得到真实的字符串一般没多少个特殊字符，够用就好了。

		自动登录	找回密码
密码			注册

[新手上路]批处理新手入门导读	[视频教程]批处理基础视频教程	[视频教程]VBS基础视频教程	[批处理精品]批处理版照片整理器
[批处理精品]纯批处理备份&还原驱动	[批处理精品]CMD命令50条不能说的秘密	[在线下载]第三方命令行工具	[在线帮助]VBScript / JScript 在线参考

[文本处理] 【已解决】批处理将主板名称重命名计算机名称

评分

评分

评分

评分

评分

评分

评分

评分