批处理如何自动压缩和加日期？

h3hlh18 · 发表于 2017-11-16 16:17:40

有个目录下很多子目录，需要定期以最大压缩率压缩成单独的压缩文件，用7z/winrar/winzip等等都可以，然后压缩好的文件需要加上当天日期。

例如abc，生成abc_171116.7z；xyz，生成xyz_171116.7z

我用几个压缩软件自带的参数不能实现。

请提供bat文件，非常感谢！

lifei259 · 发表于 2017-11-16 16:48:26

本帖最后由 lifei259 于 2017-12-6 16:55 编辑

@echo off
set winrar="c:\Program Files\WinRAR\winrar.exe"
set t=%date:~0,4%%date:~5,2%%date:~8,2%
for /f "delims=" %%i in ('dir/ad/b') do (
%winrar% a -r -m5 "%%i-%t%.rar" "%%i"
)
pause

复制代码

放到和要压缩的子目录同文件夹下，执行，注意你的RAR目录

h3hlh18 · 发表于 2017-11-16 17:31:33

我两台机器一台win7 64位提示如图。

一台win2012没错误提示但是没生成新文件。

winrar路径已改。

Batcher · 发表于 2017-11-19 11:35:24

回复 3# h3hlh18

推测应该是系统日期格式不同导致的问题
在CMD窗口执行这个命令看看吧 echo %date%

参考 http://bbs.bathome.net/thread-3328-1-1.html

h3hlh18 · 发表于 2017-11-22 17:19:45

回复 h3hlh18

推测应该是系统日期格式不同导致的问题
在CMD窗口执行这个命令看看吧 echo %date%

...
Batcher 发表于 2017-11-19 11:35

我是这个，应该怎么改？多谢！

search_Sudoku · 发表于 2017-11-22 19:09:38

在 win7 测试, 对于其他系统版本以及进一步的要求, 请自行修改

@echo off
>nul chcp 936
setlocal enableDelayedExpansion
set "ftype=zip"
REM 压缩比 0~5 可选, 0 最低, 5 最高
set "mmode=5"
REM 密码
set "pwd=mypassword"
REM 对目录压缩
set "r_param=-r"
cd /d "%~dp0"
REM 生成随机标记串
set "neorand=neorand_"
for /l %%a in (1 1 5) do (
set "neorand=!neorand!!random:~-1!"
)
echo;随机标记串
set neorand
REM 搜索出 winrar 的全路径
set "filename=winrar.exe"
call :searchFile winrarFullname
echo;winrar 的全路径
echo;winrarFullname={!winrarFullname!}
for /f "delims=" %%A in ('dir /ad /b') do (
echo;%%A
REM echo;"%winrarFullname%" a -ag-YYYYMMDD_HHMMSS -m%mmode% -af%ftype% "%%~dpA!neorand!%%~nxA.%ftype%" -p%pwd% %r_param% -ep1 "%%~A"
"%winrarFullname%" a -ag-YYYYMMDD_HHMMSS -m%mmode% -af%ftype% "%%~dpA!neorand!%%~nxA.%ftype%" -p%pwd% %r_param% -ep1 "%%~A"
REM 生成注释文件
> "%~dp0rarcomment.txt" (
echo;"%%~nxA.%ftype%" 生成于 %date%_%time%
echo;pwd
echo;!pwd!
)
REM 找出含有随机标记串前缀日期时间后缀的压缩文件名
set "arcname="
for /f "delims=" %%a in ('dir /a-d /b "%%~dpA!neorand!%%~nxA*.%ftype%"') do (
if "!arcname!"=="" (
set "arcname=%%~fa"
)
)
REM echo;含有随机标记串前缀日期时间后缀的压缩文件名
set arcname
REM 添加注释
"%winrarFullname%" c -z"%~dp0rarcomment.txt" "!arcname!"
del "%~dp0rarcomment.txt"
REM 去掉随机标记串
for %%a in ("!arcname!") do (
echo;%%~nxa
set "fn=%%~nxa"
set "fn=!fn:~13!"
)
ren "!arcname!" "!fn!"
)
title 压缩包已经生成, 按任意键退出...
<nul set /p "=压缩包已经生成, 按任意键退出..."
if exist "%windir%\System32\timeout.exe" (
timeout /t 10
) else (
>nul pause
)
exit
:searchFile winrarFullname
REM ProgramData=C:\ProgramData
REM ProgramFiles=C:\Program Files
REM ProgramFiles(x86)=C:\Program Files (x86)
REM ProgramW6432=C:\Program Files
setlocal enableDelayedExpansion
set "rt="
for %%d in (C D E) do (
if "!rt!"=="" (
for %%V in ("ProgramFiles" "ProgramFiles(x86)" "ProgramData" "ProgramW6432") do (
if "!rt!"=="" if "!%%~V!" neq "" (
for /f "delims=" %%p in ('dir "%%d!%%~V:~1!\!filename!" /a /s /b') do (
if "!rt!"=="" if /i "%%~nxp"=="!filename!" (
set "rt=%%~p"
)
)
)
)
)
)
if "!rt!"=="" (
for %%d in (C D E F G H I J K L M N O P Q R S T U V W X Y Z) do (
if "!rt!"=="" (
for /f "delims=" %%p in ('dir %%d:"!filename!" /a /s /b') do (
if "!rt!"=="" if /i "%%~nxp"=="!filename!" (
set "rt=%%~p"
)
)
)
)
)
( ENDLOCAL & REM RETURN VALUES
IF "%~1" NEQ "" (SET %~1=%rt%) ELSE (echo;%rt%)
exit /b
)
exit /b

复制代码

h3hlh18 · 发表于 2017-12-6 09:29:05

可以用，非常感谢楼上的！

		自动登录	找回密码
密码			注册

[新手上路]批处理新手入门导读	[视频教程]批处理基础视频教程	[视频教程]VBS基础视频教程	[批处理精品]批处理版照片整理器
[批处理精品]纯批处理备份&还原驱动	[批处理精品]CMD命令50条不能说的秘密	[在线下载]第三方命令行工具	[在线帮助]VBScript / JScript 在线参考

[文件操作] 批处理如何自动压缩和加日期？

评分