【已解决】求化简bat删除文件、启动应用，谢谢

yyz219 · 发表于 2021-10-20 15:54:29

一个文件夹内有：Tab0.txt，Tab1.txt。Tab2.txt，Tab3.txt................
现在要保留：Tab0.txt和Tab2.txt，删除其它*.txt文件.
——————————————————————————————————
下面的批处理可以实现，但是我觉得不科学，老师们看看怎么化简？谢谢

@echo off
::Tab0.txt是“QQ号码”不能删除、Tab2.txt是“自动保存”不能删除
del Tab1.txt >nul 2>nul
del Tab3.txt >nul 2>nul
del Tab4.txt >nul 2>nul
del Tab5.txt >nul 2>nul
del Tab6.txt >nul 2>nul
del Tab7.txt >nul 2>nul
del Tab8.txt >nul 2>nul
del Tab9.txt >nul 2>nul
del Tab10.txt >nul 2>nul
del Tab11.txt >nul 2>nul
del Tab12.txt >nul 2>nul
::下面新建“Tab1.txt”
echo,>Tab1.txt
start "" 文本收集器.exe
exit

复制代码

qixiaobin0715 · 发表于 2021-10-20 16:17:05

本帖最后由 qixiaobin0715 于 2021-10-20 16:19 编辑

@echo off
for /l %%a in (3,1,12) do del Tab%%a.txt
::不用新建“Tab1.txt”，你下面这行代码就已经清空了“Tab1.txt”中的原来所有内容。
echo,>Tab1.txt
start "" 文本收集器.exe
exit

复制代码

yyz219 · 发表于 2021-10-20 16:28:11

回复 2# qixiaobin0715

我试一试先，谢谢

yyz219 · 发表于 2021-10-20 17:01:13

本帖最后由 yyz219 于 2021-10-20 21:06 编辑

回复 2# qixiaobin0715

能够解释一下。in (3,1,12)里面的3和1代表什么吗？
谢谢！
【已经基本弄明白：整行功能是，搜索并删除由3~12，其中1是步长】

Fit · 发表于 2021-10-20 17:14:30

@echo off
for %%i in (*.txt) do (
   if not "%i"=="Tab0.txt" (
   if not "%i"=="Tab2.txt" (
      del %i /q)
   )
)
pause

yyz219 · 发表于 2021-10-20 17:24:24

回复 5# Fit
我找个时间试一试。谢谢！

Batcher · 发表于 2021-10-20 17:27:38

回复 4# yyz219

参考for命令教程第15页：
http://bbs.bathome.net/thread-31727-1-1.html

aloha20200628 · 发表于 2021-10-20 19:17:41

可以试试如下代码：
ren Tab0.txt Tab0.0
ren Tab2.txt Tab2.2
del /q *.txt
ren Tab0.0 Tab0.txt
ren Tab2.2 Tab2.txt

yyz219 · 发表于 2021-10-20 20:09:57

回复 5# Fit

下面这个才正确：
@echo off
for %%i in (*.txt) do (
   if not "%%i"=="Tab0.txt" (
   if not "%%i"=="Tab2.txt" (
      del %%i /q)
   )
)
pause

yyz219 · 发表于 2021-10-20 20:11:17

回复 8# aloha20200628

能够实现，谢谢

Fit · 发表于 2021-10-21 08:14:49

%i 全部变成 %%i

yyz219 · 发表于 2021-10-21 09:14:57

%i 全部变成 %%i
Fit 发表于 2021-10-21 08:14

是的

否则提示找不到：%i

qixiaobin0715 · 发表于 2021-10-21 09:49:34

回复 1# yyz219
2楼代码有局限性，文件数量发生变化时，要修改终值，下面代码通用性要好一些：

@echo off
for /f "delims=" %%a in ('dir /b /a-d *.txt ^| findstr /rv "Tab[0-2]\.txt"') do del %%a
echo,>Tab1.txt
start "" 文本收集器.exe
exit

复制代码

代码未经测试。

yyz219 · 发表于 2021-10-21 10:10:40

回复 13# qixiaobin0715

试了有效（终值不受限制）

辛苦了

		自动登录	找回密码
密码			注册

[新手上路]批处理新手入门导读	[视频教程]批处理基础视频教程	[视频教程]VBS基础视频教程	[批处理精品]批处理版照片整理器
[批处理精品]纯批处理备份&还原驱动	[批处理精品]CMD命令50条不能说的秘密	[在线下载]第三方命令行工具	[在线帮助]VBScript / JScript 在线参考

[文件操作] 【已解决】求化简bat删除文件、启动应用，谢谢

评分

评分

评分

评分