【已解决】批处理文件夹及文件夹内部的文件

qixiaobin0715 · 发表于 2020-10-15 12:06:43

你想表达的意思是：将最末级文件夹中的文件改名并上移一级，删除移空的文件夹。文件夹改名有意义吗？

miss_sokuber · 发表于 2020-10-15 12:16:46

回复 16# qixiaobin0715
你说的对，改名无任务意义，只需要重新创建新文件夹就好了，原谅我之前的胡乱描述

qixiaobin0715 · 发表于 2020-10-15 12:34:00

回复 15# miss_sokuber

我上面的意思是，不如0下的合并到0，1下的合并到1...。省得再创建新的文件夹了。

WHY · 发表于 2020-10-15 14:10:47

本帖最后由 WHY 于 2020-10-15 14:22 编辑

@echo off
setlocal enabledelayedexpansion
set /a x=0
for %%i in (attack dead hit run stand) do set "_!x!=%%i" & set /a x+=1
REM 查找png文件，其上一级目录名为a、d、h、r、s，上上一级目录名为数字0-4
for /f "delims=" %%i in ('dir /b /a-d /s *.png ^| findstr /i "\\[0-4]\\[adhrs]\\[^\\]*$"') do (
REM 当前png文件的上上一级目录
for %%j in ("%%i\..\..") do set "curPath=%%~fj"
if /i "!prePath!" NEQ "!curPath!" (
for %%j in ("%%i\..\..") do (
set /a n = "(%%~nj + 1) * 1000 + 1"
set "newFolder=!_%%~nj!"
md "%%i\..\..\..\!newFolder!" 2>nul
)
) else (
set /a n+=1
)
REM 前一个png文件的上上一级目录
set "prePath=!curPath!"
move "%%i" "%%i\..\..\..\!newFolder!\0!n!%%~xi"
)
REM 删除空目录
for /f "delims=" %%i in ('dir /b /ad /s ^| sort /r') do rd "%%i" 2>nul
pause

复制代码

WHY · 发表于 2020-10-15 14:27:46

描述得模模糊糊，看了好几遍才搞明白。

miss_sokuber · 发表于 2020-10-15 14:47:57

回复 19# WHY
实现效果基本已经达到了，就是命名没正确，能否看一下我最初发需求那里，我重新整理了，😁😁

WHY · 发表于 2020-10-15 15:03:03

回复 21# miss_sokuber

哪一条命令没正确？
脚本保存为 test.bat，编码格式选 ansi，test.bat 与 1001、1002 文件夹存放在同一级目录里面。
我测试没有问题。

miss_sokuber · 发表于 2020-10-15 15:12:04

回复 22# WHY
命令没问题，是图片命名搞错了，正确的是
attack包括0下面的a,d,h,r,s下的所有图片，最终生成的是010000，0100001，0100002...，020000，020001...，030000，040000，040001，040002，050001，050001，尾数是按0开始，后续的类推
dead包括1下面的a,d,h,r,s下的所有图片，最终生成的是010000，0100001，0100002...，020000，020001...，030000，040000，040001，040002，050001，050001，尾数是按0开始，后续的类推
hit包括2下面的a,d,h,r,s下的所有图片，最终生成的是010000，0100001，0100002...，020000，020001...，030000，040000，040001，040002，050001，050001，尾数是按0开始，后续的类推
run包括3下面的a,d,h,r,s下的所有图片，最终生成的是010000，0100001，0100002...，020000，020001...，030000，040000，040001，040002，050001，050001，尾数是按0开始，后续的类推
stand包括4下面的a,d,h,r,s下的所有图片，最终生成的是010000，0100001，0100002...，020000，020001...，030000，040000，040001，040002，050001，050001，尾数是按0开始，后续的类推

qixiaobin0715 · 发表于 2020-10-15 15:26:55

本帖最后由 qixiaobin0715 于 2020-10-15 16:22 编辑

你还是没说清楚：0文件夹下的文件名第二个数字应当是0+1=1，你怎么搞出来12345都有啊。
什么情况下0+1、什么情况下1+1、什么情况下2+1...？应当说清楚。

miss_sokuber · 发表于 2020-10-15 16:33:49

回复 24# qixiaobin0715
按文件夹a,d,h,r,s的顺序，也可以说是a下面的就是对应0+1，d下面的就是对应1+1，这样类推
你看我最最顶楼重新整理的，跟我回复给上一楼的表述，应该说清楚了吧😂😂

qixiaobin0715 · 发表于 2020-10-15 16:43:10

这么说不就清楚了吗！跟文件夹数字无关。与文件夹a,d,h,r,s有联系。a-1 d-2 h-3 r-4 s-5

miss_sokuber · 发表于 2020-10-15 16:47:58

回复 26# qixiaobin0715
是的，是的，我都有点想打我自己了，哈哈哈

qixiaobin0715 · 发表于 2020-10-15 17:10:06

这样代码也好写多了。

miss_sokuber · 发表于 2020-10-15 18:12:29

回复 28# qixiaobin0715

有结果了吗，兄弟

WHY · 发表于 2020-10-15 19:57:33

回复 23# miss_sokuber

这样试试，如果仍然不行，我放弃。

@echo off
setlocal enabledelayedexpansion
set /a x=0
for %%i in (attack dead hit run stand) do (
set "s=%%i" & set "s=!s:~0,1!"
set "_!x!=%%i"
set /a x+=1, #!s!=x
)
REM 查找png文件，其上一级目录名为a、d、h、r、s，上上一级目录名为数字0-4
for /f "delims=" %%i in ('dir /b /a-d /s *.png ^| findstr /i "\\[0-4]\\[adhrs]\\[^\\]*$"') do (
REM 当前png文件所在的目录
set "curPath=%%~dpi"
if /i "!prePath!" NEQ "!curPath!" (
for %%j in ("%%i\..") do set /a n = !#%%~nj! * 1000
REM png文件的上上一级目录
for %%j in ("%%i\..\..") do (
set "newFolder=!_%%~nj!"
md "%%i\..\..\..\!newFolder!" 2>nul
)
) else (
set /a n+=1
)
REM 前一个png文件所在的目录
set "prePath=%%~dpi"
move "%%i" "%%i\..\..\..\!newFolder!\0!n!%%~xi"
)
REM 删除空目录
for /f "delims=" %%i in ('dir /b /ad /s ^| sort /r') do rd "%%i" 2>nul
pause

复制代码

		自动登录	找回密码
密码			注册

[新手上路]批处理新手入门导读	[视频教程]批处理基础视频教程	[视频教程]VBS基础视频教程	[批处理精品]批处理版照片整理器
[批处理精品]纯批处理备份&还原驱动	[批处理精品]CMD命令50条不能说的秘密	[在线下载]第三方命令行工具	[在线帮助]VBScript / JScript 在线参考

[文件操作] 【已解决】批处理文件夹及文件夹内部的文件

评分