图片转动态视频时根据文本时间戳去计算持续时间的批处理

877 · 发表于 2024-5-20 18:18:16

@echo off
cd /d "%~dp0"
setlocal enabledelayedexpansion
for /l %%l in (1,2,10000) do (
set /a p1=%%l,p2=%%l+1
if exist "!p2!.jpg" (
ffmpeg -y -hwaccel_device 0 -i !p1!.jpg -i !p2!.jpg -filter_complex "[0:v]zoompan='1.5':x='if(lte(on,1),(iw-iw/zoom)/2,x)':y='if(lte(on,-1),(ih-ih/zoom)/2,y+3)':d=175[v0];[1:v]zoompan='1.5':x='if(lte(on,1),(iw-iw/zoom)/2,x)':y='if(lte(on,1),(ih/zoom)/2,y-3)':d=175[v1];[v0][v1]concat=n=2:v=1:a=0,format=yuv420p[v]" -map "[v]" -c:v h264_nvenc -gpu 0 out_!p1!.mp4
)
if exist "out_!p1!.mp4" (
>>x.txt echo file '%~dp0out_!p1!.mp4'
)
)
endlocal
ffmpeg -f concat -safe 0 -i x.txt -c copy output.mp4
del out_*.mp4;x.txt
pause

复制代码

以上代码每段动态视频的持续时间通过以下公式计算：
持续时间= 帧率（fps）/d参数值（帧）

我想对每张图片生成动态视频时的持续时间做出以下修改：
目录内有同名的txt和srt，例如：“真的爱你.txt”和“真的爱你.srt”
txt里面是多行文本，需要根据每一行的文本内容，去计算srt里面的文本内容持续时间是多少~

txt文本内容：
无法可修饰的一对手，带出温暖永远在背后。
总是啰嗦始终关注，不懂珍惜太内疚。

srt字幕内容：
1
00:00:00,366 --> 00:00:02,066
无法可修饰的一对手

2
00:00:02,116 --> 00:00:05,166
带出温暖永远在背后

3
00:00:05,216 --> 00:00:09,000
总是啰嗦始终关注

4
00:00:09,050 --> 00:00:12,400
不懂珍惜太内疚

需要计算txt第一行对应的srt时间戳，也就是第一行的持续时间是：00:00:00,000至00:00:05,166，00:00:05,166减去00:00:00,000就是第一张图片变为动态视频的持续时间为：05,166。
第二行对应的srt时间戳，00:00:05,216至00:00:12,400，00:00:12,400减去00:00:05,216等于07,184，07,184为第二张图片的持续时间！

有些复杂，大佬们是否理解~
欢迎77七大佬与各位大佬出手相助~
万分感谢大家！

Five66 · 发表于 2024-5-20 19:01:42

下面这样的情况下怎么弄

txt文本内容：
无法可修饰，的一对手，带出温暖，永远在背后。

srt字幕内容：
1
00:00:00,366 --> 00:00:02,066
带出温暖，永远在背后

2
00:00:02,116 --> 00:00:05,166
无法可修饰，的一对手

3
00:00:05,216 --> 00:00:09,000
无法可修饰，的一对手

4
00:00:09,050 --> 00:00:12,400
带出温暖，永远在背后

877 · 发表于 2024-5-20 19:17:58

本帖最后由 877 于 2024-5-20 19:53 编辑

回复 2# Five66

大佬好，我的思路是，可以先根据txt每一行的文本，去确定srt内容的时间戳是从哪里开始到哪里结束，
然后生成出来每一张图片需要的持续时间~，例如生成一个"真的爱你time.txt"，里面包含所有的持续时间~
然后生成时再按顺序调用~

有其他思路也行~

77七 · 发表于 2024-5-20 20:50:54

txt和srt 有什么对应规律？全是一行对6行？

877 · 发表于 2024-5-20 21:52:50

回复 4# 77七

如果txt文本内容只有1行(里面包含2个符号)：
无法可修饰的一对手，带出温暖永远在背后。

那么srt字幕内容会有如下2个：
1
00:00:00,366 --> 00:00:02,066
无法可修饰的一对手

2
00:00:02,116 --> 00:00:05,166
带出温暖永远在背后

77七 · 发表于 2024-5-20 22:19:56

本帖最后由 77七于 2024-5-20 22:31 编辑

回复 5# 877

请选择至少3对 txt和srt文件上传到网盘。

1
00:00:00,366 --> 00:00:02,066
无法可修饰的一对手

第一条时间前面的都视为0吗？

77七 · 发表于 2024-5-20 23:24:20

本帖最后由 77七于 2024-5-20 23:26 编辑

回复 8# 877

3对 txt和srt文件，一共6个文件。只提供几个特例，写了不一定能用。时间好算，ffmpeg代码我不会改。

877 · 发表于 2024-5-20 23:36:46

回复 9# 77七

大佬好，这是3行txt文本的示例，您下载看下~
获取到这三行正确的持续时间就行~输出到目录内，具体怎样修改替换ffmpeg的我再研究研究~
谢谢您~！
链接：https://pan.baidu.com/s/1idbduuU7xEhvoYnwAuSEkw?pwd=7777

877 · 发表于 2024-5-20 23:55:09

回复 7# 77七

ffmpeg代码应该是需要根据计算出来的持续时间，换算~

如果帧率是30fps，那么3秒就是90帧，5秒就是150帧。

然后，修改zoompan滤镜的d参数，

877 · 发表于 2024-5-21 00:01:10

回复 7# 77七

这是第一张持续3秒，第二张持续5秒的修改。。不够精确，大佬您看下~

ffmpeg -y -hwaccel_device 0 -i !p1!.jpg -i !p2!.jpg -filter_complex "[0:v]zoompan='1.5':z='1.0':d=90:x='if(lte(on,1),(iw-iw/zoom)/2,x)':y='if(lte(on,-1),(ih-ih/zoom)/2,y+3)'[v0];[1:v]zoompan='1.5':z='1.0':d=150:x='if(lte(on,1),(iw-iw/zoom)/2,x)':y='if(lte(on,1),(ih/zoom)/2,y-3)'[v1];[v0][v1]concat=n=2:v=1:a=0,format=yuv420p[v]" -map "[v]" -c:v h264_nvenc -gpu 0 out_!p1!.mp4

复制代码

77七 · 发表于 2024-5-21 01:21:14

回复 8# 877

@echo off
rem 批处理保存为utf-8编码格式
chcp 65001 >nul
for /f "delims=" %%i in ('dir /b /a-d *.srt') do (
setlocal enabledelayedexpansion
if exist "%%~ni.txt" (
for /f "useback tokens=1-3" %%a in ("%%i") do (
if "%%b" equ "-->" (
set /a _str=str*2-1,__str=str*2
set #!_str!=%%a
set #!__str!=%%c
)
if not defined str (
set str=1
) else (
set str=%%a
)
)
set #1=00:00:00,000
for /f "useback delims=" %%a in ("%%~ni.txt") do (
set str=%%a
for %%x in ("，" "，" "！" "。" "." "?" "？") do (
set "str=!str:%%~x= !"
)
for %%x in (!str!) do (
set /a n+=1,m+=2
if not defined s (
for /f %%y in ("#!n!") do (
set s=!%%y!
)
)
for /f %%y in ("#!m!") do (
set e=!%%y!
)
)
set n=!m!
for /f "tokens=1-4 delims=:," %%a in ("!s!") do (
set /a "t2mss=((1%%a%%100*60+1%%b%%100)*60+1%%c%%100)*1000+1%%d%%1000"
)
for /f "tokens=1-4 delims=:," %%a in ("!e!") do (
set /a "t2mse=((1%%a%%100*60+1%%b%%100)*60+1%%c%%100)*1000+1%%d%%1000"
)
set /a t=t2mse-t2mss
for /f "delims=" %%a in ('powershell -c "!t!/1000"') do (
set t=%%a
)
>> "%%~ni.time" echo !t!
set s=
)
)
endlocal
)
pause

复制代码

77七 · 发表于 2024-5-21 01:23:57

回复 10# 877

应该是p1 p2 对应 txt 的第一行和第二行吧？

@echo off
cd /d "%~dp0"
setlocal enabledelayedexpansion
for /f "useback delims=" %%a in ("真的爱你.time") do (
set /a n+=1
for /f "delims=" %%b in ('powershell -c "%%a*30"') do (
set #!n!=%%b
)
)
for /l %%l in (1,2,10000) do (
set /a p1=%%l,p2=%%l+1
if exist "!p2!.jpg" (
for /f "tokens=1-2" %%a in ("#!p1! #!p2!") do (
set d1=!%%a!
set d2=!%%b!
ffmpeg -y -hwaccel_device 0 -i !p1!.jpg -i !p2!.jpg -filter_complex "[0:v]zoompan='1.5':x='if(lte(on,1),(iw-iw/zoom)/2,x)':y='if(lte(on,-1),(ih-ih/zoom)/2,y+3)':d=!d1![v0];[1:v]zoompan='1.5':x='if(lte(on,1),(iw-iw/zoom)/2,x)':y='if(lte(on,1),(ih/zoom)/2,y-3)':d=!d2![v1];[v0][v1]concat=n=2:v=1:a=0,format=yuv420p[v]" -map "[v]" -c:v h264_nvenc -gpu 0 out_!p1!.mp4
)
)
if exist "out_!p1!.mp4" (
>>x.txt echo file '%~dp0out_!p1!.mp4'
)
)
endlocal
ffmpeg -f concat -safe 0 -i x.txt -c copy output.mp4
del out_*.mp4;x.txt
pause

复制代码

877 · 发表于 2024-5-21 05:35:18

回复 11# 77七

非常厉害77七大佬

，测试了，这样对着呢！

简直太牛了！！！

非常感谢我大哥！膜拜！

877 · 发表于 2024-5-21 05:59:09

回复 11# 77七

大佬，计算毫秒数这里我刚刚发现，每一组时间戳结束时间与下一组的开始都有一点的延迟~

第一组计算正确！下一组的开始时间能否修改为上一组的结束时间作为开始时间呢？
例如：
1
00:00:00,366 --> 00:00:02,066
2
00:00:02,116 --> 00:00:05,166

第一组的持续时间为：02,066正确，第二组改为05,166-02,066。
现在是05,166-02,116，这是我之前没有说清楚的缘故~
02,066和02,116延迟了50...

77七 · 发表于 2024-5-21 09:22:10

回复 14# 877

11楼代码28-30行，修改为：

if defined e (
set s=!e!
) else (
set s=00:00:00,000
)

复制代码

		自动登录	找回密码
密码			注册

[新手上路]批处理新手入门导读	[视频教程]批处理基础视频教程	[视频教程]VBS基础视频教程	[批处理精品]批处理版照片整理器
[批处理精品]纯批处理备份&还原驱动	[批处理精品]CMD命令50条不能说的秘密	[在线下载]第三方命令行工具	[在线帮助]VBScript / JScript 在线参考

[文本处理] 图片转动态视频时根据文本时间戳去计算持续时间的批处理