[已解决]批处理for语句中使用wmic命令的奇怪问题

fantasybb · 发表于 2015-6-16 17:28:49

WMIC LOGICALDISK get DESCRIPTION,DEVICEID,FILESYSTEM,SIZE,FREESPACE

复制代码

这条命令直接在cmd中执行结果如下：
Description DeviceID  FileSystem  FreeSpace    Size
本地固定磁盘  C:       NTFS       261877760    39419113472
本地固定磁盘  D:       NTFS       180770955264  229895041024
本地固定磁盘  E:       NTFS       137467572224  230686715904

但是，放到批处理的for语句里：

@echo off
for /f "delims= " %%a in ('WMIC LOGICALDISK get DESCRIPTION,DEVICEID,FILESYSTEM,SIZE,FREESPACE') do echo %%a
pause

复制代码

执行后，就会报错：GET表达式无效

请教大家，是什么原因，怎么解决？谢谢！

CrLf · 发表于 2015-6-16 18:43:57

逗号要转义

fantasybb · 发表于 2015-6-16 19:24:31

明白啦，谢谢

tiandyoin · 发表于 2023-9-2 00:06:25

本帖最后由 tiandyoin 于 2023-9-2 00:07 编辑

回复 2# CrLf

rem Windows 规定文件名违法字符: 【*\/|:"<>? 】
rem ;1,%~2%,%~,!%~3!,!%%~4!,!!%%5!!^^^,)(.)(,& ;set ==!@#$%^&_+{}`-=[];',..txt
rem ;1,%~2%,%~,!%~3!,!%%~4!,!!%%5!!^^^,)(.)(,& ;set ==!@#$%^&_+{}`-=[];',..txt.lnk
call set "filepath=%%%~1%%"
echo "lnkpath2=%filepath%"
set "filepath=%filepath:\=\\%"
echo "lnkpath3=%filepath%"
REM set "filepath=%filepath:,=,%"
REM echo "lnkpath4=%filepath%"
REM set "filepath=%filepath:`=``%"
REM echo "lnkpath5=%filepath%"
REM set "filepath=%filepath:;=^;%"
REM echo "lnkpath6=%filepath%"
REM set "filepath=%filepath:'=\'%"
REM echo "lnkpath7=%filepath%"
wmic path win32_shortcutfile where "name='%filepath%'" get target

复制代码

怎么转，转了十圈网上没找到答案。

Five66 · 发表于 2023-9-2 02:47:32

本帖最后由 Five66 于 2023-9-2 03:56 编辑

回复 4# tiandyoin
额，好像是双引号里面的才需要多层转义，已编辑

set "aaa=%~dp0%~1%"
set filepath=%aaa:\=\\%
wmic path win32_shortcutfile where name='%filepath%' get target
pause

复制代码

tiandyoin · 发表于 2023-9-2 18:18:25

回复 2# CrLf

@echo OFF
call :main_20230214_010127 %*
REM echo.&pause
@goto :EOF
@rem https://learn.microsoft.com/zh-cn/windows/win32/wmisdk/like-operator
:main_20230214_010127
@echo off
set "filepath=%~f1"
if not exist "%filepath%" set/p "filepath=filepath="
REM 脱去环境变量 filepath 左右两侧的双引号。
set filepath| findstr /i /r "^filepath=".*"$" > nul && set "filepath=%filepath:~1,-1%"
if not exist "%filepath%" exit /b 1
echo "lnkpath1=%filepath%"
call :get_lnk_target3 filepath returnVal
echo.
echo.dir "%returnVal%"
dir "%returnVal%"
@goto :eof
@rem Usage:
rem 获取快捷方式的目标路径。
:get_lnk_target3 {<@in &file=*.lnk> ,[@out target]}
@echo off||code by tiandyoin&title ^Call :get_lnk_target4 {^<@in ^&file=*.lnk^> ,[@out target]}
rem Windows 规定文件名违法字符: 【*\/|:"<>? 】
rem ;1,%~2%,%~,!%~3!,!%%~4!,!!%%5!!^^^,)(.()(,& ;set ==!@#$%^&_+{}`-=[];',..txt
rem ;1,%~2%,%~,!%~3!,!%%~4!,!!%%5!!^^^,)(.()(,& ;set ==!@#$%^&_+{}`-=[];',..txt.lnk
call set "filepath=%%%~1%%"
echo "lnkpath2=%filepath%"
set "filepath=%filepath:\=\\%"
echo "lnkpath3=%filepath%"
set "filepath=%filepath:'=\'%"
echo "lnkpath4=%filepath%"
set "filepath=%filepath:[=[[]%"
echo "lnkpath5=%filepath%"
set "filepath=%filepath:_=[_]%"
echo "lnkpath6=%filepath%"
rem 似乎没法转义逗号？？只能使用 Like 通配符 _（下划线）。
setlocal enabledelayedexpansion
set "filepath=!filepath:,=_!"
echo "lnkpath7=!filepath!"
set "filepath=!filepath:%%=[%%]!"
endlocal & set "filepath=%filepath%"
echo "lnkpath8=%filepath%"
set target=
for /f "skip=1 delims=" %%a in (
'wmic path win32_shortcutfile where "name like '%filepath%'" get target'
) do (
set "target=%%~a"
goto :BREAK
)
:BREAK
set "target=%target:~0,-2%"
if "%~2" neq "" (set "%~2=%target%") else echo "target=%target%"
@goto :eof

复制代码

找遍全网也没有找到转义逗号的方法，只能使用 like+通配符的方法搜索。

buyiyang · 发表于 2023-9-2 18:50:20

回复 6# tiandyoin

首先要知道为啥要转义逗号，因为它被当作谓词分隔符了，你这种情况可以用括号括起来：

for /f "delims=" %%i in ('"wmic path win32_shortcutfile where (name='C:\\ProgramData\\应用,商店.lnk') get target /value|findstr ."') do echo,%%i

复制代码

tiandyoin · 发表于 2023-9-19 22:41:45

本帖最后由 tiandyoin 于 2023-9-19 22:51 编辑

回复 7# buyiyang

那么如何转义百分号呢？比如我的路径是： "c:\Users\test\Desktop\;1,2,3A'%temp%.lnk"

不想让TEMP求值，
知道了，前面加 ^

setlocal enabledelayedexpansion
set "filepath=!filepath:%%=^%%!"
endlocal & set "filepath=%filepath%"
@ echo "lnkpath6=%filepath%"

复制代码

但又如何转义 ( 和 ) 两个括号呢?
比如我的路径是： "c:\Users\test\Desktop\;1,2,3A'%temp(%)().lnk"

tiandyoin · 发表于 2023-9-19 22:58:42

rem 手动创建 .lnk 系统可能会转义，要重新检查，改名为以下内容。
rem Windows 规定文件名违法字符: 【*\/|:"<>? 】
:: filename=;%1,%~2%,%~,if !%~3!==!%%~4!,!!%temp%!!%my%,^^^,)(.()(,& ;set a=!@#$%^&_+{}`-`=[];'',..txt
:: filename=;%1,%~2%,%~,if !%~3!==!%%~4!,!!%temp%!!%my%,^^^,)(.()(,& ;set a=!@#$%^&_+{}`-`=[];'',..txt.lnk

这是终极挑战

		自动登录	找回密码
密码			注册

[新手上路]批处理新手入门导读	[视频教程]批处理基础视频教程	[视频教程]VBS基础视频教程	[批处理精品]批处理版照片整理器
[批处理精品]纯批处理备份&还原驱动	[批处理精品]CMD命令50条不能说的秘密	[在线下载]第三方命令行工具	[在线帮助]VBScript / JScript 在线参考

[系统相关] [已解决]批处理for语句中使用wmic命令的奇怪问题

评分

评分