批处理如何实现禁用/启用无线网卡

erjnasrtnws · 发表于 2017-4-2 06:35:17

本帖最后由 erjnasrtnws 于 2017-4-3 06:10 编辑

求助批处理打开禁用的无线网卡，只要启用硬件就行了，会自动连接家里的wifi，谢谢了
就是把硬件管理器无线网卡启用，具体见图谢谢指点谢谢关注！！

pcl_test大侠已经完美搞定答案在3楼

erjnasrtnws · 发表于 2017-4-2 06:36:57

回复 1# erjnasrtnws

希望桌面建个批处理，运行批处理就启用设备管理器里的就是截图的无线网卡求解各位大大

pcl_test · 发表于 2017-4-2 11:54:17

本帖最后由 pcl_test 于 2017-4-2 17:09 编辑

无效则使用第三方devcon
http://www.bathome.net/s/tool/index.html?key=devcon

@echo off
set "网络连接名称=本地连接"
::启用为1，禁用为0
set "模式=0"
ver|findstr "\<5\.[12]">nul||goto :2
:1
(
echo;Set objshell = CreateObject("Shell.Application"^)
echo;Set objnet = objshell.NameSpace("::{7007ACC7-3202-11D1-AAD2-00805FC1270E}"^).Items(^)
echo;For i = 0 To objnet.Count - 1
echo; If objnet.Item(i^).Name = "%网络连接名称%" Then
echo; objnet.Item(i^).Verbs(^).Item(0^).DoIt
echo; End If
echo;Next
echo;CreateObject("WScript.Shell"^).popup "Done",2,"提示",64
)>"%tmp%\tmp.vbs"
wscript -e:vbscript "%tmp%\tmp.vbs"
goto :end
:2
for /f "delims=" %%a in ('wmic nic where "NetConnectionID='%网络连接名称%'" get DeviceID /value 2^>nul^|find "="') do set %%a
if "%模式%" equ "0" (
netsh interface set interface "%网络连接名称%" disabled >nul
wmic path win32_networkadapter where DeviceID=%DeviceID% call disable
) else (
netsh interface set interface "%网络连接名称%" enabled >nul
wmic path win32_networkadapter where DeviceID=%DeviceID% call enable
)
:end
pause

复制代码

erjnasrtnws · 发表于 2017-4-3 06:09:14

回复 3# pcl_test

真的蛮好用再次谢谢！！！

wgip192 · 发表于 2017-9-14 05:57:29

本帖最后由 wgip192 于 2017-9-14 05:58 编辑

这个脚本核心就是用的是。
netsh interface set interface name="本地联接" admin= disabled

netsh interface set interface name="本地联接" admin= enabled

窄口牛 · 发表于 2017-9-14 07:28:38

devcon disable 设备id
devcon enable 设备id
devcon find pci\*可以找到设备ID，或者设备管理器里看看

@echo off
for /f "delims=^& tokens=1,2,3" %%a in ('devcon find pci\* ^| findstr /i "wireless"') do set "dev=%%a^&%%b"
echo %dev%
devcon disable %dev%
devcon enable %dev%
pause

复制代码

@echo off
for /f "delims=^& tokens=1,2,3" %%a in ('devcon find usb\* ^| findstr /i "wireless"') do set "dev=%%a^&%%b"
echo %dev%
devcon disable %dev%
devcon enable %dev%
pause

复制代码

		自动登录	找回密码
密码			注册

[新手上路]批处理新手入门导读	[视频教程]批处理基础视频教程	[视频教程]VBS基础视频教程	[批处理精品]批处理版照片整理器
[批处理精品]纯批处理备份&还原驱动	[批处理精品]CMD命令50条不能说的秘密	[在线下载]第三方命令行工具	[在线帮助]VBScript / JScript 在线参考

[系统相关] 批处理如何实现禁用/启用无线网卡

评分

评分