【已解决】批处理删除某一段代码

Zhanggli · 发表于 2023-9-1 15:17:22

现在需要删除的是T2-M05之间的代码，包括T2行，但是不包括M05，不同文件这两者之间的代码会有不同行数，另外在M05后面加一个指令M55，多个文件需要同样处理，我总是循环不起来。

hfxiang · 发表于 2023-9-1 15:52:19

回复 15# Zhanggli
可用第3方工具sed（ http://bcn.bathome.net/tool/4.9/sed.exe ）

sed -e"/T2/,/M05/{/M05/!d;s/M05/M05\nM55/;}" 1.txt>2.txt

复制代码

qixiaobin0715 · 发表于 2023-9-1 15:55:31

本帖最后由 qixiaobin0715 于 2023-9-1 17:21 编辑

@echo off
for /f "delims=" %%x in ('dir /b /a-d *.txt') do (
set n=0
(for /f "delims=" %%i in ('type "%%x"') do (
if "%%i"=="T2" set n=
if defined n echo,%%i
if "%%i"=="M05" (
set n=0
echo,%%i
echo,M55
)
))>"New-%%x"
)
pause

复制代码

Zhanggli · 发表于 2023-9-1 16:51:47

感谢qixiaobin，真的很简洁明了，再次感谢

Zhanggli · 发表于 2023-9-1 16:52:50

我之前的思路也是和前面的定义了两个字符串变量来处理反倒没搞好

Zhanggli · 发表于 2023-9-1 16:58:58

不过如果是多个文件同样处理的话需要引入临时文件变量temp吧？

77七 · 发表于 2023-9-1 16:59:31

回复 16# Zhanggli

@echo off
for /f "delims=" %%i in ('dir /b /a-d *.txt') do (
call :1 "%%i"
)
pause & exit
:1
setlocal
for /f "tokens=1* delims=:" %%a in ('findstr /nxr /c:"M05" /c:"T2" "%~1"') do (
if not defined s (
set s=%%a
) else (
set e=%%a
)
)
(for /f "tokens=1* delims=:" %%a in ('findstr /n .* "%~1"') do (
if %%a lss %s% (
echo=%%b
) else if %%a equ %e% (
echo=%%b
echo=M55
) else if %%a gtr %e% (
echo=%%b
)
))>$
move /y $ "%~1"
endlocal
exit /b

复制代码

qixiaobin0715 · 发表于 2023-9-1 17:21:41

回复 21# Zhanggli
已修改

Zhanggli · 发表于 2023-9-1 21:15:08

太赞了，我试了好几次循环都没成功，底子还是太弱了，再次感谢

lovekix · 发表于 2023-11-30 20:15:09

回复 9# 77七

微软总把制表符换成空格（有时候 9个有时候8个）

有时候还在会把
<Application Id="WindowsBackup" Executable="WindowsBackupClient.exe" EntryPoint="WindowsBackup.App" uap10:TrustLevel="mediumIL" uap10:RuntimeBehavior="windowsApp">"

替换成
<Application Id="WindowsBackup" Executable="WindowsBackupClient.exe" EntryPoint="WindowsBackup.App" uap10/4:TrustLevel="mediumIL" uap10/4:RuntimeBehavior="windowsApp">"

还有其他办法吗？

77七 · 发表于 2023-11-30 21:19:53

回复 25# lovekix

请把出现问题的文件传上来，看看是什么原因。

lovekix · 发表于 2023-12-1 08:48:49

本帖最后由 lovekix 于 2023-12-1 08:52 编辑

回复 26# 77七

https://wwrj.lanzouu.com/i461Y1ggo9zc

77七 · 发表于 2023-12-1 14:52:31

本帖最后由 77七于 2023-12-1 14:54 编辑

回复 27# lovekix

@echo off
set "str1=<Application Id="WindowsBackup" Executable="WindowsBackupClient.exe" EntryPoint="WindowsBackup.App" uap10[/]*[4]*:TrustLevel="mediumIL" uap10[/]*[4]*:RuntimeBehavior="windowsApp">"
set "str2=</Application>"
set "str1=%str1:"="""%"
for /f "tokens=1 delims=:" %%a in ('findstr /nxr /c:"[ ]*%str1%" "appxmanifest.xml"') do set start=%%a
for /f "tokens=1 delims=:" %%a in ('findstr /nxr /c:"[ ]*%str2%" "appxmanifest.xml"') do (
if %%a gtr %start% (
set end=%%a
goto :next
)
)
:next
(for /f "tokens=1* delims=:" %%a in ('findstr /n .* "appxmanifest.xml"') do (
if %%a lss %start% echo=%%b
if %%a gtr %end% echo=%%b
))>"appxmanifest-2.xml"
pause

复制代码

lovekix · 发表于 2023-12-1 17:57:25

回复 28# 77七

这行代码可以用* 代替后面的吗？

set "str1=<Application Id="WindowsBackup" Executable="WindowsBackupClient.exe" EntryPoint="WindowsBackup.App" uap10[/]*[4]*:TrustLevel="mediumIL" uap10[/]*[4]*:RuntimeBehavior="windowsApp">"

复制代码

set "str1=<Application Id="WindowsBackup" Executable="WindowsBackupClient.exe" EntryPoint="WindowsBackup.App"*>"

复制代码

77七 · 发表于 2023-12-1 18:24:38

回复 29# lovekix

.*
前面加个.

		自动登录	找回密码
密码			注册

[新手上路]批处理新手入门导读	[视频教程]批处理基础视频教程	[视频教程]VBS基础视频教程	[批处理精品]批处理版照片整理器
[批处理精品]纯批处理备份&还原驱动	[批处理精品]CMD命令50条不能说的秘密	[在线下载]第三方命令行工具	[在线帮助]VBScript / JScript 在线参考

[文本处理] 【已解决】批处理删除 某一段代码

[文本处理] 【已解决】批处理删除某一段代码