[已解决]批处理按照顺序合并PDF 文件

feiyan · 发表于 2023-6-24 19:11:09

1.在当前目录有多个文件夹，每个文件夹内有多个PDF 文件。
2.想把每个文件内的多个pdf 文件合并成一个pdf,存在在这个文件夹内，用这个文件夹名来命名这个合并PDF 文件。

举例，文件夹名称：S123 包含（1.pdf, 2.pdf, 3.pdf, 4.pdf,5.pdf)等多个pdf 文件，要求合并后文件名称是S123,
在当前目录下，这样类似的文件夹有多个。

77七 · 发表于 2023-6-24 21:19:38

@echo off
rem 站内下载pdftk，修改为实际路径
set "pdftk=C:\PDFtk\PDFtk\pdftk.exe"
for /d %%d in (*) do (
pushd "%%d"
setlocal enabledelayedexpansion
for /f "delims=" %%a in ('dir /b /a-d *.pdf ^|findstr /vbc:"S" /vbc:"D C F" /vbc:"D C S" /vbc:"D P" /vbc:"D F"') do (
set "str=!str! "%%a""
)
"%pdftk%" "S*.pdf" "D C F*.pdf" "D C S*.pdf" !str! "D P*.pdf" "D F*.pdf" cat output "%%~nxd.pdf"
endlocal
popd
)
pause

复制代码

Batcher · 发表于 2023-6-25 07:45:12

回复 2# 77七

findstr的这些条件是为了满足顶楼的哪个需求？

Batcher · 发表于 2023-6-25 07:52:40

回复 1# feiyan

test-1.bat

@echo off
REM 1、下载命令行工具PDFtk
REM http://bcn.bathome.net/s/tool/index.html?key=PDFtk
REM 2、根据自己电脑实际安装路径设置以下临时环境变量
set "path=C:\Program Files (x86)\PDFtk Server\bin;%path%"
cd /d "%~dp0"
for /d %%i in (*) do (
pushd "%%i"
echo 正在处理文件夹：%%i
pdftk.exe *.pdf cat output "%%~nxi.pdf"
popd
)
pause

复制代码

Batcher · 发表于 2023-6-25 07:54:00

回复 1# feiyan

test-2.bat

@echo off
REM 1、下载命令行工具PDFtk
REM http://bcn.bathome.net/s/tool/index.html?key=PDFtk
REM 2、根据自己电脑实际安装路径设置以下临时环境变量
set "path=C:\Program Files (x86)\PDFtk Server\bin;%path%"
cd /d "%~dp0"
for /f "delims=" %%i in ('dir /b /ad') do (
pushd "%%i"
echo 正在处理文件夹：%%i
pdftk.exe *.pdf cat output "%%~nxi.pdf"
popd
)
pause

复制代码

77七 · 发表于 2023-6-25 11:51:41

回复 3# Batcher
站长，是这样的，楼主编辑了顶楼，把需求改简单了，之前是根据文件名开头指定了顺序合并，考虑楼主问题未解决，我就把原始需求的代码发上来了。

feiyan · 发表于 2023-6-25 12:13:44

回复 2# 77七
感谢77，当时我发现我描述的有点复杂，怕难以实现，后来就重新编辑了下，把要求变的简单点了，
其实我发现只要在 pdftk *.pdf cat （这个地方，使用首字母加通配符也可以达到我的要求，和你的思路有点类似，但是我的三角猫技术，不会把合并后的文件名称变成和文件夹名称一致。也不会把所有的文件夹都这样操作
你这个我跑了下，无法成功。

feiyan · 发表于 2023-6-25 12:30:56

回复 5# Batcher
感谢管理员batcher, 我拷贝试了下，无法成功，我还怕我的路径和你的不一样，特地在 bin 添加\pdftk.exe, 添加这个和不添加这个，我都试了下，还是无法成功
但是我使用最小白的方式，是可以合并的，证明我的软件是可以起作用的。（pdftk.exe *.pdf cat output 11.pdf）

77七 · 发表于 2023-6-25 13:07:29

回复 7# feiyan

提示什么？
把批处理保存为ansi编码格式，试试。

Batcher · 发表于 2023-6-25 14:29:10

回复 8# feiyan

请参考Q-04把bat文件保存为ANSI编码：
https://mp.weixin.qq.com/s/Koje4FufWxWBs7ioDy_LJA

feiyan · 发表于 2023-6-25 19:09:09

回复 10# Batcher
感谢，是我失误了，我把这个批处理放在这个文件夹里面，难怪一直不成功，放在外面就OK了

feiyan · 发表于 2023-6-25 19:12:44

回复 9# 77七
是我失误了，我把这个批处理放在文件夹里面了，所以一直不成功，放在外面就OK 了，感谢

feiyan · 发表于 2023-7-3 20:10:52

回复 2# 77七

@77七 77你好，是这样的，这个我用这个代码尝试下，发现最后会多合并几个文件进去，就是之前已经被定义顺序的这几个文件，也就是在（ !str! ）之前的几个文件名，最后还是会被重复合并到整个文件中。

77七 · 发表于 2023-7-4 18:58:54

回复 13# feiyan

@echo off
rem 站内下载pdftk，修改为实际路径
set "pdftk=C:\PDFtk\PDFtk\pdftk.exe"
for /d %%d in (*) do (
pushd "%%d"
setlocal enabledelayedexpansion
for /f "delims=" %%a in ('dir /b /a-d *.pdf ^|findstr /vbc:"S" /vbc:"D C F" /vbc:"D C S" /vbc:"D P" /vbc:"D F"') do (
set "str=!str! "%%a""
)
"%pdftk%" "S*.pdf" "D C F*.pdf" "D C S*.pdf" !str! "D P*.pdf" "D F*.pdf" cat output "%~dp0%%~nxd.pdf"
endlocal
popd
if exist "%%~nxd.pdf" (
move "%%~nxd.pdf" "%%d"
)
)
pause

复制代码

feiyan · 发表于 2023-7-4 20:13:06

回复 14# 77七
感谢77.

		自动登录	找回密码
密码			注册

[新手上路]批处理新手入门导读	[视频教程]批处理基础视频教程	[视频教程]VBS基础视频教程	[批处理精品]批处理版照片整理器
[批处理精品]纯批处理备份&还原驱动	[批处理精品]CMD命令50条不能说的秘密	[在线下载]第三方命令行工具	[在线帮助]VBScript / JScript 在线参考

[文件操作] [已解决]批处理按照顺序合并PDF 文件

评分