[已解决]批处理如何复制文件同名不覆盖，且重命名？

77七 · 发表于 2024-6-7 21:45:41

@echo off
set f1=d:\from
set f2=d:\to
cd /d "%f1%"
for /f "delims=" %%i in ('2^>nul dir /b /s /a-d *.txt *.rar') do (
set f=%%i
set nx=%%~nxi
set x=%%~xi
set n=1
call :1 "%%~nxi"
)
pause
exit
:1
for /f "tokens=1* delims=(" %%a in ("%~1") do (
if "%%b" neq "" (
call :1 "%%b"
) else (
for /f "tokens=* delims=0123456789" %%c in ("%%a") do (
if "%%c" equ ")%x%" (
call set "str=%%nx:(%%a=%x%%%"
) else (
set "str=%nx%"
)
setlocal enabledelayedexpansion
for /f "delims=" %%e in ("!str!") do (
endlocal
call :2 "%%e"
)
)
)
)
exit /b
:2
set /a n+=1
if not exist "%f2%\%~n1%~x1" (
copy "%f%" "%f2%\%~n1%~x1"
) else if not exist "%f2%\%~n1(%n%)%~x1" (
copy "%f%" "%f2%\%~n1(%n%)%~x1"
) else (
goto :2
)
exit /b

复制代码

aloha20200628 · 发表于 2024-6-8 17:02:52

本帖最后由 aloha20200628 于 2024-6-8 17:10 编辑

本帖楼主的原意是将多个子目录中的同名文件复制到目标目录时须作更名处理，其更名格式如 *(1).*，因源文件不包含类似 *(1).* 的文件，故解法要比另帖（http://www.bathome.net/thread-69152-1-1.html）来的轻快，但若假定源文件名可能包含 !&^ 等特殊字符时，其解法则须另辟捷径了》既要放弃延迟变量（以便兼容源文件名中的特殊字符），又要在循环中采用计数器（以便顺序匹配目标文件名），还要逃避复合语块中%n%变量的预处理...

@echo off &set "d1=c:\源目录" &set "d2=d:\目标目录"
pushd "%d2%"
for /f "delims=" %%a in (' dir /b/s/a-d "%d1%\*.txt" ') do (
if not exist "%%~nxa" (copy "%%a") else (
set/a "n=1" &set "F=%%a" &set "nF=%%~na" &set "xF=%%~xa"
(call :copy#n)
)
)
popd &pause &exit/b
:copy#n
if exist "%nF%(%n%)%xF%" (set/a "n+=1" &goto :copy#n)
copy "%F%" "%nF%(%n%)%xF%" &exit/b

复制代码

newswan · 发表于 2024-6-8 21:04:28

powershell 不必纠结 bat 特殊字符

$sour = ".\old"
$dest = ".\new"
$ext = "*.txt"
Get-ChildItem -Path $sour -Filter $ext | ForEach-Object {
if ( -Not (Test-Path ( Join-Path -Path $dest -ChildPath $_.Name )) ) {
Copy-Item -Path $_.FullName -Destination ( Join-Path -Path $dest -ChildPath $_.Name )
} else {
$i = 0
do {
$i++
}
while ( Test-Path ( Join-Path -Path $dest -ChildPath ($_.BaseName + $i + $_.Extension) ) )
Copy-Item -Path $_.FullName -Destination ( Join-Path -Path $dest -ChildPath ($_.BaseName + $i + $_.Extension) )
}
}

复制代码

aloha20200628 · 发表于 2024-6-8 22:15:02

本帖最后由 aloha20200628 于 2024-6-9 00:11 编辑

回复 18# newswan

每家都有几曲乡愁，彼此彼此，一方水土养一方人，苦乐痛痒其实一脉相通...

		自动登录	找回密码
密码			注册

[新手上路]批处理新手入门导读	[视频教程]批处理基础视频教程	[视频教程]VBS基础视频教程	[批处理精品]批处理版照片整理器
[批处理精品]纯批处理备份&还原驱动	[批处理精品]CMD命令50条不能说的秘密	[在线下载]第三方命令行工具	[在线帮助]VBScript / JScript 在线参考

[文件操作] [已解决]批处理如何复制文件同名不覆盖，且重命名？

评分