设为首页收藏本站
切换到宽版

 找回密码
 注册
搜索
批处理之家»论坛 › 批处理专区: BAT CMD DOS › BAT求助&讨论 › [已解决]请问这个批处理还能精简下吗
[新手上路]批处理新手入门导读[视频教程]批处理基础视频教程[视频教程]VBS基础视频教程[批处理精品]批处理版照片整理器
[批处理精品]纯批处理备份&还原驱动[批处理精品]CMD命令50条不能说的秘密[在线下载]第三方命令行工具[在线帮助]VBScript / JScript 在线参考
返回列表 发新帖
查看: 22731|回复: 6

[系统相关] [已解决]请问这个批处理还能精简下吗

[复制链接]
kli2018
发表于 2020-7-2 09:38:18 | 显示全部楼层 |阅读模式
本帖最后由 kli2018 于 2020-7-2 13:28 编辑

如题
  1. @echo off
  2. PUSHD %~dp0

  4. echo.
  5. echo 1.为常用图片格式文件添加右键打开
  6. echo.
  7. echo 2.删除
  8. echo.
  9. set /p file=请选择？(1/2):
  10. if "%file%"=="1" goto ql1
  11. if "%file%"=="2" goto ql2

  13. :ql1
  14. for /f "tokens=2 delims==" %%a in ('assoc .bmp') do set "pictype=%%a"
  15. call :addright
  16. for /f "tokens=2 delims==" %%a in ('assoc .gif') do set "pictype=%%a"
  17. call :addright
  18. for /f "tokens=2 delims==" %%a in ('assoc .ico') do set "pictype=%%a"
  19. call :addright
  20. for /f "tokens=2 delims==" %%a in ('assoc .jpg') do set "pictype=%%a"
  21. call :addright
  22. for /f "tokens=2 delims==" %%a in ('assoc .jpe') do set "pictype=%%a"
  23. call :addright
  24. for /f "tokens=2 delims==" %%a in ('assoc .jpeg') do set "pictype=%%a"
  25. call :addright
  26. for /f "tokens=2 delims==" %%a in ('assoc .png') do set "pictype=%%a"
  27. call :addright
  28. goto :EOF

  30. :ql2
  31. for /f "tokens=2 delims==" %%a in ('assoc .bmp') do set "pictype1=%%a"
  32. call :deleteright
  33. for /f "tokens=2 delims==" %%a in ('assoc .gif') do set "pictype1=%%a"
  34. call :deleteright
  35. for /f "tokens=2 delims==" %%a in ('assoc .ico') do set "pictype1=%%a"
  36. call :deleteright
  37. for /f "tokens=2 delims==" %%a in ('assoc .jpg') do set "pictype1=%%a"
  38. call :deleteright
  39. for /f "tokens=2 delims==" %%a in ('assoc .jpe') do set "pictype1=%%a"
  40. call :deleteright
  41. for /f "tokens=2 delims==" %%a in ('assoc .jpeg') do set "pictype1=%%a"
  42. call :deleteright
  43. for /f "tokens=2 delims==" %%a in ('assoc .png') do set "pictype1=%%a"
  44. call :deleteright
  45. goto :EOF

  47. :addright
  48. Reg.exe add "HKLM\SOFTWARE\Classes\%pictype%\shell\open1" /v "Icon" /t REG_SZ /d "%CD%\FSViewer.exe,0" /f
  49. Reg.exe add "HKLM\SOFTWARE\Classes\%pictype%\shell\open1" /ve /t REG_SZ /d "FSViewer" /f
  50. Reg.exe add "HKLM\SOFTWARE\Classes\%pictype%\shell\open1\command" /ve /t REG_SZ /d ""%CD%\FSViewer.exe" "%%1"" /f
  51. goto :EOF

  53. :deleteright
  54. Reg.exe delete "HKLM\SOFTWARE\Classes\%pictype1%\shell\open1" /f
  55. goto :EOF
复制代码
回复

举报

went
发表于 2020-7-2 12:07:21 | 显示全部楼层
  1. @echo off
  2. PUSHD %~dp0

  4. echo.
  5. echo 1.为常用图片格式文件添加右键打开
  6. echo.
  7. echo 2.删除
  8. echo.
  9. set /p file=请选择？(1/2):
  10. set "ext=.bmp .gif .ico .jpg .jpe .jpeg .png"
  11. if "%file%"=="1" for /f "tokens=2 delims==" %%a in ('assoc ^| findstr "%ext%"') do call :addright "%%a"
  12. if "%file%"=="2" for /f "tokens=2 delims==" %%a in ('assoc ^| findstr "%ext%"') do call :deleteright "%%a"
  13. pause&exit

  15. :addright
  16. Reg.exe add "HKLM\SOFTWARE\Classes\%~1\shell\open1" /v "Icon" /t REG_SZ /d "%CD%\FSViewer.exe,0" /f
  17. Reg.exe add "HKLM\SOFTWARE\Classes\%~1\shell\open1" /ve /t REG_SZ /d "FSViewer" /f
  18. Reg.exe add "HKLM\SOFTWARE\Classes\%~1\shell\open1\command" /ve /t REG_SZ /d ""%CD%\FSViewer.exe" "%%1"" /f
  19. goto :EOF
  20. :deleteright
  21. Reg.exe delete "HKLM\SOFTWARE\Classes\%~1\shell\open1" /f
  22. goto :EOF
复制代码
回复

举报

kli2018
 楼主| 发表于 2020-7-2 13:28:08 | 显示全部楼层
本帖最后由 kli2018 于 2020-7-2 13:54 编辑

回复 2# went

谢谢

同时再问个问题
为什么我只是

set "ext=.doc .docx"

但是最后.mydocs这个的下面也添加了啊？
回复

举报

smss
发表于 2020-7-2 14:15:25 | 显示全部楼层
本帖最后由 smss 于 2020-7-2 14:36 编辑
  1. @Echo off
  2. :X
  3. cls&echo 1.添加图片格式关联  2.删除图片格式关联&choice /C:12 /N /M ">>输入选择:
  4. for /f "tokens=2 delims==" %%i in ('assoc ^|findstr ".bmp .gif .ico .jpg .jpe .jpeg .png"') do call :%errorlevel% "%%i"
  5. ping 0 -n "2">nul&goto :X
  6. :1
  7. reg add "HKLM\SOFTWARE\Classes\%~1\shell\open1" /v "Icon" /t REG_SZ /d "%CD%\FSViewer.exe,0" /f
  8. reg add "HKLM\SOFTWARE\Classes\%~1\shell\open1" /ve /t REG_SZ /d "FSViewer" /f
  9. reg add "HKLM\SOFTWARE\Classes\%~1\shell\open1\command" /ve /t REG_SZ /d ""%CD%\FSViewer.exe" "%%1"" /f
  10. goto :EOF
  11. :2
  12. reg delete "HKLM\SOFTWARE\Classes\%~1\shell\open1" /f
  13. goto :EOF
复制代码
回复

举报

went
发表于 2020-7-2 14:17:10 | 显示全部楼层
回复 3# kli2018
改成这样
  1. findstr /b "%ext%"
复制代码
更加准确就
  1. findstr /b "%ext: == %"
复制代码
回复

举报

kli2018
 楼主| 发表于 2020-7-2 15:35:22 | 显示全部楼层
回复 4# smss

谢谢
回复

举报

kli2018
 楼主| 发表于 2020-7-2 15:35:57 | 显示全部楼层
回复 5# went

谢谢
回复

举报

返回列表 发新帖
高级模式
B Color Image Link Quote Code Smilies
您需要登录后才可以回帖 登录 | 注册

本版积分规则

Archiver|手机版|小黑屋|批处理之家 ( 渝ICP备10000708号 )

GMT+8, 2026-3-20 00:54 , Processed in 0.018851 second(s), 8 queries , File On.

Powered by Discuz! X3.5

© 2001-2026 Discuz! Team.

快速回复 返回顶部 返回列表