求批处理进度条

xiaoguren · 发表于 2018-12-26 14:21:49

进度条，60秒减少一格，10分钟减完
代码如下，怎么调试也不显示进度条
求大神帮忙

@echo off&setlocal enabledelayedexpansion
mode con cols=113 lines=20 &color 9f
set a=■■■■■■■■■■
for /l %%i in (600,-1,1) do (
cls
set /a n=%%i%60
set /a m=60
if !n! geq 60 set /a m-=1
echo After %%i seconds ,start thunder
echo !a:~-%m%!
ping /n 2 127.1 >nul
)

复制代码

523066680 · 发表于 2018-12-26 15:54:08

yhcfsr · 发表于 2018-12-26 17:35:19

@echo off&setlocal enabledelayedexpansion
mode con cols=113 lines=20 &color 9f
set "bar=■■■■■■■■■■"
for /l %%i in (600,-1,0) do (
if %%i neq 600 (set/a "num=%%i%%60")
if defined num if !num! equ 0 set bar=!bar:~,-1!
cls
echo After %%i seconds ,start thunder
echo;!bar!
ping /n 2 127.1 >nul
)
pause

复制代码

SQYSQYSQY · 发表于 2019-1-5 22:20:34

本帖最后由 SQYSQYSQY 于 2019-1-5 22:21 编辑

回复 1# xiaoguren

@echo off&setlocal enabledelayedexpansion
mode con cols=113 lines=20 &color 9f
set "a=■■■■■■■■■■"
for /l %%a in (600 -1 1) do (
set /a "b=(%%a+59)/60"
cls
echo After %%a seconds ,start thunder
for %%b in (!b!) do echo !a:~0,%%b!
ping -n 2 127.1 >nul
)
cls
echo After 0 seconds ,start thunder
pause >nul

复制代码

我调试过的，没问题

Zhou. · 发表于 2020-5-12 13:23:57

我这有一个不用开启变量延迟的方法。
:start
cls
set a=10
set b=■■■■■■■■■■
:jindu
cls
set /a a=a-1
if "%a%"=="9" set b=■■■■■■■■■
if "%a%"=="8" set b=■■■■■■■■
if "%a%"=="7" set b=■■■■■■■
if "%a%"=="6" set b=■■■■■■
if "%a%"=="5" set b=■■■■■
if "%a%"=="4" set b=■■■■
if "%a%"=="3" set b=■■■
if "%a%"=="2" set b=■■
if "%a%"=="1" set b=■
if "%a%"=="0" goto kaishi
echo 还剩%a%秒
echo %b%
ping /n 2 127.0.0.1>nul
goto jindu
已测试，没问题。

Zhou. · 发表于 2020-5-12 13:26:32

回复 5# Zhou.
说错了！
:start
cls
set a=10
set b=■■■■■■■■■■
:jindu
cls
set /a a=a-1
if "%a%"=="9" set b=■■■■■■■■■
if "%a%"=="8" set b=■■■■■■■■
if "%a%"=="7" set b=■■■■■■■
if "%a%"=="6" set b=■■■■■■
if "%a%"=="5" set b=■■■■■
if "%a%"=="4" set b=■■■■
if "%a%"=="3" set b=■■■
if "%a%"=="2" set b=■■
if "%a%"=="1" set b=■
if "%a%"=="0" goto kaishi
echo 还剩%a%秒
echo %b%
ping /n 2 127.0.0.1>nul
goto jindu

:kaishi
echo 成功！
pause
exit

Zhou. · 发表于 2020-5-12 13:27:34

回复 6# Zhou.

记得前面加上@echo off

		自动登录	找回密码
密码			注册

[新手上路]批处理新手入门导读	[视频教程]批处理基础视频教程	[视频教程]VBS基础视频教程	[批处理精品]批处理版照片整理器
[批处理精品]纯批处理备份&还原驱动	[批处理精品]CMD命令50条不能说的秘密	[在线下载]第三方命令行工具	[在线帮助]VBScript / JScript 在线参考

[特效代码] 求批处理进度条