批处理将二级文件夹下的文件名修改成一级加二级文件夹的名字,并放到一个文件夹下

twoflowe · 发表于 2021-3-15 17:43:27

我有多个文件夹，20210301VFA、20210302VFA、20210303VFA……
每一个文件夹下又有多个文件夹1、2、3、……
这些子文件夹下又有多个文件，其中一个txt文档的名字为report.txt,
我想要把这个二级文件夹下的子文件report.txt的名称批量重新命名，改为一级文件夹加二级文件夹名字，即20210301VFA/1/report.txt 路径下的report.txt重命名为20210301VFA1.txt，20210301VFA/2/report.txt路径下的report.txt重命名为20210301VFA2.txt，20210302VFA/1/report.txt 路径下的report.txt重命名为20210302VFA1.txt，以此类推，并将这些修改了名字的txt文档全部复制到一个新的命名为“VFA”的文件夹下，不知道有没有批处理的办法，请各位大神帮帮忙，非常感谢。

WHY · 发表于 2021-3-15 19:54:40

@echo off
for /f "delims=" %%i in ('dir /b /s report.txt?') do (
if /i "%%~xi" == ".txt" (
for /f "tokens=1,2 delims=|" %%j in ("%%i\..\..|%%i\..") do (
echo; ren "%%i" "%%~nxj%%~nxk%%~xi"
)
)
)
pause

复制代码

Batcher · 发表于 2021-3-15 20:01:24

回复 1# twoflowe

bat脚本和20210301VFA、20210302VFA、20210303VFA……放在同一级目录下

@echo off
setlocal enabledelayedexpansion
set "NewFolder=VFA"
cd /d "%~dp0"
if not exist "%NewFolder%" (
md "%NewFolder%"
)
for /f "delims=" %%i in ('dir /b /s /a-d "report.txt"') do (
for %%j in ("%%i\..\..") do (
set "NewFile=%%~nxj"
)
for %%j in ("%%i\..") do (
set "NewFile=!NewFile!%%~nxj%%~xi"
)
copy /y "%%i" "%NewFolder%\!NewFile!"
ren "%%i" "!NewFile!"
)

复制代码

请参考Q-04把bat文件保存为ANSI编码：
https://mp.weixin.qq.com/s/6lbb97qUOs1sTyKJfN0ZEQ

twoflowe · 发表于 2021-3-15 20:48:03

本帖最后由 twoflowe 于 2021-3-15 20:49 编辑

回复 2# WHY

您好，我试了一下，您的代码好像没办法达到我的目的，但依旧感谢您的回复，祝您天天开心

twoflowe · 发表于 2021-3-15 20:48:43

回复 3# Batcher

你好，感谢您的回复，代码非常好用，祝您身体健康，事事顺心

		自动登录	找回密码
密码			注册

[新手上路]批处理新手入门导读	[视频教程]批处理基础视频教程	[视频教程]VBS基础视频教程	[批处理精品]批处理版照片整理器
[批处理精品]纯批处理备份&还原驱动	[批处理精品]CMD命令50条不能说的秘密	[在线下载]第三方命令行工具	[在线帮助]VBScript / JScript 在线参考

[文件操作] 批处理将二级文件夹下的文件名修改成一级加二级文件夹的名字,并放到一个文件夹下