批处理重命名文件名后，第一个文件名出现重复文本，如何解决？

布布丁 · 发表于 2023-6-11 23:37:18

本帖最后由布布丁于 2023-6-11 23:39 编辑

手头有10个txt文件，每个文件只有2行内容。文件原名称为第一行文本的内容，现在需要重命名为：第二行文本的内容+原名称。举例说明：
文件原名称为：
001.泥坑.txt
003.春节.txt
005.最好的朋友.txt
007.捉迷藏.txt
009.猪妈妈在工作.txt
011.猪爸爸的眼镜不见了.txt
013.打嗝.txt
015.秘密.txt
017.野餐.txt
019.青蛙，虫子和蝴蝶.txt
----------------------------
期望重命名后的文件名称为：
002.双胞胎熊猫_001.泥坑.txt
004.恐龙先生弄丢了_003.春节.txt
006.鹦鹉波莉_005.最好的朋友.txt
008.乔治第一天上幼儿园_007.捉迷藏.txt
010.中间的小猪_009.猪妈妈在工作.txt
012.花园种菜_011.猪爸爸的眼镜不见了.txt
014.自行车_013.打嗝.txt
016.放风筝_015.秘密.txt
018.乐器_017.野餐.txt
020.装扮游戏_019.青蛙，虫子和蝴蝶.txt
-------------------------------------------
按照下面的脚本:

@echo off
setlocal enabledelayedexpansion
for %%a in (*.txt) do set "txt=%%a" & call :aa
pause
:aa
for /f "usebackq skip=1 delims=*" %%b in ("!txt!") do (
set "a=%%a" & set "b=%%b"
ren "!a!" "!b!_!a!"
goto :eof
)

复制代码

执行后，文件名称为：
002.双胞胎熊猫_002.双胞胎熊猫_001.泥坑.txt
004.恐龙先生弄丢了_003.春节.txt
006.鹦鹉波莉_005.最好的朋友.txt
008.乔治第一天上幼儿园_007.捉迷藏.txt
010.中间的小猪_009.猪妈妈在工作.txt
012.花园种菜_011.猪爸爸的眼镜不见了.txt
014.自行车_013.打嗝.txt
016.放风筝_015.秘密.txt
018.乐器_017.野餐.txt
020.装扮游戏_019.青蛙，虫子和蝴蝶.txt
--------------------------------------------------
即第一个文件名中，"002.双胞胎熊猫_002.双胞胎熊猫"出现了重复（实际第一个文件第二行文本内容为：002.双胞胎熊猫）。
请帮忙看看为什么第一个文件名中会出现重复？该如何修正脚本呢？

77七 · 发表于 2023-6-11 23:53:16

说明对001.泥坑.txt 这个文件执行了两次重命名操作
把脚本第三行改为

for /f "delims=" %%a in ('dir /b /a-d *.txt') do set "txt=%%a" & call :aa

复制代码

试试

布布丁 · 发表于 2023-6-12 00:05:11

回复 2# 77七
果然好了，感谢感谢！

qixiaobin0715 · 发表于 2023-6-12 09:43:55

@echo off
setlocal enabledelayedexpansion
for /f "delims=" %%a in ('dir /b /a-d *.txt') do (
for /f "delims=" %%i in ('type "%%a"') do set Prefix=%%i
ren "%%a" "!Prefix!_%%a"
)
pause

复制代码

布布丁 · 发表于 2023-6-12 12:24:58

回复 4# qixiaobin0715
如果Prefix是指定行文本（比如第5行），如何改进呢？

qixiaobin0715 · 发表于 2023-6-12 12:35:51

@echo off
set LineNo=5
setlocal enabledelayedexpansion
for /f "delims=" %%a in ('dir /b /a-d *.txt') do (
set n=0
for /f "delims=" %%i in ('type "%%a"') do (
set /a n+=1
if !n! equ %LineNo% set Prefix=%%i
)
if defined Prefix ren "%%a" "!Prefix!_%%a"
set Prefix=
)
pause

复制代码

		自动登录	找回密码
密码			注册

[新手上路]批处理新手入门导读	[视频教程]批处理基础视频教程	[视频教程]VBS基础视频教程	[批处理精品]批处理版照片整理器
[批处理精品]纯批处理备份&还原驱动	[批处理精品]CMD命令50条不能说的秘密	[在线下载]第三方命令行工具	[在线帮助]VBScript / JScript 在线参考

[文本处理] 批处理重命名文件名后，第一个文件名出现重复文本，如何解决？

评分

评分