【已解决】求bat：替换含 wall 行内容（最好纯批处理，第三方也行）。谢谢

yyz219 · 发表于 2023-11-24 11:23:13

本帖最后由 yyz219 于 2023-11-25 12:31 编辑

完美解决了
方法1：
@echo off
set /p var=<1.txt
(for /f "tokens=1*" %%i in (a.txt) do (
if /i not "%%i"=="wall" (
if "%%j"=="" (echo,%%i) else (echo,%%i %%j)) else (echo,%%i %var%)))>temp
move /y "temp" "a.txt"
方法2：
@echo off
set "OldFile=a.txt"
set "NewFile=%OldFile%.tmp"
set "InputFile=1.txt"
cd /d "%~dp0"
set /p NewStr=<"%InputFile%"
(for /f "tokens=1* delims=:" %%a in ('findstr /n .* "%OldFile%"') do (
if "%%b" == "" (
      echo,
) else (
      set "OldStr=%%b"
      setlocal enabledelayedexpansion
      if not "!OldStr:wall =!" == "!OldStr!" (
         echo wall !NewStr!
      ) else (
         echo,!OldStr!
      )
      endlocal
)
))>"%NewFile%"
move /y "%NewFile%" "%OldFile%" >nul
********************************************************************************************************************************
原来的问题：
需要替换的文本 a.txt（其中： D:\PE整理碎片（很好）\修改PE\程序\!墙纸\灰色.jpg——不是固定的）：
... ...
//【3.设置墙纸】
wall D:\PE整理碎片（很好）\修改PE\程序\!墙纸\灰色.jpg
*********************************************************
处理以后需要的结果是：
... ...
//【3.设置墙纸】
wall X:\XX\XX\XX.jpg
其中：X:\XX\XX\XX.jpg————由 1.txt 提供

ShowCode · 发表于 2023-11-24 12:09:25

回复 1# yyz219

@echo off
set "OldFile=a.txt"
set "NewFile=%OldFile%.tmp"
set "InputFile=1.txt"
cd /d "%~dp0"
set /p NewStr=<"%InputFile%"
(for /f "tokens=1* delims=:" %%a in ('findstr /n .* "%OldFile%"') do (
if "%%b" == "" (
echo,
) else (
set "OldStr=%%b"
setlocal enabledelayedexpansion
if not "!OldStr:wall =!" == "!OldStr!" (
echo wall %NewStr%
) else (
echo,!OldStr!
)
endlocal
)
))>"%NewFile%"
move /y "%NewFile%" "%OldFile%" >nul

复制代码

yyz219 · 发表于 2023-11-24 12:25:54

回复 2# ShowCode
我试一试先谢谢

yyz219 · 发表于 2023-11-24 12:29:26

回复 2# ShowCode

成功了再次感谢

yyz219 · 发表于 2023-11-24 22:03:54

回复 2# ShowCode

*.JPG 的路径中，如果有！号，！号会丢失

例如：

D:\PE整理碎片（很好）\修改PE\程序\!墙纸\灰色.jpg
运行以后变为：

D:\PE整理碎片（很好）\修改PE\程序\墙纸\灰色.jpg

能不能修改一下？谢谢

ShowCode · 发表于 2023-11-24 23:16:06

回复 5# yyz219

2楼第14行的%NewStr%改成!NewStr!

@echo off
set "OldFile=a.txt"
set "NewFile=%OldFile%.tmp"
set "InputFile=1.txt"
cd /d "%~dp0"
set /p NewStr=<"%InputFile%"
(for /f "tokens=1* delims=:" %%a in ('findstr /n .* "%OldFile%"') do (
if "%%b" == "" (
echo,
) else (
set "OldStr=%%b"
setlocal enabledelayedexpansion
if not "!OldStr:wall =!" == "!OldStr!" (
echo wall !NewStr!
) else (
echo,!OldStr!
)
endlocal
)
))>"%NewFile%"
move /y "%NewFile%" "%OldFile%" >nul

复制代码

yyz219 · 发表于 2023-11-25 07:42:54

回复 6# ShowCode
再次感谢

qixiaobin0715 · 发表于 2023-11-25 09:05:11

@echo off
set /p var=<1.txt
(for /f "tokens=1*" %%i in (a.txt) do (
if /i not "%%i"=="wall" (
if "%%j"=="" (
echo,%%i
) else (
echo,%%i %%j
)
) else (
echo,%%i %var%
)
))>temp
move /y "temp" "a.txt"

复制代码

yyz219 · 发表于 2023-11-25 10:18:36

回复 8# qixiaobin0715

我试一试先谢谢

yyz219 · 发表于 2023-11-25 10:32:56

回复 8# qixiaobin0715

成功了再次感谢

		自动登录	找回密码
密码			注册

[新手上路]批处理新手入门导读	[视频教程]批处理基础视频教程	[视频教程]VBS基础视频教程	[批处理精品]批处理版照片整理器
[批处理精品]纯批处理备份&还原驱动	[批处理精品]CMD命令50条不能说的秘密	[在线下载]第三方命令行工具	[在线帮助]VBScript / JScript 在线参考

[文本处理] 【已解决】求bat：替换含 wall 行内容（最好纯批处理，第三方也行）。谢谢

评分

评分

评分

评分