批处理如何在变量多个参数中查找到需要的字符？

szl1123 · 发表于 2023-4-30 22:35:27

已知变量
%mz% =45 45 89 365 56 94 56584 364
如何查找到包含658的参数并设置到变量%m%
得到变量%m%=56584

这个查找的包含658字符的参数位置不固定。

77七 · 发表于 2023-5-1 00:05:30

@echo off
set "mz=45 45 89 365 56 94 56584 364"
for %%a in (%mz%) do (
echo %%a|find "658" 1>nul && set m=%%a
)
pause

复制代码

Batcher · 发表于 2023-5-1 09:04:15

回复 1# szl1123

如果有多个参数包含658，希望如何处理？

Batcher · 发表于 2023-5-1 09:09:53

回复 1# szl1123

减少外部命令find调用

@echo off
setlocal enabledelayedexpansion
set "mz=45 45 89 365 56 94 56584 364"
for %%a in (%mz%) do (
set "x=%%a"
if "!x:658=!" neq "%%a" (
set "m=%%a"
)
)
echo,%m%
pause

复制代码

szl1123 · 发表于 2023-5-1 10:08:34

回复 2# 77七

非常感谢老师

szl1123 · 发表于 2023-5-1 10:09:17

回复 3# Batcher

目前应该不会有重复的结果

szl1123 · 发表于 2023-5-1 10:09:48

回复 4# Batcher

感谢各位老师，

szl1123 · 发表于 2023-5-1 13:30:51

回复 2# 77七

现在还有一个情况
%mz% =45 45 89 365 56 94 56584 364 5468
查找到包含658的参数后，要得到这个参数以及后面的所有字符，设置到变量%m%
得到结果应该是
%m%=56584 364 5468
包含后面的空格

还请各位老师帮忙解答一下，谢谢。

77七 · 发表于 2023-5-1 14:11:03

回复 8# szl1123

@echo off
setlocal enabledelayedexpansion
set "mz=45 45 89 365 56 94 56584 364 5468"
for %%a in (%mz%) do (
echo %%a|find "658" 1>nul && set "m=%%a" || (
if defined m (
set "m=!m! %%a"
)
)
)
echo %m%
endlocal
pause

复制代码

terse · 发表于 2023-5-1 17:03:55

@echo off
setlocal enabledelayedexpansion
set "mz=45 45 89 365 56 94 56584 364 5468"
for %%a in (%mz%) do (
set "x=%%a"
if not defined m (
if "!x:658=!" neq "%%a" (
set "m=%%a"
)
) else set "m=!m! %%a"
)
echo,%m%
pause

复制代码

		自动登录	找回密码
密码			注册

[新手上路]批处理新手入门导读	[视频教程]批处理基础视频教程	[视频教程]VBS基础视频教程	[批处理精品]批处理版照片整理器
[批处理精品]纯批处理备份&还原驱动	[批处理精品]CMD命令50条不能说的秘密	[在线下载]第三方命令行工具	[在线帮助]VBScript / JScript 在线参考

[文本处理] 批处理如何在变量多个参数中查找到需要的字符？