批处理如何批量检查文件名与TXT第一行指定位置的内容是否相同？

eddyann · 发表于 2016-2-5 15:31:05

各位大神  我的需求就是题目的需求，求帮忙
文件第一行的内容是

channel:XXYY

文件名一般为 XXYY  或者是YY
我需要检查的就是TXT文件内容中XXYY的 YY 部分是否跟和文件名中的YY匹配

举例说明： txt 第一行为 channel:北京新闻
               文件名是新闻.txt

验证内容中的 channel:北京新闻  是否跟文件名中的新闻.txt  或者北京新闻.txt  或者是新闻频道.txt 的新闻这两字匹配

在百度看到一个但他是检查其他位置数据跟文件名的

贴出来给各位大神参考下

@echo off
setlocal enabledelayedexpansion
for /r %%a in (*.txt) do (
set Str=%%~na
for /f "tokens=3-6 delims=_-" %%w in ("!Str!") do set Str=%%~w%%~x%%~y%%~z
more +3 "%%~a">$tmp
set /p FStr=<$tmp
del $tmp
if defined FStr (
echo !FStr:-=!|findstr /i /c:"!Str!">nul || echo %%~nxa>>Mismatch.log
set FStr=
) else (
echo %%~nxa>>Mismatch.log
)
)
echo 不匹配的文件名已写入Mismatch.log
pause

复制代码

另外文件的第二行是当前日期下一天的日期格式为 2月5日星期五需要检查的是2月5日是否为系统当前日期下一天的日期
如果不是则导入LOG 不知道这个可以实现么

具体格式：
channel:北京新闻
02月05日星期五

谢谢各位大神了

eddyann · 发表于 2016-2-5 17:25:32

求帮忙-。-

CrLf · 发表于 2016-2-6 00:38:16

@echo off&setlocal enabledelayedexpansion
for /f "tokens=1,2" %%a in ('mshta "http://bathome.net/s/hta/?%random%&load=+moment" "moment().add(1,'d').lang('zh-cn').format('MM月DD日星期dd')"') do set dt=%%a
(for %%a in (*.txt) do (
set "line1="
set "line2="
(set /p line1=&set /p line2=)<"%%a"
for /f "tokens=1* delims=: " %%b in ("!line1!") do (
if %%b==channel if %%c neq %%~na echo %%a&set "line2=%dt%"
)
if !line2! neq !dt! echo %%a
))>Mismatch.log

复制代码

eddyann · 发表于 2016-2-6 14:58:39

回复 3# CrLf
大神这个怎么用

WHY · 发表于 2016-2-7 00:12:26

test.bat

@if (0)==(0) echo off
dir /b *.txt | cscript //nologo //e:jscript "%~f0" > NoMatch.Log
pause & exit
@end
var fso = new ActiveXObject('Scripting.FileSystemObject');
while(!WSH.StdIn.AtEndOfStream){
var strFile = WSH.StdIn.ReadLine();
var objFile = fso.OpenTextFile(strFile, 1);
var s1 = objFile.ReadLine().replace(/.*(..)$/, '$1');
var s2 = objFile.ReadLine();
objFile.Close(); objFile = null;
if(strFile.indexOf(s1) < 0 || dateTest(s2)) WSH.Echo(strFile);
}
function dateTest(s) {
var date = new Date();
date.setDate(date.getDate() + 1);
var dt = (date.getMonth() + 101 + '月').substr(1);
dt += (date.getDate() + 100 + '日').substr(1);
dt += ' 星期' + '日一二三四五六'.charAt(date.getDay());
if(s != dt){return 1}else return 0
}

复制代码

		自动登录	找回密码
密码			注册

[新手上路]批处理新手入门导读	[视频教程]批处理基础视频教程	[视频教程]VBS基础视频教程	[批处理精品]批处理版照片整理器
[批处理精品]纯批处理备份&还原驱动	[批处理精品]CMD命令50条不能说的秘密	[在线下载]第三方命令行工具	[在线帮助]VBScript / JScript 在线参考

[文件操作] 批处理如何批量检查文件名与TXT第一行指定位置的内容是否相同？

浏览过的版块