求个批处理：将当前路径下的某个文件夹创建快捷方式，然后发送到指定路径？

ednykissyou · 发表于 2025-7-7 00:55:59

回复 ednykissyou

照以下步骤》先开启cmd管理员窗口，在命令行上直接运行 cd /d d:\abc，其中 d:\abc ...
aloha20200628 发表于 2025-7-7 00:34

刚试了，可行。
可是，这些如何转变为代码，不然对普通人他没有意义啊

ednykissyou · 发表于 2025-7-7 01:18:06

本帖最后由 ednykissyou 于 2025-7-7 01:52 编辑

回复 ednykissyou

照以下步骤》先开启cmd管理员窗口，在命令行上直接运行 cd /d d:\abc，其中 d:\abc ...
aloha20200628 发表于 2025-7-7 00:34

大神，帮看一下这个，我直接改那个目录好像不对，你能结合你的代码，你一定能帮我解决这个问题
http://www.bathome.net/viewthrea ... mp;extra=#pid289560

还有这个我没看大懂
https://blog.csdn.net/xundao255/article/details/98727676

这个好像也支持长文件名　可惜双击后没反应
https://blog.csdn.net/yan_onion/article/details/13240091

czjt1234 · 发表于 2025-7-7 10:27:01

都是高手
我从头看到尾看了2遍，愣是没搞清楚楼主的需求是什么

aloha20200628 · 发表于 2025-7-7 10:43:26

回复 31# ednykissyou

只要在代码第一行定义快捷方式的目标目录 a, b 的全路径名就省事多了，无论在已打开的管理员CMD窗口中运行，还是直接用右键管理员身份启运批处脚本均可...
关键是运行批处脚本之前要把第一行中的 set "Da=d:\xyz\a" &set "Db=d:\xyz\b" 改为 a, b 的真实完整路径！
订正的代码如下

@echo off &setlocal &set "Da=d:\xyz\a" &set "Db=d:\xyz\b"
if "%~1" neq "" set "Da=%~1"
if "%~2" neq "" set "Db=%~2"
powershell "$ws=new-object -comobject wscript.shell;('%Da%','%Db%')|%%{$sc=$ws.createshortcut($_+'.lnk');$sc.targetpath=$_;$sc.save()}"
if not exist "C:\Program Files\Adobe\Adobe InDesign 2024\Scripts\Scripts Panel" goto :next
set/p "r=将删除 C:\Program Files\Adobe\Adobe InDesign 2024\Scripts\Scripts Panel 中的全部内容（1=是，0=否）："
if %r% neq 1 goto :next
del /q "C:\Program Files\Adobe\Adobe InDesign 2024\Scripts\Scripts Panel\*.*"
pushd "C:\Program Files\Adobe\Adobe InDesign 2024\Scripts\Scripts Panel"
rd /q /s "C:\Program Files\Adobe\Adobe InDesign 2024\Scripts\Scripts Panel" 2>nul
popd
:next
for /f "delims=" %%d in ('dir /b/s/ad "C:\Program Files\Adobe\*Scripts Panel"^|findstr /irc:"Adobe InDesign 202[0-9]" ') do for %%F in ("%Da%", "%Db%") do copy /y "%%~F.lnk" "%%d"
pause&exit/b

复制代码

以上代码亦可用命令行参数定义第一行的变量值 Da, Db，如在CMD管理员窗口中的命令行启运批处脚本（假设其名为 d:\xyz\test.bat）的格式为

d:\xyz\test.bat "d:\123\a" "d:\123\b"

复制代码

aloha20200628 · 发表于 2025-7-7 11:37:43

本帖最后由 aloha20200628 于 2025-7-7 11:47 编辑

回复 32# ednykissyou

创建及保存快捷方式到指定目录和将其复制到指定目录（如桌面或普通目录）都是一步到位的简单操作，但是要保存的目录（如 c:\windows\system32）或被直接复制到的目录（例如 C:\Program Files\...）是被保护的目录，就有问题，简单解法就是将快捷方式保存到普通目录，并在管理员窗口中完成复制快捷方式的操作，新订正的34楼代码就是基于此理。

77七 · 发表于 2025-7-7 12:20:21

本帖最后由 77七于 2025-7-7 12:22 编辑

@echo off & FLTMC>nul||(mshta vbscript:CreateObject^("Shell.Application"^).ShellExecute^("%~snx0"," %*","","runas",1^)^(window.close^)&&exit /b)
rem 保存为ansi编码
cd /d "%~dp0"
rem 需要的快捷方式路径
set list="aa" "bb"
rem 预设软件路径或获取拖放路径
if "%~1" neq "" (
set "folder_adobe=%~1"
) else (
set "folder_adobe=C:\Program Files\Adobe"
)
rem 预设软件脚本目录名
set "folder_scripts=Scripts Panel"
for /f "delims=" %%i in ('2^>nul dir /b /s /ad "%folder_adobe%\%folder_scripts%*"') do (
if /i "%%~nxi" equ "%folder_scripts%" (
set m=1
echo 将在目录[%%i] 下创建快捷方式
choice /m "确认请按 Y，否请按 N"
if errorlevel 1 (
if not errorlevel 2 (
echo 将删除目录[%%i] 下所有文件（包括子目录）
choice /m "确认请按 Y，否请按 N"
if errorlevel 1 (
if not errorlevel 2 (
rd /s /q "%%i"
md "%%i"
)
)
for %%a in (%list%) do (
if exist "%%~a" (
echo 正在创建快捷方式 [%%~a]
mshta VBScript:Execute("Set a=CreateObject(""WScript.Shell""):Set b=a.CreateShortcut("^
"%%i\%%~nxa.lnk""):b.TargetPath=""%%~fa"":b.WorkingDirectory=""%%~dpa"":b.Save:close"^)
if exist "%%i\%%~nxa.lnk" (
echo 操作成功
) else (
echo 操作失败
)
) else (
echo 未找到 [%%~a] ，请检查路径
)
)
)
)
echo=
echo=
)
)
if not defined m (
if "%~1" equ "" (
echo 未在预设路径"[%folder_adobe%]" 下找到目录"[%folder_scripts%]"
echo 请修改预设路径或拖动目录[Adobe] 到批处理文件打开
) else (
echo 未在拖放目录"[%folder_adobe%]" 下找到目录"[%folder_scripts%]"
echo 请确认拖动目录是否正确显示，如果不正确，请直接在代码中修改预设软件路径；如果正确，请修改预设软件脚本目录名
)
)
pause

复制代码

写了个几乎面面俱到的代码，也希望楼主能在论坛内学习到一点东西，不能注册10多年，批处理文件编码都搞不清楚吧！

另外提醒，删除目录存在风险。

aloha20200628 · 发表于 2025-7-7 16:07:05

本帖最后由 aloha20200628 于 2025-7-7 16:10 编辑

回复 18# ednykissyou

如果真如18，21楼所述，快捷方式对应的完整路径名只能在用户运行批处脚本时确定，那就让批处运行开始先提示用户输入指定这两个完整路径名，其余如开启CMD管理员窗口，创建快捷方式，.... 等等，均由批处自己搞定了，如此批处脚本在哪个目录启运均可。试试以下新版代码

@echo off &setlocal
%~1 powershell "start -file '%~f0' -arg '::' -verb runas" &exit/b
:Loop#1
set/p "Da=请输入指定快捷方式对应的第一个目录："
set "Da=%Da:"=%"
if not exist "%Da%" echo,指定目录不存在，重新指定&goto :Loop#1
:Loop#2
set/p "Db=请输入指定快捷方式对应的第二个目录："
set "Db=%Db:"=%"
if not exist "%Db%" echo,指定目录不存在，重新指定&goto :Loop#2
powershell "$ws=new-object -comobject wscript.shell;('%Da%','%Db%')|%%{$sc=$ws.createshortcut($_+'.lnk');$sc.targetpath=$_;$sc.save()}"
if not exist "C:\Program Files\Adobe\Adobe InDesign 2024\Scripts\Scripts Panel" goto :next
set/p "r=将删除 C:\Program Files\Adobe\Adobe InDesign 2024\Scripts\Scripts Panel 中的全部内容（1=是，0=否）："
if %r% neq 1 goto :next
del /q "C:\Program Files\Adobe\Adobe InDesign 2024\Scripts\Scripts Panel\*.*"
pushd "C:\Program Files\Adobe\Adobe InDesign 2024\Scripts\Scripts Panel"
rd /q /s "C:\Program Files\Adobe\Adobe InDesign 2024\Scripts\Scripts Panel" 2>nul
popd
:next
for /f "delims=" %%d in ('dir /b/s/ad "C:\Program Files\Adobe\*Scripts Panel"^|findstr /irc:"Adobe InDesign 202[0-9]" ') do for %%F in ("%Da%", "%Db%") do copy /y "%%~F.lnk" "%%d"
pause&exit/b

复制代码

ednykissyou · 发表于 2025-7-7 18:57:38

本帖最后由 ednykissyou 于 2025-7-7 19:08 编辑

回复 ednykissyou

如果真如18，21楼所述，快捷方式对应的完整路径名只能在用户运行批处脚本时确定，那 ...
aloha20200628 发表于 2025-7-7 16:07

aloha,非常感谢你的帮助，我用上了36楼 77七的了，他这个能够运行。
你个结构虽然简单，但不适合，用户是不会那么复杂的操作的。有时只会点点鼠标确认一下。

ednykissyou · 发表于 2025-7-7 19:01:59

回复 36# 77七
77七　你太生猛了。
非常感谢　能很好的运行。
只是我想把创建快捷方式的改为默认执行，这个不需确认的。
只有删除文件需提示。

话说我是十年老油条啦？时间过得真快，大事未成啊，你戳着我的伤点了。

77七 · 发表于 2025-7-7 19:33:58

回复 39# ednykissyou

删除第22、23、24、47、48行。

ednykissyou · 发表于 2025-7-7 19:49:28

本帖最后由 ednykissyou 于 2025-7-7 20:23 编辑

回复 40# 77七
好像不对。
是创建快捷方式时不需确认，默认执行。
只是删除时需确认。

aloha20200628 · 发表于 2025-7-7 19:51:58

回复 38# ednykissyou

你想要的就是以下这个填表式版本？只须代码第三行中的两个变量被替换为用户的真实完整路径值，即可完事大吉了...

@echo off &setlocal
%~1 powershell "start -file '%~f0' -arg '::' -verb runas" &exit/b
set "Da=d:\abc\AA" &set "Db=d:\abc\BB"
powershell "$ws=new-object -comobject wscript.shell;('%Da%','%Db%')|%%{$sc=$ws.createshortcut($_+'.lnk');$sc.targetpath=$_;$sc.save()}"
if not exist "C:\Program Files\Adobe\Adobe InDesign 2024\Scripts\Scripts Panel" goto :next
set/p "r=将删除 C:\Program Files\Adobe\Adobe InDesign 2024\Scripts\Scripts Panel 中的全部内容（1=是，0=否）："
if %r% neq 1 goto :next
del /q "C:\Program Files\Adobe\Adobe InDesign 2024\Scripts\Scripts Panel\*.*"
pushd "C:\Program Files\Adobe\Adobe InDesign 2024\Scripts\Scripts Panel"
rd /q /s "C:\Program Files\Adobe\Adobe InDesign 2024\Scripts\Scripts Panel" 2>nul
popd
:next
for /f "delims=" %%d in ('dir /b/s/ad "C:\Program Files\Adobe\*Scripts Panel"^|findstr /irc:"Adobe InDesign 202[0-9]" ') do for %%F in ("%Da%", "%Db%") do copy /y "%%~F.lnk" "%%d"
pause&exit/b

复制代码

ednykissyou · 发表于 2025-7-7 20:00:47

本帖最后由 ednykissyou 于 2025-7-7 20:20 编辑

回复 42# aloha20200628
要自动能获取aa bb所在目录, 因为不同用户可能喜欢放在不同位置。

77七 · 发表于 2025-7-7 20:22:33

回复 41# ednykissyou

删除那些行后，代码确认的是删除目录，不是是否创建。21行只是提示，也可以删。

ednykissyou · 发表于 2025-7-7 20:32:25

本帖最后由 ednykissyou 于 2025-7-7 20:35 编辑

回复 ednykissyou

删除那些行后，代码确认的是删除目录，不是是否创建。21行只是提示，也可以删。
77七发表于 2025-7-7 20:22

应该没删对，还在提示创建……
不是应该删18、19么？

		自动登录	找回密码
密码			注册

[新手上路]批处理新手入门导读	[视频教程]批处理基础视频教程	[视频教程]VBS基础视频教程	[批处理精品]批处理版照片整理器
[批处理精品]纯批处理备份&还原驱动	[批处理精品]CMD命令50条不能说的秘密	[在线下载]第三方命令行工具	[在线帮助]VBScript / JScript 在线参考

[文件操作] 求个批处理：将当前路径下的某个文件夹创建快捷方式，然后发送到指定路径？

浏览过的版块