[已解决]BAT脚本怎样批量以文件夹名命名全部文件

无情浪子哥 · 发表于 2021-5-7 10:58:04

本帖最后由无情浪子哥于 2021-5-8 15:43 编辑

举例说明
原来：
文件夹名称：JC00101
文件夹内文件名称：房屋背面、房屋右侧、房屋正面

修改：
文件夹名称：JC00101
文件夹内文件名称：JC00101房屋背面、JC00101房屋右侧、JC00101房屋正面

这其中有子文件夹、子子文件夹

批量命名文件夹内文件，但文件夹内文件名称不动，增加文件夹名称在文件前面

无情浪子哥 · 发表于 2021-5-7 11:05:04

https://wwa.lanzous.com/iIBvSovuova

qixiaobin0715 · 发表于 2021-5-7 11:48:36

本帖最后由 qixiaobin0715 于 2021-5-7 14:36 编辑

未测试

@echo off
for /f "delims=" %%a in ('dir /b /s /a-d') do (
for %%i in ("%%~dp0.") do ren "%%a" "%%~ni%%~nxa"
)
pause

复制代码

无情浪子哥 · 发表于 2021-5-7 14:30:07

回复 3# qixiaobin0715
一级文件夹可以使用，二级、三级无法使用

qixiaobin0715 · 发表于 2021-5-7 14:37:23

回复 4# 无情浪子哥
3楼代码已修改

无情浪子哥 · 发表于 2021-5-7 14:45:29

回复 5# qixiaobin0715

你好是可以使用了,但不能以一级文件夹名称命名所有文件了

qixiaobin0715 · 发表于 2021-5-7 14:54:34

回复 6# 无情浪子哥
那是你没说明白
bat放在一级文件夹内

无情浪子哥 · 发表于 2021-5-7 14:56:05

回复 7# qixiaobin0715

我有几百个一级文件夹，不能只放一个一级文件夹

newswan · 发表于 2021-5-7 14:59:22

@echo off
setlocal enableDelayedExpansion
set stra=t1
call :f1 "%~1"
goto :END
:f1
cd %1
for /f "usebackq delims=" %%a in (` dir /b `) do (
echo "%%a" "%stra%%%a"
)
pause
for /f "usebackq delims=" %%a in (` dir /b /ad `) do (
call :f1 "%%a"
)
cd ..
goto :eof
:END
pause

复制代码

处理的文件夹t1，如果正确，把echo 改成ren

qixiaobin0715 · 发表于 2021-5-7 15:33:31

回复 8# 无情浪子哥

@echo off
for /d %%a in (*) do (
pushd %%a
for /f "delims=" %%i in ('dir /b /s /a-d') do ren "%%i" "%%a%%~nxi"
popd
)
pause

复制代码

cutebe · 发表于 2021-5-7 17:17:24

判断一下文件名，防止多次累加目录名

::添加目录名前缀
@echo off
cd/d%~dp0
setlocal enableDelayedExpansion
for /f "delims=" %%d in ('dir/s/b/ad')do (
pushd %%d
call :strLen dLen "%%~nxd"
for /f "delims=" %%f in ('dir/b/a-d')do (
set "filename=%%f"
for /f %%s in ("!dlen!")do if "!filename:~,%%s!" neq "%%~nxd" ren "%%f" "%%~nxd%%f"
)
popd
)
pause
goto :eof
:strLen len str ::code by plp626
setlocal
set "$=%~2#"
set N=&for %%a in (4096 2048 1024 512 256 128 64 32 16)do if !$:~%%a!. NEQ . set/aN+=%%a&set $=!$:~%%a!
set $=!$!fedcba9876543210&set/aN+=0x!$:~16,1!
endlocal&set/a%1=%N%
goto :eof

复制代码

无情浪子哥 · 发表于 2021-5-8 15:36:04

本帖最后由无情浪子哥于 2021-5-8 15:41 编辑

回复 11# cutebe

九楼运行没有反应、十一楼只能到二级，三级四级没有反应

无情浪子哥 · 发表于 2021-5-8 15:38:23

回复 10# qixiaobin0715

谢谢，可以使用了

		自动登录	找回密码
密码			注册

[新手上路]批处理新手入门导读	[视频教程]批处理基础视频教程	[视频教程]VBS基础视频教程	[批处理精品]批处理版照片整理器
[批处理精品]纯批处理备份&还原驱动	[批处理精品]CMD命令50条不能说的秘密	[在线下载]第三方命令行工具	[在线帮助]VBScript / JScript 在线参考

[文件操作] [已解决]BAT脚本怎样批量以文件夹名命名全部文件

附件