【已解决】求助：去文件名空格.bat，命令语法不正确。

yyz219 · 发表于 2023-9-15 23:47:31

本帖最后由 yyz219 于 2023-9-17 09:31 编辑

完美解决了：

::【文件名去空格（本目录全部）】
版本1：
@echo off
cls
echo.
echo.
echo 【文件名去空格（本目录全部）】？
pause>nul 2>nul
cls
set "str= "
for /f "delims=" %%i in ('dir /b *.*') do (
set "var=%%i" & Setlocal Enabledelayedexpansion & ren "!var!" "!var:%str%=!" & endlocal)
exit

版本2：

@echo off
::【文件名去空格】【结尾不能有：exit 】
echo.
echo.
echo 【文件名去空格（本目录全部）】？
pause>nul 2>nul
for %%f in (*) do call :r %%f
:r
set f=%* & ren "%f%" %f: =%

*********************************************
原来的问题：
::【去文件名空格】
@echo off
Setlocal Enabledelayedexpansion & set "str= "
for /f "delims=" %%i in ('dir /b *.*') do (set "var=%%i" & ren "%%i" "!var:%str%=!")
pause>nul 2>nul
*********************************************
运行后提示：命令语法不正确。（实际上：除了含！号的文件名不能够去空格外，普通文件名还是能够去空格的）

这是为什么？
********************************************************
原因已经查到了：是因为文件夹里面的文件名，有一个文件名字是！号开头的

就是不知道，应该怎样解决？谢谢

Five66 · 发表于 2023-9-15 23:59:29

大概是ren "%%i" "!var:%str%=!")中的)被当成了ren的一部分

yyz219 · 发表于 2023-9-16 00:56:41

大概是ren "%%i" "!var:%str%=!")中的)被当成了ren的一部分
Five66 发表于 2023-9-15 23:59

原因已经查到了：是因为文件夹里面的文件名，有一个文件名字是！号开头的

就是不知道，应该怎样解决？谢谢

Five66 · 发表于 2023-9-16 01:31:31

试试看看这样行不行吧
(批处理文件自身有空格好像也会被改名)

@echo off
set "str= "
for /f "delims=" %%i in ('dir /b *.*') do (
set "var=%%i"
Setlocal Enabledelayedexpansion
ren "!var!" "!var:%str%=!"
endlocal
)
pause>nul 2>nul

复制代码

yyz219 · 发表于 2023-9-16 08:08:06

试试看看这样行不行吧
(批处理文件自身有空格好像也会被改名)
Five66 发表于 2023-9-16 01:31

我试一试先谢谢

yyz219 · 发表于 2023-9-16 08:12:19

试试看看这样行不行吧
(批处理文件自身有空格好像也会被改名)
Five66 发表于 2023-9-16 01:31

成功了再次感谢

Batcher · 发表于 2023-9-16 13:30:50

回复 4# Five66

排除自身-1.bat

@echo off
for /f "delims=" %%i in ('dir /b /a-d') do (
if "%%i" neq "%~nx0" (
set "OldName=%%i"
setlocal enabledelayedexpansion
set "NewName=!OldName: =!"
if "!OldName!" neq "!NewName!" (
ren "!OldName!" "!NewName!"
)
endlocal
)
)

复制代码

Batcher · 发表于 2023-9-16 13:34:20

回复 4# Five66

排除自身-2.bat

@echo off
for /f "delims=" %%i in ('dir /b /a-d ^| findstr /v /i /x /c:"%~nx0"') do (
set "OldName=%%i"
setlocal enabledelayedexpansion
set "NewName=!OldName: =!"
if "!OldName!" neq "!NewName!" (
ren "!OldName!" "!NewName!"
)
endlocal
)

复制代码

yyz219 · 发表于 2023-9-16 18:24:24

回复 Five66

排除自身-2.bat
Batcher 发表于 2023-9-16 13:34

非常感谢

yyz219 · 发表于 2023-9-16 18:25:40

回复 7# Batcher

再次感谢

		自动登录	找回密码
密码			注册

[新手上路]批处理新手入门导读	[视频教程]批处理基础视频教程	[视频教程]VBS基础视频教程	[批处理精品]批处理版照片整理器
[批处理精品]纯批处理备份&还原驱动	[批处理精品]CMD命令50条不能说的秘密	[在线下载]第三方命令行工具	[在线帮助]VBScript / JScript 在线参考

[其他] 【已解决】求助：去文件名空格.bat，命令语法不正确。

评分

评分

评分

评分