【已解决】求助批处理删除特殊字符

lj670 · 发表于 2024-12-16 18:02:21

本帖最后由 lj670 于 2024-12-17 00:50 编辑

mp4文件名中包含有许多特殊字符☀ ✦ ♬ ♭ ♩等等需要删除掉，用删除一般字符的脚本无法删除这些，求助各位大佬，谢谢！🙏🙏
例如：
高清✦ 难以置信的美丽.mp4
高清难☀☀以置信的美丽.mp4
高清难以置信的♬ ♭美丽.mp4

77七 · 发表于 2024-12-16 19:16:47

本帖最后由 77七于 2024-12-16 19:21 编辑

@echo off
rem 保存为utf-8编码
chcp 65001 >nul
set str="☀" "✦" "♬" "♭" "♩"
for /f "delims=" %%i in ('dir /b /a-d *.mp4') do (
set n=%%~ni
if defined n (
setlocal enabledelayedexpansion
set _n=!n!
for %%a in (%str%) do (
set _n=!_n:%%~a=!
)
ren "!n!%%~xi" "!_n!%%~xi"
endlocal
)
)
pause

复制代码

Five66 · 发表于 2024-12-16 21:50:08

不知行否

@echo off&chcp 936
for %%a in (*.mp4) do (
set old=%%a
for /f "delims=" %%b in ('echo "%%a"') do (
set "new=%%~b"
setlocal enabledelayedexpansion
echo rename "!old!" to "!new:?=!"
rename "!old!" "!new:?=!"
endlocal
)
)
pause&exit/b

复制代码

aloha20200628 · 发表于 2024-12-17 00:07:11

回复 1# lj670

@echo off & chcp 936>nul &setlocal enabledelayedexpansion
for /f "delims=" %%a in ('dir /b/a-d *.mp4') do set "a=%%a" &ren "%%a" "!a:?=!"
pause&exit/b

复制代码

lj670 · 发表于 2024-12-17 00:09:00

回复 2# 77七

运行完美，非常好！谢谢🙏🙏

lj670 · 发表于 2024-12-17 00:46:01

回复 3# Five66

非常行，运行完美，不用指定，去除所有特殊字符，谢谢🙏🙏🙏

lj670 · 发表于 2024-12-17 00:49:18

回复 4# aloha20200628

运行完美，速度非常快，处理4150个视频用时65秒，谢谢🙏🙏

		自动登录	找回密码
密码			注册

[新手上路]批处理新手入门导读	[视频教程]批处理基础视频教程	[视频教程]VBS基础视频教程	[批处理精品]批处理版照片整理器
[批处理精品]纯批处理备份&还原驱动	[批处理精品]CMD命令50条不能说的秘密	[在线下载]第三方命令行工具	[在线帮助]VBScript / JScript 在线参考

[文件操作] 【已解决】求助批处理删除特殊字符

评分

评分

评分

评分

浏览过的版块