[已解决]批处理根据文件名移动文件到新建文件夹

赚他一个亿 · 发表于 2019-7-4 16:32:22

IP监控点11_192.168.1.3_192.168.1.3_20181208001053_20181208001109_76396580.mp4
根据文件日期20181208这个段文字移动且新建文件夹20181208这个
完成

我搜索了之前的帖子：
http://www.bathome.net/viewthrea ... etag=s_pctim_aiomsg
这个帖子和我很像下面是这个帖子给出的代码：

@echo off每个批处理里都用，关闭回显以及不显示本行
for %%a in (*.*) do 以%%a显示当前目录下所有文件和目录，不包括子目录内，也不包括隐藏或系统属性的文件
for /f "tokens=5 delims=-." %%b in ("%%a") do 解析这些文件名，把“件号”赋值给变量%%b
if not exist %%b\ md %%b\判断“件号”为名的目录是否存在，不存在就创建
move "%%a" %%b\移动符合条件的文件到“件号”目录

复制代码

这个脚本我要怎改才能适合我呢，搞好有红包！！！！！没有这个脚本我工作量巨大！！

赚他一个亿 · 发表于 2019-7-4 16:35:48

自己顶一下子，
根据文件名里的20181208新建文件夹，把文件名带有20181208的文件移动到新建文件夹
就这样子。

Batcher · 发表于 2019-7-4 16:52:30

@echo off
setlocal enabledelayedexpansion
for %%a in (*.mp4) do (
for /f "tokens=1-5* delims=_" %%b in ("%%a") do (
set "FileDate=%%f"
set "FileDate=!FileDate:~0,8!"
if not exist "!FileDate!" (
md "!FileDate!"
)
move /y "%%b_%%c_%%d_%%e_%%f_%%g" "!FileDate!"
)
)

复制代码

zaqmlp · 发表于 2019-7-4 16:53:10

@echo off
set info=互助互利,支付宝扫码头像,感谢赞助
rem 有问题,可加QQ956535081及时沟通
title %info%
cd /d "%~dp0"
for /f "delims=" %%a in ('dir /a-d/b *_*_*_*_*.mp4') do (
for /f "tokens=5 delims=_" %%b in ("%%~na") do (
set "fd=%%b"
set "file=%%a"
setlocal enabledelayedexpansion
set "fd=!fd:~,8!"
if not exist "!fd!" md "!fd!"
echo;"!file!" --^> "!fd!"
move "!file!" "!fd!"
endlocal
)
)
echo;%info%
pause

复制代码

赚他一个亿 · 发表于 2019-7-4 16:59:59

回复 4# zaqmlp

红包已发送，不多也够烟钱，谢谢。

赚他一个亿 · 发表于 2019-7-4 17:00:44

回复 3# Batcher

留言一下支付宝，赞助链接无权限打开。xx

zaqmlp · 发表于 2019-7-4 17:04:47

回复 5# 赚他一个亿

互助互利,感谢赞助

Batcher · 发表于 2019-7-4 17:08:33

回复 6# 赚他一个亿

不用了兄弟，红包你先自己留着吧，欢迎多来论坛切磋交流，很快就有权限了

		自动登录	找回密码
密码			注册

[新手上路]批处理新手入门导读	[视频教程]批处理基础视频教程	[视频教程]VBS基础视频教程	[批处理精品]批处理版照片整理器
[批处理精品]纯批处理备份&还原驱动	[批处理精品]CMD命令50条不能说的秘密	[在线下载]第三方命令行工具	[在线帮助]VBScript / JScript 在线参考

[文件操作] [已解决]批处理根据文件名移动文件到新建文件夹

评分