[已解决]批处理如何提取指定内容所属的文本区域（范围）？

enoone1 · 发表于 2016-3-20 10:16:18

BAT如何获取指定行所在的文本区域
比如test.txt文本内容
安卓手机低配一：
{
   oppo：电池2000毫安
   oppo：充电一分钟通话一小时
   oppo：内存16G
……
}
功能机配置：不做配置描述
诺基亚：1050
安卓手机标配一：
{
华为：电池3000毫安
   华为：1600万像素
   华为：6英寸
……
}
安卓手机低配二：
{
类似上面格式
……
}
安卓手机高配二：
{
类似上面格式，每个配置项都是唯一的
……
}
……文本里还有很多低配置/高配置/标配置，类似上面配置格式

如何获取某一配置行，如“华为：1600万像素 ”所在的配置区域？？即经BAT过滤后，得到如下结果：
安卓手机标配一：
{
华为：电池3000毫安
   华为：1600万像素
   华为：6英寸
……
}

bailong360 · 发表于 2016-3-20 11:00:39

本帖最后由 bailong360 于 2016-3-20 20:48 编辑

//&@cls&more test.txt|cscript -nologo -e:jscript "%~f0"&pause
WSH.Echo(WSH.StdIn.ReadAll().match(/{[^{}]+?华为：1600万像素[^{}]+?}/g))

复制代码

=====2016-3-20 17:35==============
你们都来纯批处理,那我也来一个.应该是最短了

@echo off
setlocal enabledelayedexpansion
set keyword=华为：1600万像素
set LF=^
for /f "delims=" %%i in ('findstr /rc:"^[ {}]" test.txt') do (
set "str=!str!!LF!%%i"
if "%%i"=="}" (
if "!str:%keyword%=!" neq "!str!" echo {!str:*{=!
set str=
)
)
pause

复制代码

pcl_test · 发表于 2016-3-20 14:54:42

本帖最后由 pcl_test 于 2016-3-20 18:23 编辑

mshta http://bathome.net/s/hta/ "type('test.txt').match(/[^\r\n]+：\r?\n\{[^\}]+?华为：1600万像素[^\}]+?\}/g)"

复制代码

happy886rr · 发表于 2016-3-20 15:36:57

本帖最后由 happy886rr 于 2016-3-20 23:24 编辑

回复 1# enoone1
gk开关

@echo off&setlocal enabledelayedexpansion
set /p str=请输关键词: &echo,
for /f "tokens=1* delims=:" %%A in ('type test.txt^|findstr /n /i /c:"!str!"') do (
set gk=1
for /f "tokens=1* delims=:" %%a in ('type test.txt^|findstr /n "{"') do (
if !gk! equ 1 (
if %%a gtr %%A (
set gk=0
) else (
set /a mark=%%a-1
)
)
)
if not defined #!mark! (
set "#!mark!=1" &set gk=0
for /f "tokens=1* delims=:" %%a in ('type test.txt^|findstr /n .*') do (
if %%a equ !mark! (set gk=1)
if !gk! equ 1 (echo,%%b &set "dis=%%b"
if "!dis: =!"=="}" (
set gk=0
)
)
)
)
)
pause>nul

复制代码

标记算法

...
for /f "tokens=1* delims=:" %%a in ('type test.txt^|findstr /n /i /c:"!str!"') do (set #%%a=1)
for /f "tokens=1* delims=:" %%a in ('type test.txt^|findstr /n .*') do (
if "%%b"=="{" (set /a N=%%a-1)
if defined #%%a (set "#%%a=" &set "#!N!=1")
for /f "tokens=1* delims=:" %%a in ('type test.txt^|findstr /n .*') do (
if defined #%%a (set gk=1)
...

复制代码

WHY · 发表于 2016-3-20 16:35:39

本帖最后由 WHY 于 2016-3-20 17:49 编辑

临时文件方案

@echo off & setlocal enabledelayedexpansion
set "keyWord=华为：1600万像素"
set n=0
for /f "delims=" %%i in (test.txt) do (
if "%%i" == "}" (
(echo;!s!&echo;%%i)>>!n!.$
set /a n+=1
set "flag="
)else if "%%i" == "{" set flag=1
if defined flag echo;!s!>>!n!.$
set "s=%%i"
if not "!s:%keyWord%=!" == "!s!" set _!n!=1
)
for /f "delims=_=" %%i in ('set _') do move %%i.$ %%i.txt
del *.$
pause

复制代码

enoone1 · 发表于 2016-3-20 20:26:15

回复 2# bailong360

set "str=!str!!CR!%%i"这个字符串拼接用的绝，第一次看到这种用法，学到了，多谢。

pcl_test · 发表于 2016-3-20 20:44:44

回复 2# bailong360

应该是LF

bailong360 · 发表于 2016-3-20 20:48:02

回复 7# pcl_test
受教了

enoone1 · 发表于 2016-3-20 21:06:20

回复 3# pcl_test

版主我最近发帖老被PB -4,我感觉我按版规了啊，标题清楚，不是重复帖，为什么啊

pcl_test · 发表于 2016-3-20 21:12:40

回复 9# enoone1

直接发样本网盘分享链接，比你举长而不详的样例好很多

enoone1 · 发表于 2016-3-20 21:18:10

回复 10# pcl_test

好吧，以后注意

enoone1 · 发表于 2016-3-20 23:10:29

回复 5# WHY

变量用的很巧妙，膜拜下。

CrLf · 发表于 2016-3-21 02:14:53

context -e -f "/^\S+：/" -t /\}/ '1600万像素' test.txt

复制代码

下载：http://www.bathome.net/s/tool/?key=context

		自动登录	找回密码
密码			注册

[新手上路]批处理新手入门导读	[视频教程]批处理基础视频教程	[视频教程]VBS基础视频教程	[批处理精品]批处理版照片整理器
[批处理精品]纯批处理备份&还原驱动	[批处理精品]CMD命令50条不能说的秘密	[在线下载]第三方命令行工具	[在线帮助]VBScript / JScript 在线参考

[文本处理] [已解决]批处理如何提取指定内容所属的文本区域（范围）？

评分

评分

评分

评分

评分