求助，批处理更改文件夹下的文件名20

赚他一个亿 · 发表于 2020-7-20 17:09:00

更改文件夹下的mp4文件名字
源文件是这样的

Downtest_Channel40.mp4

复制代码

我想要改成这样的 IP监控点1_172.18.3.190_1_20191223082751_20191223082812_111111[/color].mp4

复制代码

注：前面的字和时间是有更改的，比如监控点2_172.18.3.191.............等等有模板之后我自己改一下前面的时间和监控点保存运行就可以了
最后的6位数字是随机的，这个无所谓，也可以改成0001-9999这样的顺序

赚他一个亿 · 发表于 2020-7-20 17:16:31

谢谢各位出谋划策

Batcher · 发表于 2020-7-20 19:15:13

回复 1# 赚他一个亿

这两个时间戳是根据什么规律得出来的呢？
IP监控点1_172.18.3.190_1_20191223082751_20191223082812_111111.mp4

赚他一个亿 · 发表于 2020-7-21 08:42:43

回复 3# Batcher

这个时间是根据视频监控下载时间确定的。20191223082751_20191223082812 20191223******—20191223******这日期后面六位数字可以不要。。sry

Batcher · 发表于 2020-7-21 09:05:46

回复 4# 赚他一个亿

我换个方式问这个问题哈，比如我只知道这个文件名 Downtest_Channel40.mp4 我应该根据什么规律来判断它的下载时间？

赚他一个亿 · 发表于 2020-7-21 10:13:59

本帖最后由赚他一个亿于 2020-7-21 10:22 编辑

回复 5# Batcher

这个下载时间我记得就行了。比如我下载的是2020720-2020721这个时间段的监控视频，就只需要在脚本里面手动改名字为 IP监控点1_172.18.3.190_1_20200720_20200721_111111.mp4 然后运行脚本就就可以了。

换个方式说就相当于把文件夹内的文件重新命名为脚本模板里面的名字。
文件夹内的源文件为Downtest_Channel40.mp4 Downtest_Channel40_1.mp4 Downtest_Channel40_2.mp4 我自己记得他是下载的20200720-20200721日的视频
那么我就打开脚本，改一下里面的关键词和日期。然后再运行。就批量改名字成功了

赚他一个亿 · 发表于 2020-7-21 10:22:57

谢谢大神耐心解答

zaqmlp · 发表于 2020-7-21 11:09:45

@echo off
cd /d "%~dp0"
set "prefix=IP监控点1"
set "ip=172.18.3.190"
set "num=1"
set "daterange=20191223_20191223"
set "ext=*.mp4"
for /f "tokens=1* delims=:" %%a in ('dir /a-d/b "%ext%"^|findstr /n .*') do (
set "f=%%b"
set "n=00000000%%a"
setlocal enabledelayedexpansion
echo;"!f!" --^> "%prefix%_%ip%_%num%_%daterange%_!n:~-6!%%~xb"
ren "!f!" "%prefix%_%ip%_%num%_%daterange%_!n:~-6!%%~xb"
endlocal
)
pause
exit

复制代码

Batcher · 发表于 2020-7-21 11:29:57

回复 6# 赚他一个亿

@echo off
setlocal enabledelayedexpansion
set "prefix=IP监控点1_172.18.3.190_1_20200720_20200721"
set "n=1000000"
cd /d "%~dp0"
for /f "delims=" %%i in ('dir /b /a-d "Downtest_*.mp4"') do (
set /a n+=1
ren "%%i" "%prefix%_!n:~-6!"%%~xi
)

复制代码

赚他一个亿 · 发表于 2020-7-21 16:13:03

回复 8# zaqmlp

感谢感谢都可以用的！
论坛我捐助了一半！

赚他一个亿 · 发表于 2020-7-21 16:13:49

回复 9# Batcher

感谢已可以用了
论坛捐助啦1

		自动登录	找回密码
密码			注册

[新手上路]批处理新手入门导读	[视频教程]批处理基础视频教程	[视频教程]VBS基础视频教程	[批处理精品]批处理版照片整理器
[批处理精品]纯批处理备份&还原驱动	[批处理精品]CMD命令50条不能说的秘密	[在线下载]第三方命令行工具	[在线帮助]VBScript / JScript 在线参考

求助，批处理更改文件夹下的文件名20

浏览过的版块