批处理删除指定文件夹下以外的文件

lovekix · 发表于 2020-2-20 11:33:52

文件夹C:\Windows\servicing\Packages 下面包含很多文件夹和文件
只保留含有MediaPlayback的文件和SMB1的文件

里面的文件名  都是这样的

Microsoft-Windows-MediaPlayback-OC-Package~31bf3856ad364e35~amd64~~10.0.19041.1.cat
Microsoft-Windows-MediaPlayback-OC-Package~31bf3856ad364e35~amd64~~10.0.19041.1.mum
Microsoft-Windows-MediaPlayback-OC-Package~31bf3856ad364e35~amd64~zh-CN~10.0.19041.1.cat
Microsoft-Windows-MediaPlayback-OC-Package~31bf3856ad364e35~amd64~zh-CN~10.0.19041.1.mum

最好是  可以指定 MediaPlayback 只要包含这样的都保留

如果不行就前面精确  后面模糊  也行

请问如何实现？
移动文件夹的话  再移动回来就不能用了不知道是什么原因（所以尽量不要移动再创建）

for /f "delims=" %%i in ('dir /ad /b
后面不会写了

Gin_Q · 发表于 2020-2-20 11:54:20

本帖最后由 Gin_Q 于 2020-2-20 12:54 编辑

@echo off
for /r ./ %%a in (*) do (for /f %%b in ('echo %%~nxa ^| findstr /v /c:c') do echo %%b)
pause

复制代码

zaqmlp · 发表于 2020-2-20 12:00:27

以管理员身份运行

@echo off
set info=互助互利,支付宝扫码头像,感谢打赏
rem 有问题,可加QQ956535081及时沟通
title %info%
set "fd=C:\Windows\servicing\Packages"
if not exist "%fd%" (echo;"%fd%" no found&goto end)
for /f "delims=" %%a in ('dir /a-d/b/s "%fd%"') do (
if "%%~nxa" neq "%~nx0" (
set "name=%%~na"&set "f=%%a"&set "z="
setlocal enabledelayedexpansion
if /i "!name:MediaPlayback=!" neq "!name!" set z=1
if /i "!name:SMB1=!" neq "!name!" set z=1
if not defined z del /f /q "!f!"
endlocal
)
)
:end
echo;%info%
pause
exit

复制代码

lovekix · 发表于 2020-2-20 18:18:28

回复 2# Gin_Q

感谢但是不明白怎么使用

lovekix · 发表于 2020-2-20 18:19:27

回复 3# zaqmlp

谢谢

red2020 · 发表于 2020-2-20 18:38:42

本帖最后由 red2020 于 2020-2-20 18:45 编辑

一箭双雕,一行搞定.

@echo off&for /f "delims=" %%a in ('dir /a-d /b /s "C:\Windows\servicing\Packages" ^|findstr /v "MediaPlayback SMB1" ') do (del /f /q "%%a")&pause

复制代码

回复 5# lovekix

lovekix · 发表于 2020-3-25 10:05:29

@echo off
set info=标题
title %info%
set "fd=C:\Windows\servicing\Packages"
if not exist "%fd%" (echo;"%fd%" no found&goto end)
for /f "delims=" %%a in ('dir /a-d/b/s "%fd%"') do (
if "%%~nxa" neq "%~nx0" (
set "name=%%~na"&set "f=%%a"&set "z="
setlocal enabledelayedexpansion
if /i "!name:Microsoft-Windows-Presentation-Package=!" neq "!name!" set z=1
if /i "!name:Microsoft-Windows-WindowsFoundation-LanguagePack-Package=!" neq "!name!" set z=1
if not defined z del /f /q "!f!"
endlocal
)
)
:end
echo;%info%
pause
exit

复制代码

感谢 zaqmlp

		自动登录	找回密码
密码			注册

[新手上路]批处理新手入门导读	[视频教程]批处理基础视频教程	[视频教程]VBS基础视频教程	[批处理精品]批处理版照片整理器
[批处理精品]纯批处理备份&还原驱动	[批处理精品]CMD命令50条不能说的秘密	[在线下载]第三方命令行工具	[在线帮助]VBScript / JScript 在线参考

[文件操作] 批处理删除指定文件夹下以外的文件