[已解决]批处理如何将文本里的指定标点符号/字符替换成回车换行符

kunlun621 · 发表于 2016-9-22 12:40:34

本帖最后由 pcl_test 于 2016-9-24 16:59 编辑

将文本内容从行转化为列
文本1.txt内容：
床前明月光，疑是地上霜。举头望明月，低头思故乡。
转化成如下格式：
床前明月光
疑是地上霜
举头望明月
低头思故乡

运行成功的代码如下：

@echo off
for /f "tokens=1 delims=，。" %%a in (1.txt) do (echo %%a >>2.txt
)
for /f "tokens=2 delims=，。" %%a in (1.txt) do (echo %%a >>2.txt
)
for /f "tokens=3 delims=，。" %%a in (1.txt) do (echo %%a >>2.txt
)
for /f "tokens=4 delims=，。" %%a in (1.txt) do (echo %%a >>2.txt
)
pause

问题一：怎样简化呢？上面代码要重复好几遍，太繁琐

问题二：上面的代码只能新建文本2.txt显示要转化的内容，能不能在1.txt中直接转化呢？
思路将%%a %%b %%c %%d返回的结果直接引用到下面的%%a中，再用tokens截取
问题代码如下：
@echo off
for /f "tokens=1,2,3,4 delims=。，" %%a in (1.txt) do echo %%a %%b %%c %%d
for /f "tokens=1" %%a in do echo %%a >>1.txt
for /f "tokens=2" %%b in do echo %%a >>1.txt
for /f "tokens=3" %%c in do echo %%a >>1.txt
for /f "tokens=4" %%d in do echo %%a >>1.txt
pasue

从能看懂的代码开始的阅读评分，结果后面没分了

感谢各位的解答！

codegay · 发表于 2016-9-22 16:18:33

正则表达式替换，。成回车换行符即可。

happy886rr · 发表于 2016-9-22 17:07:17

回复 1# kunlun621

@echo off
for /f "delims=" %%L in ('type 1.txt') do (
set "line=%%L"
setlocal enabledelayedexpansion
set "line=!line:，=， !"
set "line=!line:。=。 !"
for %%l in (!line!) do (echo %%l)
echo;&endlocal
)
pause>NUL

复制代码

523066680 · 发表于 2016-9-22 17:50:20

装一个

echo 床前明月光，疑是地上霜。举头望明月，低头思故乡。|perl -e "$_=<>; $_=~s/，|。/\n/g;print;"

复制代码

输出：
床前明月光
疑是地上霜
举头望明月
低头思故乡

DiamondbacK · 发表于 2016-9-22 18:19:04

本帖最后由 DiamondbacK 于 2016-9-22 19:47 编辑

for /f "tokens=1,2,3,4 delims=，。？！" %%A in (1.txt) do (
echo %%A
echo %%B
echo %%C
echo %%D
)

复制代码

>con sed -r "s/[，。？！]+/\n/g" 1.txt

复制代码

>con gawk -v RS=[，。？！] 1 1.txt

复制代码

>con gawk "{ gsub(/[，。？！]/, "\n"); } 1" 1.txt

复制代码

PowerShell -c "(Get-Content 1.txt) -replace '[，。？！]', "`n""

复制代码

wskwfkbdn · 发表于 2016-9-22 18:31:22

回复 4# 523066680

话说版主，尝试一下纯BAT解决一下。

523066680 · 发表于 2016-9-22 19:01:56

回复 6# wskwfkbdn

我会复制 happy886rr 的代码，粘贴。

wskwfkbdn · 发表于 2016-9-22 19:56:12

回复 7# 523066680

只能这样啦，set替换一下，然后for处理一次OK

wskwfkbdn · 发表于 2016-9-22 21:08:19

@ECHO OFF & setlocal enabledelayedexpansion
SET "aa=床前明月光，疑是地上霜。举头望明月，低头思故乡。"
SET aa=!aa:，= !
SET aa=!aa:。= !
REM ECHO.!aa!!aa!
FOR %%i IN (!aa!) DO ECHO.%%i
pause

复制代码

WHY · 发表于 2016-9-22 21:16:34

@echo off & setlocal enabledelayedexpansion
set "s=床前明月光，疑是地上霜。举头望明月，低头思故乡。"
set s=!s:。=^
!
echo;!s:，=^
!
pause

复制代码

PowerShell -c "'床前明月光，疑是地上霜。举头望明月，低头思故乡。' -Split '[\p{P}]+'"

复制代码

CrLf · 发表于 2016-9-23 17:47:16

回复 10# WHY

加上回车符疗效更佳

@echo off & setlocal enabledelayedexpansion
set "s=床前明月光，疑是地上霜。举头望明月，低头思故乡。"
for /f %%D in ('copy /z %0 nul') do (
set s=!s:。=%%D^
!
echo;!s:，=%%D^
!
)
pause

复制代码

		自动登录	找回密码
密码			注册

[新手上路]批处理新手入门导读	[视频教程]批处理基础视频教程	[视频教程]VBS基础视频教程	[批处理精品]批处理版照片整理器
[批处理精品]纯批处理备份&还原驱动	[批处理精品]CMD命令50条不能说的秘密	[在线下载]第三方命令行工具	[在线帮助]VBScript / JScript 在线参考

[文本处理] [已解决]批处理如何将文本里的指定标点符号/字符替换成回车换行符

评分

评分

评分

评分

评分

评分

评分