求助批处理字符显示显示在CMD窗口中间

enpany · 发表于 2020-8-14 10:51:36

如何在不改变CMD窗口的尺寸下，让输出字符显示在窗口中间？

zaqmlp · 发表于 2020-8-14 12:48:37

用制表符或空格控制缩进

a20150604 · 发表于 2020-8-14 12:51:27

WIN 10 有效

复制代码

enpany · 发表于 2020-8-14 14:03:39

回复 3# a20150604

WIN7下有没有效呢？

a20150604 · 发表于 2020-8-14 18:05:29

回复 4# enpany

仅 Win 10 有效
来个简单特效

@echo off & setlocal enabledelayedexpansion
REM VT100 参考
REM https://docs.microsoft.com/en-us/windows/console/console-virtual-terminal-sequences
for /F %%a in ('echo prompt $E^| cmd') do set "_ESC=%%a"
REM 窗口尺寸也可以不指定
mode 100,40
REM 移动周期: 正整数, 越小, 移动越快
set /a "cycle=2000"
set "rgb_red=%_ESC%[38;2;255;0;0m"
set "rgb_grn=%_ESC%[38;2;0;255;0m"
set "rgb_blu=%_ESC%[38;2;0;0;255m"
REM set "str=bbs.bathome.net"
set "str=%rgb_red%bbs.%rgb_grn%bathome%rgb_blu%.net"
set "str_clear=%rgb_red%bbs.%rgb_grn% %rgb_blu%.net"
for /f "tokens=3,4 delims=, " %%A in (
'powershell -command "&{$H=get-host;$H.ui.rawui;}"^|findstr /b WindowSize'
) do set /a "_win_wid=%%A, _win_hei=%%B, x_ubound=_win_wid-14" & REM 14 为 str 的长度 - 1
set /a "y= !random! %% _win_hei + 1, x= !random! %% x_ubound + 1"
set /a "dx=dy=1"
REM 隐藏光标 Hide the cursor
<nul set /p "=%_ESC%[?25l"
for /l %%a in (-9999999 1 9999999) do (
set /a "m=%%a %% cycle"
if !m!==0 (
<nul set /p "=%_ESC%[!y!;!x!H%str_clear%"
if !y! geq !_win_hei! set /a "dy=-1"
if !y! leq 1 set /a "dy=1"
if !x! geq !x_ubound! set /a "dx=-1"
if !x! leq 1 set /a "dx=1"
set /a "y+=dy,x+=dx"
<nul set /p "=%_ESC%[!y!;!x!H%str%"
)
)

复制代码

enpany · 发表于 2020-8-14 18:40:21

回复 5# a20150604

膜拜大佬

		自动登录	找回密码
密码			注册

[新手上路]批处理新手入门导读	[视频教程]批处理基础视频教程	[视频教程]VBS基础视频教程	[批处理精品]批处理版照片整理器
[批处理精品]纯批处理备份&还原驱动	[批处理精品]CMD命令50条不能说的秘密	[在线下载]第三方命令行工具	[在线帮助]VBScript / JScript 在线参考

[特效代码] 求助批处理字符显示显示在CMD窗口中间